PositionSelectByTicket

bool  PositionSelectByTicket(
   ulong   ticket     // pozisyon fişi
   );

#define   EXPERT_MAGIC  123456   // sihirli sayı
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- talep ve sonuç yapılarını bildir ve başlat
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   
//--- bir alış pozisyonu açmak için işlem talebi parametrelerini doldur
   request.action    = TRADE_ACTION_DEAL;                      // işlem türü
   request.symbol    = Symbol();                               // sembol
   request.volume    = 0.1;                                    // 0.1 lotluk hacim
   request.type      = ORDER_TYPE_BUY;                         // emir türü
   request.price     = SymbolInfoDouble(Symbol(), SYMBOL_ASK); // açılış fiyatı
   request.deviation = 5;                                      // fiyattan izin verilen sapma
   request.magic     = EXPERT_MAGIC;                           // emir sihirli sayısı
   
//--- bir talep gönder. Talep gönderilemediyse, hata kodunu görüntüle ve operasyonu tamamla
   if(!OrderSend(request, result))
     {
      PrintFormat("OrderSend error ", GetLastError());
      return;
     }
      
//--- işlem verilerini görüntüle
   PrintFormat("Trade request result: retcode: %u, deal: %I64u, order: %I64u", result.retcode, result.deal, result.order);
   
//--- işlem sonucundan pozisyon fişini al ve pozisyonu fişe göre seç
//--- yeni açılan bir pozisyonun fişi, işlemi oluşturan emrin fişine karşılık gelir
   ulong ticket=result.order;
   ResetLastError();
   if(!PositionSelectByTicket(ticket))
     {
      PrintFormat("PositionSelectByTicket(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- fiş ile seçilen pozisyonun verilerini günlükte görüntüle
   ENUM_POSITION_TYPE type  = (ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
   long               time  = PositionGetInteger(POSITION_TIME_MSC);
   double             price = PositionGetDouble(POSITION_PRICE_OPEN);
   double             volume= PositionGetDouble(POSITION_VOLUME);
   string             symbol= PositionGetString(POSITION_SYMBOL);
   int                digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected position: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, (type==POSITION_TYPE_BUY ? "Buy" : "Sell"), ticket, digits, price, TimeMscToString(time));
   /*
   sonuç:
   Trade request result: retcode: 10009, deal: 2778100901, order: 2803905975
   Current selected position: EURUSD 0.10 Buy #2803905975 at 1.10672, 2024.09.02 12:09:51.239
   */
  }
//+------------------------------------------------------------------+
//| Milisaniyeli zamanı geri döndür                          |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }