DokümantasyonBölümler
MQL5 ReferansıÇizelge İşlemleriChartIndicatorName 

ChartIndicatorName

Belirtilen çizelge penceresinin göstergeler listesindeki numaraları kullanarak, göstergenin kısa ismine dönüş yapar.

string  ChartIndicatorName(
   long  chart_id,      // çizelge tanımlayıcısı
   int   sub_window     // alt pencerenin numarası
   int   index          // çizelgenin gösterge listesindeki gösterge indisi
   );

Parametreler

chart_id

[in]  Çizelge tanımlayıcısı. 0 mevcut çizelgeyi ifade eder.

sub_window

[in]  Çizelge alt penceresinin indisi. 0 ana çizelge penceresini tanımlar.

index

[in]  Göstergenin, gösterge listesindeki indisi. Göstergelerin numaralanması sıfırdan başlar, yani listedeki ilk gösterge 0 indisine sahip olacaktır. Listedeki göstergelerin sayısına ulaşmak için ChartIndicatorsTotal() fonksiyonunu kullanın.

Dönüş değeri

INDICATOR_SHORTNAME özelliği ile IndicatorSetString() fonksiyonu kullanılarak ayarlanan gösterge kısa ismi. Hata detayları için GetLastError() fonksiyonunu kullanın.

Not

Gösterge oluşturulurken iCustom() ve IndicatorCreate() fonksiyonları aracılığıyla belirlermiş dosya ismi ile gösterge kısa ismini birbirine karıştırmayın. Eğer göstergenin ismi açık yoldan ayarlanmamışsa, derleme sırasında, gösterge kaynak kodunu içeren dosyanın ismi, kısa isim olarak belirlenecektir.

Gösterge kısa ismi, düzgün şekilde girilmelidir. Bu, INDICATOR_SHORTNAME özelliğine, IndicatorSetString() fonksiyonu kullanılarak yazılır. Kısa isimde, gösterge parametre değerlerinin içerilmesi önerilir; çünkü çizelge penceresinden göstergeyi silerken kullanılan ChartIndicatorDelete() fonksiyonu kısa isimle tanımlanır.

Örnek:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- mevcut grafik kimliğini ve ana pencere de dahil olmak üzere alt pencerelerinin sayısını al
   long chart_id = ChartID();
   int  wnd_total= (int)ChartGetInteger(0,CHART_WINDOWS_TOTAL);
   
//--- bir döngü içinde tüm mevcut grafik pencereleri üzerinde yineleme yap
   for(int w=0; w<wnd_total; w++)
     {
      //--- döngü indeksi tarafından belirtilen grafik penceresine eklenmiş göstergelerin sayısını al
      int ind_total=ChartIndicatorsTotal(chart_id, w);
      
      //--- seçili grafik penceresi için başlığı yazdır
      PrintFormat("Chart window %d indicators: ", w);
      
      //--- döngüye gir ve seçilen pencereye bağlı tüm göstergelerin adlarını değişkene yaz
      string ind_names="";
      for(int i=0; i<ind_total; i++)
        {
         ind_names+="  "+ChartIndicatorName(chart_id, w, i)+(i<ind_total-1 ? "\n": "");
        }
      //--- belirtilen grafik penceresine eklenmiş tüm göstergelerin adlarının elde edilen listesini günlüğe yazdır
      Print(ind_names);
     }
   /*
   sonuç:
   Chart window 0 indicators: 
     AMA(9,2,30)
     SAR(0.02,0.20)
     Fractals
   Chart window 1 indicators: 
     RSI(14)
     AMA(9,2,30)
   Chart window 2 indicators: 
     MFI(14)
   */
  }

Ayrıca Bakınız

ChartIndicatorAdd(), ChartIndicatorDelete(), ChartIndicatorsTotal(), iCustom(), IndicatorCreate(), IndicatorSetString()