ドキュメントセクション
MQL5 リファレンス取引関数OrderGetString 

OrderGetString

OrderGetTicket または OrderSelect で事前に選択された注文のリクエストされたプロパティを返します。注文プロパティは string 型でなければなりません。この関数には 2 つのバージョンがあります。

1. すぐにプロパティ値を返します。

string  OrderGetString(
  ENUM_ORDER_PROPERTY_STRING  property_id        // プロパティ識別子
  );

2. 関数実行の成功に応じて true または false を返します。成功した場合、プロパティの値は、参照によって渡された最後のパラメータに配置されます。

bool  OrderGetString(
  ENUM_ORDER_PROPERTY_STRING  property_id,       // プロパティ識別子
  string&                    string_var        // プロパティ値を受け取る
  );

パラメータ

property_id

[in]  注文プロパティの識別子。値は ENUM_ORDER_PROPERTY_STRING 列挙のいずれかです。

string_var

[out] リクエストされたプロパティ値を受け取るstring 型の変数

戻り値

string 型の変数

注意事項

現在の未決注文はクライアント端末の「ツールボックス」の「取引」タブに表示されているポジションと混乱されてはなりません。

ポジションの『ネッティング』計算時（ACCOUNT_MARGIN_MODE_RETAIL_NETTINGとACCOUNT_MARGIN_MODE_EXCHANGE)各シンボルにつき常に一つのポジションのみ（1つ以上の取引の結果である）保有することができます。ポジションと『ツールボックス』パネルの『取引』タブに表示される有効な未決注文と混同しないようにしてください。

ポジションに制限がない場合(ACCOUNT_MARGIN_MODE_RETAIL_HEDGING)各シンボルごとに同時に複数のポジションを保有することができます。

取得した注文情報が最新であるように、OrderSelect() を参照直前に呼び出すことが推奨されています。

例：

//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                              |
//+------------------------------------------------------------------+
void OnStart()
 {
//--- すべての口座注文のリストのループ
  int total=OrdersTotal();
  for(int i=0; i<total; i++)
    {
    //--- ループインデックスでリストから注文チケットを取得する
    ulong ticket=OrderGetTicket(i);
    if(ticket==0)
        continue;
     
    //--- 注文タイプを取得し、選択した注文の文字列プロパティのリストのヘッダーを表示する
    string type=OrderTypeDescription((ENUM_ORDER_TYPE)OrderGetInteger(ORDER_TYPE));
    PrintFormat("String properties of an active pending order %s #%I64u:", type, ticket);
     
    //--- ヘッダーの下に選択した注文のすべての文字列プロパティを表示する
    OrderPropertiesStringPrint(13);
    }
  /*
   結果：
  String properties of an active pending order Sell Limit #2813781342:
  Comment:     Test OrderGetString
  Symbol:     EURUSD
  External ID:
  */
 }
//+------------------------------------------------------------------+
//| 操作ログに選択した注文の文字列プロパティを表示する                            |
//+------------------------------------------------------------------+
void OrderPropertiesStringPrint(const uint header_width=0)
 {
//--- 操作ログにコメントを表示する
  OrderPropertyPrint("Comment:", header_width, ORDER_COMMENT);
 
//--- 操作ログに注文が出された銘柄を表示する
  OrderPropertyPrint("Symbol:", header_width, ORDER_SYMBOL);
 
//--- 操作ログに外部取引システムでの注文IDを表示する
  OrderPropertyPrint("External ID:", header_width, ORDER_EXTERNAL_ID);
 }
//+------------------------------------------------------------------+
//  操作ログに注文の文字列プロパティを表示する                                  |
//+------------------------------------------------------------------+
void OrderPropertyPrint(const string header, uint header_width, ENUM_ORDER_PROPERTY_STRING property)
 {
  string value="";
  if(!OrderGetString(property, value))
    PrintFormat("Cannot get property %s, error=%d", EnumToString(property), GetLastError());
  else
    {
//--- ヘッダーの幅が関数に渡され、ゼロと等しい場合、幅はヘッダー行のサイズ+1になる
    uint w=(header_width==0 ? header.Length()+1 : header_width);
    PrintFormat("%-*s%-s", w, header, value);
    }
 }
//+------------------------------------------------------------------+
//| 注文タイプの説明を返す                                                 |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE type)
 {
  switch(type)
    {
    case ORDER_TYPE_BUY              : return("Buy");
    case ORDER_TYPE_SELL             : return("Sell");
    case ORDER_TYPE_BUY_LIMIT        : return("Buy Limit");
    case ORDER_TYPE_SELL_LIMIT       : return("Sell Limit");
    case ORDER_TYPE_BUY_STOP         : return("Buy Stop");
    case ORDER_TYPE_SELL_STOP        : return("Sell Stop");
    case ORDER_TYPE_BUY_STOP_LIMIT   : return("Buy Stop Limit");
    case ORDER_TYPE_SELL_STOP_LIMIT  : return("Sell Stop Limit");
    default                          : return("Unknown order type: "+(string)type);
    }
 }

参照

OrdersTotal()、OrderGetTicket()、注文プロパティ