//--- 説明
#property description "Script creates \"Chart\" object."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string InpName="Chart"; // オブジェクト名
input string InpSymbol="EURUSD"; // シンボル
input ENUM_TIMEFRAMES InpPeriod=PERIOD_H1; // 期間
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // アンカーに使用される隅
input int InpScale=2; // 規模
input bool InpDateScale=true; // 時間スケール表示
input bool InpPriceScale=true; // 価格スケール表示
input color InpColor=clrRed; // 強調表示時の境界線の色
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // 強調表示時の線のスタイル
input int InpPointWidth=1; // 移動のポイントサイズ
input bool InpBack=false; // 背景オブジェクト
input bool InpSelection=true; // 強調表示して移動
input bool InpHidden=true; // オブジェクトリストに隠す
input long InpZOrder=0; // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| チャートオブジェクトを作成する |
//+------------------------------------------------------------------+
bool ObjectChartCreate(const long chart_ID=0, // チャート識別子
const string name="Chart", // オブジェクト名
const int sub_window=0, // サブウィンドウ番号
const string symbol="EURUSD", // シンボル
const ENUM_TIMEFRAMES period=PERIOD_H1, // 期間
const int x=0, // X 座標
const int y=0, // Y 座標
const int width=300, // 幅
const int height=200, // 高さ
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // アンカーに使用される隅
const int scale=2, // 規模
const bool date_scale=true, // 時間スケール表示
const bool price_scale=true, // 価格スケール表示
const color clr=clrRed, // 強調表示時の境界線の色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 強調表示時の線のスタイル
const int point_width=1, // 移動ポイントサイズ
const bool back=false, // 背景で表示する
const bool selection=false, // 強調表示して移動
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- エラー値をリセットする
ResetLastError();
//--- チャートオブジェクトを作成する
if(!ObjectCreate(chart_ID,name,OBJ_CHART,sub_window,0,0))
{
Print(__FUNCTION__,
": failed to create \"Chart\" object! Error code = ",GetLastError());
return(false);
}
//--- オブジェクト座標を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- オブジェクトサイズを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- ポイント座標が相対的に定義されているチャートのコーナーを設定
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- シンボルを設定する
ObjectSetString(chart_ID,name,OBJPROP_SYMBOL,symbol);
//--- 期間を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_PERIOD,period);
//--- 規模を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_CHART_SCALE,scale);
//--- 時間スケールを表示(true)または非表示(false)する
ObjectSetInteger(chart_ID,name,OBJPROP_DATE_SCALE,date_scale);
//--- 価格スケールを表示(true)または非表示(false)する
ObjectSetInteger(chart_ID,name,OBJPROP_PRICE_SCALE,price_scale);
//--- オブジェクトのハイライト表示モードが有効になっている際の境界線の色を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- オブジェクトのハイライト表示モードが有効になっている際の境界線のスタイルを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- オブジェクトを移動するためのアンカーポイントのサイズを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,point_width);
//--- 前景(false)または背景(true)に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- マウスでラベルを移動させるモードを有効(true)か無効(false)にする
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示(true)か表示(false)にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャートオブジェクトのシンボルと時間軸を設定する |
//+------------------------------------------------------------------+
bool ObjectChartSetSymbolAndPeriod(const long chart_ID=0, // チャート識別子(チャートオブジェクト識別子ではない)
const string name="Chart", // オブジェクト名
const string symbol="EURUSD", // シンボル
const ENUM_TIMEFRAMES period=PERIOD_H1) // 時間軸
{
//--- エラー値をリセットする
ResetLastError();
//--- チャートオブジェクトのシンボルと時間軸を設定する
if(!ObjectSetString(chart_ID,name,OBJPROP_SYMBOL,symbol))
{
Print(__FUNCTION__,
": failed to set a symbol for \"Chart\" object! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_PERIOD,period))
{
Print(__FUNCTION__,
": failed to set a period for \"Chart\" object! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャートオブジェクトを移動する |
//+------------------------------------------------------------------+
bool ObjectChartMove(const long chart_ID=0, // チャート識別子 (チャートオブジェクト ID ではない)
const string name="Chart", // オブジェクト名
const int x=0, // X 座標
const int y=0) // Y 座標
{
//--- エラー値をリセットする
ResetLastError();
//--- オブジェクトを移動する
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": failed to move X coordinate of \"Chart\" object! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": failed to move Y coordinate of \"Chart\" object! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャートオブジェクトサイズを変更する |
//+------------------------------------------------------------------+
bool ObjectChartChangeSize(const long chart_ID=0, // チャート識別子(チャートオブジェクト ID ではない)
const string name="Chart", // オブジェクト名
const int width=300, // 幅
const int height=200) // 高さ
{
//--- エラー値をリセットする
ResetLastError();
//--- オブジェクトサイズを変更する
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": failed to change the width of \"Chart\" object! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": failed to change the height of \"Chart\" object! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャートオブジェクト ID を返す |
//+------------------------------------------------------------------+
long ObjectChartGetID(const long chart_ID=0, // チャート識別子 (チャートオブジェクト ID ではない)
const string name="Chart") // オブジェクト名
{
//--- チャートオブジェクト ID 取得の変数を準備する
long id=-1;
//--- エラー値をリセットする
ResetLastError();
//--- ID 取得
if(!ObjectGetInteger(chart_ID,name,OBJPROP_CHART_ID,0,id))
{
Print(__FUNCTION__,
": failed to get \"Chart\" object's ID! Error code = ",GetLastError());
}
//--- 結果を返す
return(id);
}
//+------------------------------------------------------------------+
//| チャートオブジェクトを削除する |
//+------------------------------------------------------------------+
bool ObjectChartDelete(const long chart_ID=0, // チャート識別子 (チャートオブジェクト ID ではない)
const string name="Chart") // オブジェクト名
{
//--- エラー値をリセットする
ResetLastError();
//--- ボタンを削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete \"Chart\" object! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 「気配値表示」でのシンボル数を取得
int symbols=SymbolsTotal(true);
//--- 指定された名称のシンボルがシンボルのリストに存在するかどうかをチェックする
bool exist=false;
for(int i=0;i<symbols;i++)
if(InpSymbol==SymbolName(i,true))
{
exist=true;
break;
}
if(!exist)
{
Print("Error!",InpSymbol," symbol is not present in \"「気配値表示」\"!");
return;
}
//--- 入力パラメータの有効性をチェックする
if(InpScale<0 || InpScale>5)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- チャートウィンドウサイズ
long x_distance;
long y_distance;
//--- ウィンドウサイズを設定する
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("Failed to get the chart width! Error code = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("Failed to get the chart height! Error code = ",GetLastError());
return;
}
//--- チャートオブジェクトの座標とサイズを設定する
int x=(int)x_distance/16;
int y=(int)y_distance/16;
int x_size=(int)x_distance*7/16;
int y_size=(int)y_distance*7/16;
//--- チャートオブジェクトを作成する
if(!ObjectChartCreate(0,InpName,0,InpSymbol,InpPeriod,x,y,x_size,y_size,InpCorner,InpScale,InpDateScale,
InpPriceScale,InpColor,InpStyle,InpPointWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- チャートを再描画して 1 秒待つ
ChartRedraw();
Sleep(1000);
//--- チャートオブジェクトをスケッチする
int steps=(int)MathMin(x_distance*7/16,y_distance*7/16);
for(int i=0;i<steps;i++)
{
//--- サイズ変更
x_size+=1;
y_size+=1;
if(!ObjectChartChangeSize(0,InpName,x_size,y_size))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画して 0.01 秒待つ
ChartRedraw();
Sleep(10);
}
//--- 半秒の遅れ
Sleep(500);
//--- チャートの時間軸を変更する
if(!ObjectChartSetSymbolAndPeriod(0,InpName,InpSymbol,PERIOD_M1))
return;
ChartRedraw();
//--- 3 秒の遅れ
Sleep(3000);
//--- オブジェクトを削除する
ObjectChartDelete(0,InpName);
ChartRedraw();
//---1 秒待つ
Sleep(1000);
//---
}
|