OBJ_ARROW_RIGHT_PRICE

右プライスラベル

ObjArrowRightPrice

次のスクリプトは、チャート上で右プライスラベルを作成して移動します。グラフィックオブジェクトのプロパティを作成そして変更するために特別な関数が開発されています。これらの関数はお使いのアプリケーションでそのまま使用することが出来ます。

 

//--- 説明
#property description "Script creates the right price label on the chart."
#property description "Anchor point coordinate is set in"
#property description "percentage of the chart window size."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string           InpName="RightPrice"; // 価格ラベル名
input int               InpDate=0;           // アンカーポイントの日付( % )
input int               InpPrice=90;         // アンカーポイントの価格( % )
input color             InpColor=clrRed;     // 価格ラベルの色
input ENUM_LINE_STYLE   InpStyle=STYLE_SOLID; // 境界線のスタイル
input int               InpWidth=2;           // 価格ラベルのサイズ
input bool             InpBack=false;       // 背景ラベル
input bool             InpSelection=true;   // 強調表示して移動
input bool             InpHidden=true;       // オブジェクトリストに隠す
input long             InpZOrder=0;         // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| 右プライスラベルを作成する                                               |
//+------------------------------------------------------------------+
bool ArrowRightPriceCreate(const long            chart_ID=0,       // チャート識別子
                          const string          name="RightPrice", // 価格ラベル名
                          const int             sub_window=0,     // サブウィンドウ番号
                          datetime              time=0,           // アンカーポイントの時刻
                          double                price=0,           // アンカーポイントの価格
                          const color           clr=clrRed,       // 価格ラベルの色
                          const ENUM_LINE_STYLE style=STYLE_SOLID, // 境界線のスタイル
                          const int             width=1,           // 価格ラベルのサイズ
                          const bool            back=false,       // 背景で表示する
                          const bool            selection=true,   // 強調表示して移動
                          const bool            hidden=true,       // オブジェクトリストに隠す
                          const long            z_order=0)         // マウスクリックの優先順位
 {
//--- 設定されてない場合アンカーポイントの座標を設定する
  ChangeArrowEmptyPoint(time,price);
//--- エラー値をリセットする
  ResetLastError();
//--- 価格ラベルを作成する
  if(!ObjectCreate(chart_ID,name,OBJ_ARROW_RIGHT_PRICE,sub_window,time,price))
    {
    Print(__FUNCTION__,
          ": failed to create the right price label! Error code = ",GetLastError());
    return(false);
    }
//--- ラベルの色を設定
  ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 境界線のスタイルを設定
  ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- ラベルサイズを設定
  ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 前景(false)または背景(true)に表示
  ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- マウスでラベルを移動させるモードを有効(true)か無効(false)にする
//--- ObjectCreate 関数を使用してグラフィックオブジェクトを作成する際、オブジェクトは
//--- デフォルトではハイライトされたり動かされたり出来ない。このメソッド内では、選択パラメータは
//--- デフォルトでは true でハイライトと移動を可能にする。
  ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
  ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示(true)か表示(false)にする
  ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
  ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| アンカーポイントを移動する                                               |
//+------------------------------------------------------------------+
bool ArrowRightPriceMove(const long   chart_ID=0,       // チャート識別子
                        const string name="RightPrice", // ラベル名
                        datetime     time=0,           // アンカーポイントの時間座標
                        double       price=0)           // アンカーポイントの価格座標
 {
//--- ポイントの位置が設定されていない場合、売値を有する現在足に移動する
  if(!time)
     time=TimeCurrent();
  if(!price)
     price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
  ResetLastError();
//--- アンカーポイントを移動する
  if(!ObjectMove(chart_ID,name,0,time,price))
    {
    Print(__FUNCTION__,
          ": failed to move the anchor point! Error code = ",GetLastError());
    return(false);
    }
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| 右プライスラベルをチャートから削除する                                       |
//+------------------------------------------------------------------+
bool ArrowRightPriceDelete(const long   chart_ID=0,       // チャート識別子
                          const string name="RightPrice") // ラベル名
 {
//--- エラー値をリセットする
  ResetLastError();
//--- ラベルを削除する
  if(!ObjectDelete(chart_ID,name))
    {
    Print(__FUNCTION__,
          ": failed to delete the right price label! Error code = ",GetLastError());
    return(false);
    }
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| アンカーポイントの値をチェックして                                           |
//| 空の物には初期値を設定する                                             |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
 {
//--- ポイントの時間が設定されていない場合、現在足になる
  if(!time)
     time=TimeCurrent();
//--- ポイントの価格が設定されていない場合、売値になる
  if(!price)
     price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
 }
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
//--- 入力パラメータの正しさをチェックする
  if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
    {
    Print("Error! Incorrect values of input parameters!");
    return;
    }
//--- チャートウィンドウで表示されているバーの数
  int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 価格配列サイズ
  int accuracy=1000;
//--- アンカーポイントの座標の設定と変更に使用される日付と
//--- 価格の値を格納するための配列
  datetime date[];
  double   price[];
//--- メモリ割り当て
  ArrayResize(date,bars);
  ArrayResize(price,accuracy);
//--- 日付配列に書き込む
  ResetLastError();
  if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
    {
    Print("Failed to copy time values! Error code = ",GetLastError());
    return;
    }
//--- 価格配列に書き込む
//--- チャートの最高値と最安値を見つける
  double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
  double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 価格の変更ステップを定義し、配列に書き込む
  double step=(max_price-min_price)/accuracy;
  for(int i=0;i<accuracy;i++)
     price[i]=min_price+i*step;
//--- ラベル描画のポイントを定義する
  int d=InpDate*(bars-1)/100;
  int p=InpPrice*(accuracy-1)/100;
//--- 右プライスラベルをチャートに作成する
  if(!ArrowRightPriceCreate(0,InpName,0,date[d],price[p],InpColor,
    InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
    {
    return;
    }
//--- チャートを再描画して 1 秒待つ
  ChartRedraw();
  Sleep(1000);
//--- アンカーポイントを移動する
//--- ループカウンタ
  int v_steps=accuracy*4/5;
//--- アンカーポイントを移動する
  for(int i=0;i<v_steps;i++)
    {
    //--- 次の値を使用する
    if(p>1)
        p-=1;
    //--- ポイントを移動する
    if(!ArrowRightPriceMove(0,InpName,date[d],price[p]))
        return;
    //--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
    if(IsStopped())
        return;
    //--- チャートを再描画する
    ChartRedraw();
    }
//--- 1 秒の遅れ
  Sleep(1000);
//--- チャートからラベルを削除する
  ArrowRightPriceDelete(0,InpName);
  ChartRedraw();
//--- 1 秒の遅れ
  Sleep(1000);
//---
 }