ChartTimePriceToXY

bool  ChartTimePriceToXY(
   long           chart_id,     // Çizelge tanımlayıcı
   int            sub_window,   // Alt pencerenin numarası
   datetime       time,         // Çizelge üstündeki zaman
   double         price,        // Çizelge üstündeki fiyat
   int&           x,            // Çizelge üstündeki zaman için X koordinatı
   int&           y             // Çizelge üstündeki fiyat için Y koordinatı
   );

#define   BAR_NUMBER    0  // fiyatı ve zamanı aldığımız çubuğun numarası
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- BAR_NUMBER indeksine göre tek bir çubuğun verilerini kopyala
   MqlRates rates[]={};
   if(CopyRates(_Symbol, _Period, BAR_NUMBER, 1, rates)!=1)
     {
      PrintFormat("CopyRates() failed for bar %d. Error %d", BAR_NUMBER, GetLastError());
      return;
     }
       
//--- elde edilen fiyat ve zamanı grafik piksel koordinatlarına dönüştür
   int x=0, y=0;
   ResetLastError();
   if(!ChartTimePriceToXY(ChartID(), 0, rates[0].time, rates[0].close, x, y))
     {
      Print("ChartTimePriceToXY() failed. Error ", GetLastError());
      return;
     }
     
//--- elde edilen sonucu günlüğe yazdır
   PrintFormat("For bar[%d] with opening time %s and price %.*f, the chart coordinates are x: %d, y: %d", BAR_NUMBER, TimeToString(rates[0].time), _Digits, rates[0].close, x, y);
   
   /*
   sonuç:
   For bar[0] with opening time 2024.08.09 15:06 and price 1.27378, the chart coordinates are x: 784, y: 240
   */
  }