//+--------------------------------------------------------------------------------+
//| Demo_FileWriteDouble.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
//--- mostra la finestra dei parametri di input quando si lancia lo script
#property script_show_inputs
//--- parametri per la ricezione dei dati dal terminale
input string InpSymbolName="EURJPY"; // coppia di valute
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_M15; // time frame
input int InpMAPeriod=10; // periodo smoothing
input int InpMAShift=0; // slittamento indicatore
input ENUM_MA_METHOD InpMAMethod=MODE_SMA; // tipo di smoothing
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE; // tipo di prezzo
input datetime InpDateStart=D'2013.01.01 00:00'; // data di inizio copiatura dati
//--- parameters for writing data to the file
input string InpFileName="MA.csv"; // nome del file
input string InpDirectoryName="Data"; // nome directory
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
datetime date_finish=TimeCurrent();
double ma_buff[];
datetime time_buff[];
int size;
//--- riceve l'handle dell'indicatore MA
ResetLastError();
int ma_handle=iMA(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpMAShift,InpMAMethod,InpAppliedPrice);
if(ma_handle==INVALID_HANDLE)
{
//--- fallimento nel ricevere l'handle dell'indicatore
PrintFormat("Errore quando si è ricevuto l'handle indicatore. Codice Errore = %d",GetLastError());
return;
}
//--- essendo nel ciclo finché l'indicatore calcola tutti i valori
while(BarsCalculated(ma_handle)==-1)
Sleep(20); // una pausa per consentire all'indicatore di calcolare tutti i suoi valori
PrintFormat("I valori dell'indicatore che iniziano da %s verranno scritti nel file",TimeToString(InpDateStart));
//--- copia i valori indicatore
ResetLastError();
if(CopyBuffer(ma_handle,0,InpDateStart,date_finish,ma_buff)==-1)
{
PrintFormat("Fallimento nel copiare i valori dell'indicatore. Codice Errore = %d",GetLastError());
return;
}
//--- copia l'orario di arrivo delle barre appropriate
ResetLastError();
if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
{
PrintFormat("Fallimento nel copiare i valori temporali. Codice Errore = %d",GetLastError());
return;
}
//--- riceve la grandezza del buffer
size=ArraySize(ma_buff);
//--- libera la memoria occupata per l'indicatore
IndicatorRelease(ma_handle);
//--- apre il file per la scrittura dei valori indicatore (se il file è assente, verrà creato automaticamente)
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("il file %s è disponibile per la scrittura",InpFileName);
PrintFormat("Percorso file: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- prima, scrive la grandezza del campione dati
FileWriteDouble(file_handle,(double)size);
//--- scrive l'orario ed il valore dell'indicatore nel file
for(int i=0;i<size;i++)
{
FileWriteDouble(file_handle,(double)time_buff[i]);
FileWriteDouble(file_handle,ma_buff[i]);
}
//--- chiude il file
FileClose(file_handle);
PrintFormat("I dati vengono scritti, il file %s è chiuso",InpFileName);
}
else
PrintFormat("Fallimento nell'aprire il file %s, Codice errore = %d",InpFileName,GetLastError());
}
|