//--- 説明
#property description "Script draws \"Standard Deviation Channel\" graphical object."
#property description "Anchor point coordinates are set in percentage of the size of"
#property description "the chart window."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string InpName="StdDevChannel"; // チャンネル名
input int InpDate1=10; // 1 番目のポイントの日付（ % ）
input int InpDate2=40; // 2 番目のポイントの日付（ % ）
input double InpDeviation=1.0; // 偏差値
input color InpColor=clrRed; // チャンネルの色
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // チャンネルの線のスタイル
input int InpWidth=2; // チャンネルの線の幅
input bool InpFill=false; // チャンネルを色で塗りつぶす
input bool InpBack=false; // 背景チャンネル
input bool InpSelection=true; // 強調表示して移動
input bool InpRayLeft=false; // チャンネルの左への継続
input bool InpRayRight=false; // チャンネルの右への継続
input bool InpHidden=true; // オブジェクトリストに隠す
input long InpZOrder=0; // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| 与えられた座標で標準偏差チャンネルを作成する |
//+------------------------------------------------------------------+
bool StdDevChannelCreate(const long chart_ID=0, // チャート識別子
const string name="Channel", // チャンネル名
const int sub_window=0, // サブウィンドウ番号
datetime time1=0, // 1 番目のポイントの時間
datetime time2=0, // 2 番目のポイントの時間
const double deviation=1.0, // 偏差値
const color clr=clrRed, // チャンネルの色
const ENUM_LINE_STYLE style=STYLE_SOLID, // チャンネルの線のスタイル
const int width=1, // チャンネルの線の幅
const bool fill=false, // チャンネルを色で塗りつぶす
const bool back=false, // 背景で表示する
const bool selection=true, // 強調表示して移動
const bool ray_left=false, // チャンネルの左への継続
const bool ray_right=false, // チャンネルの右への継続
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- 設定されてない場合アンカーポイントの座標を設定する
ChangeChannelEmptyPoints(time1,time2);
//--- エラー値をリセットする
ResetLastError();
//--- 与えられた座標でチャンネルを作成する
if(!ObjectCreate(chart_ID,name,OBJ_STDDEVCHANNEL,sub_window,time1,0,time2,0))
{
Print(__FUNCTION__,
": failed to create standard deviation channel! Error code = ",GetLastError());
return(false);
}
//--- チャンネル幅に影響を与える偏差値を設定する
ObjectSetDouble(chart_ID,name,OBJPROP_DEVIATION,deviation);
//--- チャンネルの色を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- チャンネルの線のスタイルを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- チャンネルの線の幅を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- チャンネルを色で塗りつぶすモードを有効（true）か無効（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- 前景（false）または背景（true）に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 強調表示してチャンネルを移動するモードを有効（true）か無効（false）にする。
//--- ObjectCreate 関数を使用してグラフィックオブジェクトを作成する際、オブジェクトは
//--- デフォルトではハイライトされたり動かされたり出来ない。このメソッド内では、選択パラメータは
//--- デフォルトでは true でハイライトと移動を可能にする。
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- チャンネルの表示を左に延長するモードを有効（true）か無効（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- チャンネルの表示を右に延長するモードを有効（true）か無効（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- オブジェクトリストのグラフィックオブジェクトを非表示（true）か表示（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャンネルのアンカーポイントを移動する |
//+------------------------------------------------------------------+
bool StdDevChannelPointChange(const long chart_ID=0, // チャート識別子
const string name="Channel", // チャンネル名
const int point_index=0, // アンカーポイントのインデックス
datetime time=0) // アンカーポイントの時間座標
{
//--- ポイントの時間が設定されていない場合、ポイントを現在足に移動する
if(!time)
time=TimeCurrent();
//--- エラー値をリセットする
ResetLastError();
//--- アンカーポイントを移動する
if(!ObjectMove(chart_ID,name,point_index,time,0))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャンネルの偏差を変更する |
//+------------------------------------------------------------------+
bool StdDevChannelDeviationChange(const long chart_ID=0, // チャート識別子
const string name="Channel", // チャンネル名
const double deviation=1.0) // 偏差値
{
//--- エラー値をリセットする
ResetLastError();
//--- 傾向線の傾斜角度を変更する
if(!ObjectSetDouble(chart_ID,name,OBJPROP_DEVIATION,deviation))
{
Print(__FUNCTION__,
": failed to change channel deviation! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャンネルを削除する |
//+------------------------------------------------------------------+
bool StdDevChannelDelete(const long chart_ID=0, // チャート識別子
const string name="Channel") // チャンネル名
{
//--- エラー値をリセットする
ResetLastError();
//--- チャンネルを削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete the channel! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+-------------------------------------------------------------------------+
//| チャンネルのアンカーポイントの値をチェックして |
//| 空の物には初期値を設定する |
//+-------------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,datetime &time2)
{
//--- 2 番目のポイントの時間が設定されていない場合、現在足になる
if(!time2)
time2=TimeCurrent();
//--- 1 番目のポイントの時間が設定されていない場合、2 番目から 9 バー左に置かれる
if(!time1)
{
//--- 最後の 10 バーのオープン時間を受信するための配列
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- 1 番目のポイントを 2 番目から 9 バー左に設定する
time1=temp[0];
}
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 入力パラメータの正しさをチェックする
if(InpDate1<0 || InpDate1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- チャートウィンドウで表示されているバーの数
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 価格配列サイズ
int accuracy=1000;
//--- アンカーポイントの座標の設定と変更に使用される日付と
//--- 価格の値を格納するための配列
datetime date[];
double price[];
//--- メモリ割り当て
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 日付配列に書き込む
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 価格配列に書き込む
//--- チャートの最高値と最安値を見つける
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 価格の変更ステップを定義し、配列に書き込む
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- チャンネル描画のポイントを定義する
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
//--- 標準偏差チャンネルを作成する
if(!StdDevChannelCreate(0,InpName,0,date[d1],date[d2],InpDeviation,InpColor,InpStyle,
InpWidth,InpFill,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- チャートを再描画して 1 秒待つ
ChartRedraw();
Sleep(1000);
//--- チャンネルを右に水平に移動して伸ばす
//--- ループカウンタ
int h_steps=bars/2;
//--- チャンネルを移動する
for(int i=0;i<h_steps;i++)
{
//--- 次の値を使用する
if(d1<bars-1)
d1+=1;
if(d2<bars-1)
d2+=1;
//--- アンカーポイントを移動する
if(!StdDevChannelPointChange(0,InpName,0,date[d1]))
return;
if(!StdDevChannelPointChange(0,InpName,1,date[d2]))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//--- 1 秒の遅れ
Sleep(1000);
//--- ループカウンタ
double v_steps=InpDeviation*2;
//--- チャンネルを拡張する
for(double i=InpDeviation;i<v_steps;i+=10.0/accuracy)
{
if(!StdDevChannelDeviationChange(0,InpName,i))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
}
//--- 1 秒の遅れ
Sleep(1000);
//--- チャートからチャンネルを削除する
StdDevChannelDelete(0,InpName);
ChartRedraw();
//--- 1 秒の遅れ
Sleep(1000);
//---
}
|
