DokümantasyonBölümler
MQL5 ReferansıAlım-Satım FonksiyonlarıOrderGetString 

OrderGetString

Bu fonksiyon OrderGetTicket veya OrderSelect kullanılarak önceden seçilmiş olan emrin bir özelliğine dönüş yapar. Emir özelliği dizgi tipinde olmalıdır. Fonksiyonun iki türü mevcuttur.

1. Hızlı bir şekilde özellik değerine dönüş yapar.

string  OrderGetString(
   ENUM_ORDER_PROPERTY_STRING  property_id        // özellik tanımlayıcı
   );

2. Fonksiyonun başarı durumuna göre true (doğru) veya false (yanlış) değerine dönüş yapar. Başarı durumunda özellik değeri, referansla geçirilen son parametreye girilir.

bool  OrderGetString(
   ENUM_ORDER_PROPERTY_STRING  property_id,       // özellik tanımlayıcı
   string&                     string_var         // özellik değerini burada kabul ediyoruz
   );

Parametreler

property_id

[in]  Emir özelliğinin tanımlayıcısı. Bu değişken ENUM_ORDER_PROPERTY_STRING sayımının değerlerinden birini alabilir.

string_var

[out]  İstenen özellik değerinin girileceği dizgi tipli değişken..

Dönüş Değeri

string tipli değer.

Not

Müşteri terminalinde Araçkutusunun "İşlem" sekmesinde birlikte gösterilen mevcut bekleyen emirler ve pozisyonlar birbirleriyle karıştırılmamalıdır.

Netleştirme (netting) sisteminde (ACCOUNT_MARGIN_MODE_RETAIL_NETTING ve ACCOUNT_MARGIN_MODE_EXCHANGE) bir sembol üzerinde sadece bir pozisyon bulunabilir. Bu pozisyon bir veya daha fazla işlemin sonucu açılmış olabilir. Müşteri terminalinde Araçkutusunun "İşlem" sekmesi içinde birlikte gösterilen mevcut bekleyen emirler ve pozisyonlar birbirleriyle karıştırılmamalıdır.

Çoklu pozisyonlara izin verilemsi durumunda (ACCOUNT_MARGIN_MODE_RETAIL_HEDGING) bir sembol üzerinde birden fazla pozisyon açılabilir.

Emirle ilgili güncel verileri alabilmek için OrderSelect() çağrısının değişikliklerden sonra yapıldığından emin olmalısınız.

Örnek:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- hesaptaki tüm emirlerin listesine göre bir döngü içerisinde
   int total=OrdersTotal();
   for(int i=0; i<total; i++)
     {
      //--- döngü indeksine göre listedeki emrin fişini al
      ulong ticket=OrderGetTicket(i);
      if(ticket==0)
         continue;
      
      //--- emrin türünü al ve seçilen emrin dizge özelliklerinin listesi için başlığı görüntüle
      string type=OrderTypeDescription((ENUM_ORDER_TYPE)OrderGetInteger(ORDER_TYPE));
      PrintFormat("String properties of an active pending order %s #%I64u:", type, ticket);
      
      //--- seçilen emrin tüm dizge özelliklerini başlık altında yazdır
      OrderPropertiesStringPrint(13);
     }
   /*
   sonuç:
   String properties of an active pending order Sell Limit #2813781342:
   Comment:     Test OrderGetString
   Symbol:      EURUSD
   External ID: 
   */
  }
//+------------------------------------------------------------------+
//| Seçilen emrin dizge özelliklerini günlükte görüntüle             |
//+------------------------------------------------------------------+
void OrderPropertiesStringPrint(const uint header_width=0)
  {
//--- yorumu günlükte görüntüle
   OrderPropertyPrint("Comment:", header_width, ORDER_COMMENT);
   
//--- emrin yerleştirildiği sembolü günlükte görüntüle
   OrderPropertyPrint("Symbol:", header_width, ORDER_SYMBOL);
   
//--- harici bir sistemdeki emir kimliğini günlükte görüntüle
   OrderPropertyPrint("External ID:", header_width, ORDER_EXTERNAL_ID);
  }
//+------------------------------------------------------------------+
//| Emrin dizge özellik değerini günlükte görüntüle                  |
//+------------------------------------------------------------------+
void OrderPropertyPrint(const string header, uint header_width, ENUM_ORDER_PROPERTY_STRING property)
  {
   string value="";
   if(!OrderGetString(property, value))
      PrintFormat("Cannot get property %s, error=%d", EnumToString(property), GetLastError());
   else
     {
      //--- başlık genişliği fonksiyona sıfıra eşit olarak aktarılırsa, genişlik başlık satırının boyutu + 1 olacaktır
      uint w=(header_width==0 ? header.Length()+1 : header_width);
      PrintFormat("%-*s%-s", w, header, value);
     }
  }
//+------------------------------------------------------------------+
//| Emir türü açıklamasını geri döndür                               |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE type)
  {
   switch(type)
     {
      case ORDER_TYPE_BUY              :  return("Buy");
      case ORDER_TYPE_SELL             :  return("Sell");
      case ORDER_TYPE_BUY_LIMIT        :  return("Buy Limit");
      case ORDER_TYPE_SELL_LIMIT       :  return("Sell Limit");
      case ORDER_TYPE_BUY_STOP         :  return("Buy Stop");
      case ORDER_TYPE_SELL_STOP        :  return("Sell Stop");
      case ORDER_TYPE_BUY_STOP_LIMIT   :  return("Buy Stop Limit");
      case ORDER_TYPE_SELL_STOP_LIMIT  :  return("Sell Stop Limit");
      default                          :  return("Unknown order type: "+(string)type);
     }
  }

Ayrıca bakınız

OrdersTotal(), OrderGetTicket(), Emir Özellikleri