OrderCalcProfit

bool  OrderCalcProfit(
   ENUM_ORDER_TYPE       action,           // emir tipi (ORDER_TYPE_BUY veya ORDER_TYPE_SELL)
   string                symbol,           // sembol ismi
   double                volume,           // hacim
   double                price_open,       // açılış fiyatı
   double                price_close,      // kapanış fiyatı
   double&               profit            // kar değerinin alınacağı değişken
   );

 
#define   VOLUME     1.0   // emir hacmi
#define   DEVIATION  100   // kapanış fiyatından önceki puan sayısı
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string currency_profit=SymbolInfoString(_Symbol,SYMBOL_CURRENCY_PROFIT);   // kâr para birimi
   double close_price=ChartPriceOnDropped(); // komut dosyasının fare kullanılarak bırakıldığı noktaya karşılık gelen fiyat koordinatı, kapanış fiyatı olarak işlev görür
 
//---
   for(int i=0; i<=ORDER_TYPE_SELL; i++)
     {
      ENUM_ORDER_TYPE order_type=(ENUM_ORDER_TYPE)i;                 // emir türü: 0 - Alış, 1 - Satış
      double open_price=PriceOpenByOrderType(_Symbol, order_type);   // açılış fiyatı: Alış için - Ask, Satış için - Bid
     
      //--- açılış fiyatı alınmazsa, döngüye devam et
      if(open_price==0)
         continue;
      
      //--- kapanış fiyatı sıfırsa (kod grafiğe sürüklenerek başlatılmadıysa), fiyatı hesapla
      if(close_price==0)
         close_price=(order_type==ORDER_TYPE_BUY ? open_price + DEVIATION * _Point : open_price - DEVIATION * _Point);
      
      //--- iletilen parametrelere dayanarak mevcut hesap ve piyasa ortamı için yaklaşık kâr büyüklüğünü hesapla
      double profit=0;
      ResetLastError();
      if(!OrderCalcProfit(order_type, _Symbol, VOLUME, open_price, close_price, profit))
        {
         Print("OrderCalcProfit() failed. Error ", GetLastError());
         continue;
        }
      
      //--- elde edilen kâr değerini günlüğe yazdır
      PrintFormat("Estimated profit for %.2f %s position on %s with opening price of %.*f and closing price of %.*f: %.2f %s",
                  VOLUME, OrderTypeDescription(order_type), _Symbol, _Digits, open_price, _Digits, close_price, profit, currency_profit);
      
     }
   /*
   sonuç:
   Estimated profit for 1.00 Buy position on EURUSD with opening price of 1.10757 and closing price of 1.10881: 124.00 USD
   Estimated profit for 1.00 Sell position on EURUSD with opening price of 1.10753 and closing price of 1.10881: -128.00 USD
   */
  }
//+------------------------------------------------------------------+
//| Emir türüne göre açılış fiyatını geri döndür                     |
//+------------------------------------------------------------------+
double PriceOpenByOrderType(const string symbol, const ENUM_ORDER_TYPE order_type)
  {
   MqlTick tick={};
 
//--- sembole göre son fiyatları al
   if(!SymbolInfoTick(symbol, tick))
     {
      Print("SymbolInfoTick() failed. Error ", GetLastError());
      return 0;
     }
     
//--- emir türüne bağlı olarak fiyatı geri döndür
   switch(order_type)
     {
      case ORDER_TYPE_BUY              :  return(tick.ask);
      case ORDER_TYPE_SELL             :  return(tick.bid);
      default                          :  return(0);
     }
  }
//+------------------------------------------------------------------+
//| Emir türü açıklamasını geri döndür                               |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE order_type)
  {
   switch(order_type)
     {
      case ORDER_TYPE_BUY              :  return("Buy");
      case ORDER_TYPE_SELL             :  return("Sell");
      default                          :  return("Unknown order type");
     }
  }