FileWriteFloat

Dosya işaretçisinin geçerli konumundan başlayarak float tipindeki parametrenin değerini ikili dosyaya yazar.

Dosya işaretçisinin geçerli konumundan başlayarak float tipindeki parametrenin metne dönüştürülmüş değerini CSV veya metin dosyasına yazar.

uint  FileWriteFloat(
   int    file_handle,     // Dosya tanıtıcısı
   float  value            // Yazılacak değer
   );

Parametreler

file_handle

[in] FileOpen() fonksiyonunun dönüş yaptığı dosya tanımlayıcısı.

value

[in] float tipli değer.

Dönüş değeri

Başarılı olursa fonksiyon yazılan bayt sayısını döndürür (ikili dosyaya yazarken — sizeof(float)=4). Dosya işaretçisi aynı bayt sayısı kadar hareket eder.

Not

İkili dosyaya yazma durumunda, float tipinde bir parametreyle FileWrite fonksiyonunu çağırmaya eşdeğerdir

float float_value;
FileWrite(file_handle,float_value);

Örnek:

//+------------------------------------------------------------------+
//|                                          Demo_FileWriteFloat.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- script çalıştığında giriş parametrelerinin penceresini göster
#property script_show_inputs
//--- terminalden veri alımı için parametreler
input string          InpSymbolName="EURUSD";           // döviz çifti
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_M15;       // zaman aralığı
input datetime        InpDateStart=D'2013.01.01 00:00'; // veri kopyalamanın başlangıç tarihi
//--- verinin dosyaya yazılması için gereken parametreler
input string          InpFileName="Close.bin"; // dosya ismi
input string          InpDirectoryName="Data"; // dizin ismi
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish=TimeCurrent();
   double   close_buff[];
   datetime time_buff[];
   int      size;
//--- hata değerini sıfırla
   ResetLastError();
//--- her bir çubuğun kapanış fiyatını kopyala
   if(CopyClose(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,close_buff)==-1)
     {
      PrintFormat("Kapanış fiyatları kopyalanamadı. Hata kodu = %d",GetLastError());
      return;
     }
//--- her bir çubuk için zamanı kopyala
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
     {
      PrintFormat("Zaman değerleri kopyalanamadı. Hata kodu = %d",GetLastError());
      return;
     }
//--- tampon büyüklüğünü al
   size=ArraySize(close_buff);
//--- değerlerin yazılacağı dosyayı aç (dosya mevcut değilse, otomatik olarak oluşturulacak)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s dosyası, yazma amacıyla açıldı",InpFileName);
      PrintFormat("Dosya yolu: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- kapanış fiyatı değerlerini ve zamanlarını yaz
      for(int i=0;i<size;i++)
        {
         FileWriteDouble(file_handle,(double)time_buff[i]);
         FileWriteFloat(file_handle,(float)close_buff[i]);
        }
      //--- dosyayı kapat
      FileClose(file_handle);
      PrintFormat("Veri yazıldı, %s dosyası kapatıldı",InpFileName);
     }
   else
      PrintFormat("%s dosyası açılamadı, Hata kodu = %d",InpFileName,GetLastError());
  }

Ayrıca Bakınız

Reel tipler (double, float), FileWriteDouble