//--- 説明
#property description "Script draws \"Horizontal Line\" graphical object."
#property description "Anchor point price is set in percentage of the height of"
#property description "the chart window."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string InpName="HLine"; // 線の名称
input int InpPrice=25; // % で表された線の価格
input color InpColor=clrRed; // 線の色
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // 線のスタイル
input int InpWidth=3; // 線の幅
input bool InpBack=false; // 背景の線
input bool InpSelection=true; // 強調表示して移動
input bool InpHidden=true; // オブジェクトリストに隠す
input long InpZOrder=0; // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| 水平線を作成する |
//+------------------------------------------------------------------+
bool HLineCreate(const long chart_ID=0, // チャート識別子
const string name="HLine", // 線の名称
const int sub_window=0, // サブウィンドウ番号
double price=0, // 線の価格
const color clr=clrRed, // 線の色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 線のスタイル
const int width=1, // 線の幅
const bool back=false, // 背景で表示する
const bool selection=true, // 強調表示して移動
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- 価格が設定されていない場合、現在の売値レベルで設定する
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
ResetLastError();
//--- 水平線を作成する
if(!ObjectCreate(chart_ID,name,OBJ_HLINE,sub_window,0,price))
{
Print(__FUNCTION__,
": failed to create a horizontal line! Error code = ",GetLastError());
return(false);
}
//--- 線の色を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 線の表示スタイルを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 線の幅を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 前景(false)または背景(true)に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- マウスで線を移動させるモードを有効(true)か無効(false)にする
//--- ObjectCreate 関数を使用してグラフィックオブジェクトを作成する際、オブジェクトは
//--- デフォルトではハイライトされたり動かされたり出来ない。このメソッド内では、選択パラメータは
//--- デフォルトでは true でハイライトと移動を可能にする。
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示(true)か表示(false)にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| 水平線を移動する |
//+------------------------------------------------------------------+
bool HLineMove(const long chart_ID=0, // チャート識別子
const string name="HLine", // 線の名称
double price=0) // 線の価格
{
//--- 価格が設定されていない場合、現在の売値レベルへ移す
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
ResetLastError();
//--- 水平線を移動する
if(!ObjectMove(chart_ID,name,0,0,price))
{
Print(__FUNCTION__,
": failed to move the horizontal line! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| 水平線を削除する |
//+------------------------------------------------------------------+
bool HLineDelete(const long chart_ID=0, // チャート識別子
const string name="HLine") // 線の名称
{
//--- エラー値をリセットする
ResetLastError();
//--- 水平線を削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete a horizontal line! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 入力パラメータの正しさをチェックする
if(InpPrice<0 || InpPrice>100)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- 価格配列サイズ
int accuracy=1000;
//--- アンカーポイントの座標の設定と変更に使用される
//--- 価格の値を格納するための配列
double price[];
//--- メモリ割り当て
ArrayResize(price,accuracy);
//--- 価格配列に書き込む
//--- チャートの最高値と最安値を見つける
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 価格の変更ステップを定義し、配列に書き込む
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 線を描画するポイントを定義する
int p=InpPrice*(accuracy-1)/100;
//--- 水平線を作成する
if(!HLineCreate(0,InpName,0,price[p],InpColor,InpStyle,InpWidth,InpBack,
InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- チャートを再描画して 1 秒待つ
ChartRedraw();
Sleep(1000);
//--- 線を移動する
//--- ループカウンタ
int v_steps=accuracy/2;
//--- 線を移動する
for(int i=0;i<v_steps;i++)
{
//--- 次の値を使用する
if(p<accuracy-1)
p+=1;
//--- ポイントを移動する
if(!HLineMove(0,InpName,price[p]))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
}
//--- 1 秒の遅れ
Sleep(1000);
//--- チャートから削除する
HLineDelete(0,InpName);
ChartRedraw();
//--- 1 秒の遅れ
Sleep(1000);
//---
}
|