//+------------------------------------------------------------------+
//| Demo_FileWriteLong.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
//--- montrons la fenêtre des paramètres d'entrée au lancement du script
#property script_show_inputs
//--- les paramètres pour la réception des données du terminal
input string InpSymbolName="EURUSD"; // la paire de devise
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_H1; // le temps trame
input datetime InpDateStart=D'2013.01.01 00:00'; // la date de commencement du copiage des données
//--- les paramètres pour l'enregistrement des données au fichier
input string InpFileName="Volume.bin"; // le nom du fichier
input string InpDirectoryName="Data"; // le nom du répertoire
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date_finish=TimeCurrent();
long volume_buff[];
datetime time_buff[];
int size;
//--- oblitérons la valeur de l'erreur
ResetLastError();
//--- copions les volumes de tick pour chaque barre
if(CopyTickVolume(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,volume_buff)==-1)
{
PrintFormat("On n'a pas réussi de copier les valeurs du volume de tick. Le code de l'erreur = %d",GetLastError());
return;
}
//---copions le temps pour chaque barre
if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
{
PrintFormat("On n'a pas réussi de copier les valeurs du temps. Le code de l'erreur = %d",GetLastError());
return;
}
//--- recevrons la taille du tampon
size=ArraySize(volume_buff);
//--- ouvrirons le fichier pour l'enregistrement des valeurs de l'indicateur (s'il n'existe pas, il sera créé automatiquement)
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("Le fichier %s est ouvert pour l'enregistrement",InpFileName);
PrintFormat("La voie vers le fichier: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
//--- d'abord enregistrons la taille de l'extrait des données
FileWriteLong(file_handle,(long)size);
//--- enregistrons le temps et les valeurs du volume au fichier
for(int i=0;i<size;i++)
{
FileWriteLong(file_handle,(long)time_buff[i]);
FileWriteLong(file_handle,volume_buff[i]);
}
//--- fermons le fichier
FileClose(file_handle);
PrintFormat("Les données sont enregistrés, le fichier %s est fermé",InpFileName);
}
else
PrintFormat("On n'a pas réussi d'ouvrir le fichier %s, Le code de l'erreur = %d",InpFileName,GetLastError());
}
|