DocumentaciónSecciones
Manual de referencia de MQL5Operaciones con archivosFileIsEnding 

FileIsEnding

Determina el final de un archivo en el proceso de lectura.

bool  FileIsEnding(
   int  file_handle      // manejador del archivo
   );

Parámetros

file_handle

[in]  Descriptor de archivo devuelto por la función FileOpen().

Valor devuelto

La función devuelve true, si se llega el final del archivo durante la lectura o en el proceso de mover el puntero de archivos.

Nota

Para detectar el fin del archivo, la función intenta leer la siguiente cadena del archivo. Si no la hay, la función devuelve true, de lo contrario - false.

Ejemplo:

//--- mostramos la ventana de parámetros de entrada al iniciar el script
#property script_show_inputs
//--- parámetros de entrada
input string InpFileName="file.txt";    // nombre del archivo
input string InpDirectoryName="Data";   // nombre de la carpeta
input int    InpEncodingType=FILE_ANSI; // ANSI=32 o UNICODE=64
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- imprimimos la ruta de la carpeta en la que vamos a trabajar
   PrintFormat("Trabajamos en la carpeta %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- reseteamos el valor del error
   ResetLastError();
//--- abrimos el archivo de lectura (si el archivo no existe, se produce un error)
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_TXT|InpEncodingType);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- imprimimos el contenido del archivo
      while(!FileIsEnding(file_handle))
         Print(FileReadString(file_handle));
      //--- cerramos el archivo
      FileClose(file_handle);
     }
   else
      PrintFormat("Error, código = %d",GetLastError());
  }