FileWriteLong

uint  FileWriteLong(
   int   file_handle,     // manejador del archivo
   long  value            // valor para escribir
   );

//+------------------------------------------------------------------+
//|                                           Demo_FileWriteLong.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- mostramos la ventana de parámetros de entrada al iniciar el script
#property script_show_inputs
//--- parámetros para obtener datos desde el terminal
input string          InpSymbolName="EURUSD";           // par de divisas
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_H1;        // período de tiempo
input datetime        InpDateStart=D'2013.01.01 00:00'; // fecha de inicio del copiado de datos
//--- parámetros para la escritura de datos en el archivo
input string          InpFileName="Volume.bin"; // nombre del archivo
input string          InpDirectoryName="Data";  // nombre de la carpeta
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish=TimeCurrent();
   long     volume_buff[];
   datetime time_buff[];
   int      size;
//--- reseteamos el valor del error
   ResetLastError();
//--- copiamos los volúmenes de ticks para cada barra
   if(CopyTickVolume(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,volume_buff)==-1)
     {
      PrintFormat("Fallo al copiar los valores del volumen de ticks. Código del error = %d",GetLastError());
      return;
     }
//--- copiamos el tiempo para cada barra
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
     {
      PrintFormat("Fallo al copiar el valor del tiempo. Código del error = %d",GetLastError());
      return;
     }
//--- obtenemos el tamaño del búfer
   size=ArraySize(volume_buff);
//--- abrimos el archivo para escribir los valores del indicador (si no existe, se crea automáticamente)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("El archivo %s está abierto para la escritura",InpFileName);
      PrintFormat("Ruta del archivo: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- primero escribimos el tamaño de la muestra de datos
      FileWriteLong(file_handle,(long)size);
      //--- escribimos el tiempo y los valores del volumen en el archivo
      for(int i=0;i<size;i++)
        {
         FileWriteLong(file_handle,(long)time_buff[i]);
         FileWriteLong(file_handle,volume_buff[i]);
        }
      //--- cerramos el archivo
      FileClose(file_handle);
      PrintFormat("Datos grabados, el archivo %s cerrado",InpFileName);
     }
   else
      PrintFormat("Fallo al abrir el archivo %s, Código del error = %d",InpFileName,GetLastError());
  }