OBJ_GANNLINE

ギャンライン

ObjGannLine

注意事項

ギャンラインでは継続のモードを右及び/または左に指定することが出来ます(OBJPROP_RAY_RIGHT 及び OBJPROP_RAY_LEFT プロパティ)。

スケールを持ったギャン角度及び第2アンカー点の座標の両方が、線の傾きを設定するために使用出来ます。

次のスクリプトは、チャート上でギャンラインを作成して移動します。グラフィックオブジェクトのプロパティを作成そして変更するために特別な関数が開発されています。これらの関数はお使いのアプリケーションでそのまま使用することが出来ます。

 

//--- 説明
#property description "Script draws \"Gann Line\" graphical object."
#property description "Anchor point coordinates are set in percentage of"
#property description "the chart window size."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string         InpName="GannLine";       // 線の名称
input int             InpDate1=20;               // 1 番目のポイントの日付( % )
input int             InpPrice1=75;             // 1 番目のポイントの価格( % )
input int             InpDate2=80;               // 2 番目のポイントの日付( % )
input double         InpAngle=0.0;             // ギャン角度
input double         InpScale=1.0;             // 規模
input color           InpColor=clrRed;           // 線の色
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // 線のスタイル
input int             InpWidth=2;               // 線の幅
input bool           InpBack=false;             // 背景の線
input bool           InpSelection=true;         // 強調表示して移動
input bool           InpRayLeft=false;         // 線の左への継続
input bool           InpRayRight=true;         // 線の右への継続
input bool           InpHidden=true;           // オブジェクトリストに隠す
input long           InpZOrder=0;               // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| 与えられた座標、角度とスケールでギャンラインを作成する                           |
//+------------------------------------------------------------------+
bool GannLineCreate(const long            chart_ID=0,       // チャート識別子
                  const string          name="GannLine",   // 線の名称
                  const int             sub_window=0,     // サブウィンドウ番号
                  datetime              time1=0,           // 1 番目のポイントの時間
                  double                price1=0,         // 1 番目のポイントの価格
                  datetime              time2=0,           // 2 番目のポイントの時間
                  const double          angle=1.0,         // ギャン角度
                  const double          scale=1.0,         // 規模
                  const color           clr=clrRed,       // 線の色
                  const ENUM_LINE_STYLE style=STYLE_SOLID, // 線のスタイル
                  const int             width=1,           // 線の幅
                  const bool            back=false,       // 背景で表示する
                  const bool            selection=true,   // 強調表示して移動
                  const bool            ray_left=false,   // 線の左への継続
                  const bool            ray_right=true,   // 線の右への継続
                  const bool            hidden=true,       // オブジェクトリストに隠す
                  const long            z_order=0)         // マウスクリックの優先順位
 {
//--- 設定されてない場合アンカーポイントの座標を設定する
  ChangeGannLineEmptyPoints(time1,price1,time2);
//--- エラー値をリセットする
  ResetLastError();
//--- 与えられた座標でギャンラインを作成する
//--- 第2アンカー点の正しい座標は
//--- ギャン角度及び/または規模の変更後に自動的に再定義される
  if(!ObjectCreate(chart_ID,name,OBJ_GANNLINE,sub_window,time1,price1,time2,0))
    {
    Print(__FUNCTION__,
          ": failed to create \"Gann Line\"! Error code = ",GetLastError());
    return(false);
    }
//--- ギャン角度を変更する
  ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- スケール(バーあたりのピップ数)を変更する
  ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- 線の色を設定する
  ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 線の表示スタイルを設定する
  ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 線の幅を設定する
  ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 前景(false)または背景(true)に表示
  ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 強調表示して線を移動するモードを有効(true)か無効(false)にする
//--- ObjectCreate 関数を使用してグラフィックオブジェクトを作成する際、オブジェクトは
//--- デフォルトではハイライトされたり動かされたり出来ない。このメソッド内では、選択パラメータは
//--- デフォルトでは true でハイライトと移動を可能にする。
  ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
  ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 線の表示を左に延長するモードを有効(true)か無効(false)にする
  ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- 線の表示を右に延長するモードを有効(true)か無効(false)にする
  ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- オブジェクトリストのグラフィックオブジェクトを非表示(true)か表示(false)にする
  ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
  ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| ギャンラインのアンカーポイントを移動する                                      |
//+------------------------------------------------------------------+
bool GannLinePointChange(const long   chart_ID=0,     // チャート識別子
                        const string name="GannLine", // 線の名称
                        const int    point_index=0,   // アンカーポイントのインデックス
                        datetime     time=0,         // アンカーポイントの時間座標
                        double       price=0)         // アンカーポイントの価格座標
 {
//--- ポイントの位置が設定されていない場合、売値を有する現在足に移動する
  if(!time)
     time=TimeCurrent();
  if(!price)
     price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
  ResetLastError();
//--- 線のアンカーポイントを移動する   
  if(!ObjectMove(chart_ID,name,point_index,time,price))
    {
    Print(__FUNCTION__,
          ": failed to move the anchor point! Error code = ",GetLastError());
    return(false);
    }
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| ギャン角度を変更する                                                  |
//+------------------------------------------------------------------+
bool GannLineAngleChange(const long   chart_ID=0,     // チャート識別子
                        const string name="GannLine", // 線の名称
                        const double angle=1.0)       // ギャン角度
 {
//--- エラー値をリセットする
  ResetLastError();
//--- ギャン角度を変更する
  if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
    {
    Print(__FUNCTION__,
          ": failed to change Gann angle! Error code = ",GetLastError());
    return(false);
    }
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| ギャンラインの規模を変更する                                             |
//+------------------------------------------------------------------+
bool GannLineScaleChange(const long   chart_ID=0,     // チャート識別子
                        const string name="GannLine", // 線の名称
                        const double scale=1.0)       // 規模
 {
//--- エラー値をリセットする
  ResetLastError();
//--- スケール(バーあたりのピップ数)を変更する
  if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
    {
    Print(__FUNCTION__,
          ": failed to change the scale! Error code = ",GetLastError());
    return(false);
    }
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| この関数はチャートからギャンラインを削除する                                   |
//+------------------------------------------------------------------+
bool GannLineDelete(const long   chart_ID=0,     // チャート識別子
                  const string name="GannLine") // 線の名称
 {
//--- エラー値をリセットする
  ResetLastError();
//--- ギャンラインを削除する
  if(!ObjectDelete(chart_ID,name))
    {
    Print(__FUNCTION__,
          ": failed to delete \"Gann Line\"! Error code = ",GetLastError());
    return(false);
    }
//--- 実行成功
  return(true);
 }
//+------------------------------------------------------------------+
//| ギャンラインのアンカーポイントの値をチェックして                                  |
//| 空の物には初期値を設定する                                             |
//+------------------------------------------------------------------+
void ChangeGannLineEmptyPoints(datetime &time1,double &price1,datetime &time2)
 {
//--- 2 番目のポイントの時間が設定されていない場合、現在足になる
  if(!time2)
     time2=TimeCurrent();
//--- 1 番目のポイントの時間が設定されていない場合、2 番目から 9 バー左に置かれる
  if(!time1)
    {
    //--- 最後の 10 バーのオープン時間を受信するための配列
    datetime temp[10];
    CopyTime(Symbol(),Period(),time2,10,temp);
    //--- 1 番目のポイントを 2 番目から 9 バー左に設定する
     time1=temp[0];
    }
//--- 1 番目のポイントの価格が設定されていない場合、売値になる
  if(!price1)
     price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
 }
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
//--- 入力パラメータの正しさをチェックする
  if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
    InpDate2<0 || InpDate2>100)
    {
    Print("Error! Incorrect values of input parameters!");
    return;
    }
//--- チャートウィンドウで表示されているバーの数
  int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 価格配列サイズ
  int accuracy=1000;
//--- アンカーポイントの座標の設定と変更に使用される日付と
//--- 価格の値を格納するための配列
  datetime date[];
  double   price[];
//--- メモリ割り当て
  ArrayResize(date,bars);
  ArrayResize(price,accuracy);
//--- 日付配列に書き込む
  ResetLastError();
  if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
    {
    Print("Failed to copy time values! Error code = ",GetLastError());
    return;
    }
//--- 価格配列に書き込む
//--- チャートの最高値と最安値を見つける
  double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
  double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 価格の変更ステップを定義し、配列に書き込む
  double step=(max_price-min_price)/accuracy;
  for(int i=0;i<accuracy;i++)
     price[i]=min_price+i*step;
//--- ギャンライン描画のポイントを定義する
  int d1=InpDate1*(bars-1)/100;
  int d2=InpDate2*(bars-1)/100;
  int p1=InpPrice1*(accuracy-1)/100;
//--- ギャンラインを作成する
  if(!GannLineCreate(0,InpName,0,date[d1],price[p1],date[d2],InpAngle,InpScale,InpColor,
    InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
    {
    return;
    }
//--- チャートを再描画して 1 秒待つ
  ChartRedraw();
  Sleep(1000);
//--- 線のアンカーポイントを移動して角度を変更する
//--- ループカウンタ
  int v_steps=accuracy/2;
//--- 1 番目のアンカーポイントを垂直方向に移動する
  for(int i=0;i<v_steps;i++)
    {
    //--- 次の値を使用する
    if(p1>1)
        p1-=1;
    //--- ポイントを移動する
    if(!GannLinePointChange(0,InpName,0,date[d1],price[p1]))
        return;
    //--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
    if(IsStopped())
        return;
    //--- チャートを再描画する
    ChartRedraw();
    }
//--- 半秒の遅れ
  Sleep(500);
//--- ギャン角度の現在値を定義する
//--- (最初のアンカーポイントを移動した後に変更された)
  double curr_angle;
  if(!ObjectGetDouble(0,InpName,OBJPROP_ANGLE,0,curr_angle))
    return;
//--- ループカウンタ
  v_steps=accuracy/8;
//--- ギャン角度を変更する
  for(int i=0;i<v_steps;i++)
    {
    if(!GannLineAngleChange(0,InpName,curr_angle-0.05*i))
        return;
    //--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
    if(IsStopped())
        return;
    //--- チャートを再描画する
    ChartRedraw();
    }
//--- 1 秒の遅れ
  Sleep(1000);
//--- チャートから線を削除する
  GannLineDelete(0,InpName);
  ChartRedraw();
//--- 1 秒の遅れ
  Sleep(1000);
//---
 }