FileWriteString

uint  FileWriteString(
   int           file_handle,    // 파일 핸들
   const string  text_string,    // 작성할 문자열
   int           length=-1       // 심볼의 수
   );

//+------------------------------------------------------------------+
//|                                         Demo_FileWriteString.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- 스크립트를 시작할 때 입력 매개 변수의 창을 표시합니다.
#property script_show_inputs
//--- 터미널에서 데이터를 수신하기 위한 매개 변수
input string             InpSymbolName="EURUSD";           // 통화
input ENUM_TIMEFRAMES    InpSymbolPeriod=PERIOD_H1;        // 타임프레임
input int                InpMAPeriod=14;                   // MA period
input ENUM_APPLIED_PRICE InpAppliedPrice=PRICE_CLOSE;      // 가격 유형
input datetime           InpDateStart=D'2013.01.01 00:00'; // 데이터 복사 시작 날짜
//--- 파일에 데이터를 쓰기 위한 매개 변수
input string             InpFileName="RSI.csv";   // 파일명
input string             InpDirectoryName="Data"; // 디렉토리명
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish; // 데이터 복사 종료일
   double   rsi_buff[];  // 지표 값 배열
   datetime date_buff[]; // 지표 날짜 배열
   int      rsi_size=0;  // 지표 배열 사이즈
//--- 종료 시간은 현재 시간입니다
   date_finish=TimeCurrent();
//--- RSI 지표 핸들 수령
   ResetLastError();
   int rsi_handle=iRSI(InpSymbolName,InpSymbolPeriod,InpMAPeriod,InpAppliedPrice);
   if(rsi_handle==INVALID_HANDLE)
     {
      //--- 지표 핸들을 수신하지 못했습니다
      PrintFormat("지표 핸들 수신 시 오류 발생. Error code = %d",GetLastError());
      return;
     }
//--- 지표가 모든 값을 계산할 때까지 루프에 있음
   while(BarsCalculated(rsi_handle)==-1)
      Sleep(10); // 지표가 모든 값을 계산할 수 있도록 잠시 정지
//--- 일정 기간 동안 지표 값을 복제
   ResetLastError();
   if(CopyBuffer(rsi_handle,0,InpDateStart,date_finish,rsi_buff)==-1)
     {
      PrintFormat("지표값 복제 실패. Error code = %d",GetLastError());
      return;
     }
//--- 지표값에 적절한 시간을 복제
   ResetLastError();
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
     {
      PrintFormat("시간 값 복제 실패. Error code = %d",GetLastError());
      return;
     }
//--- 지표의 메모리를 비움
   IndicatorRelease(rsi_handle);
//--- 버퍼 사이즈 수령
   rsi_size=ArraySize(rsi_buff);
//--- 지표 값을 쓰기 위해 파일을 엽니다(파일이 없을 경우 자동으로 생성됨)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV|FILE_ANSI);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s 파일을 쓸 수 있습니다",InpFileName);
      PrintFormat("파일 경로: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- 변수를 추가로 준비
      string str="";
      bool   is_formed=false;
      //--- 과매수 및 과매도 영역의 형성 날짜 작성
      for(int i=0;i<rsi_size;i++)
        {
         //--- 지표 값 확인
         if(rsi_buff[i]>=70 || rsi_buff[i]<=30)
           {
            //--- 값이 이 영역에서 첫 번째일 경우
            if(!is_formed)
              {
               //--- 값과 날짜를 더함
               str=(string)rsi_buff[i]+"\t"+(string)date_buff[i];
               is_formed=true;
              }
            else
               str+="\t"+(string)rsi_buff[i]+"\t"+(string)date_buff[i];
            //--- 다음 루프 반복으로 이동
            continue;
           }
         //--- 플래그 확인
         if(is_formed)
           {
            //--- 문자열이 형성되면, 파일에 작성
            FileWriteString(file_handle,str+"\r\n");
            is_formed=false;
           }
        }
      //--- 파일 닫기
      FileClose(file_handle);
      PrintFormat("데이터가 작성됐습니다, %s 파일이 닫힙니다",InpFileName);
     }
   else
      PrintFormat("%s 파일 열기 실패, 에러 코드 = %d",InpFileName,GetLastError());
  }