ДокументацияРазделы
Справочник MQL5Торговые функцииPositionGetString 

PositionGetString

Функция возвращает запрошенное свойство открытой позиции, предварительно выбранной при помощи функции PositionGetSymbol или PositionSelect. Свойство позиции должно быть типа string. Существует 2 варианта функции.

1. Непосредственно возвращает значение свойства.

string  PositionGetString(
   ENUM_POSITION_PROPERTY_STRING  property_id      // идентификатор свойства
   );

2. Возвращает true или false в зависимости от успешности выполнения функции.  В случае успеха значение свойства помещается в приемную переменную, передаваемую по ссылке последним параметром.

bool  PositionGetString(
   ENUM_POSITION_PROPERTY_STRING  property_id,     // идентификатор свойства
   string&                        string_var       // сюда примем значение свойства
   );

Параметры

property_id

[in]  Идентификатор свойства позиции. Значение может быть одним из значений перечисления ENUM_POSITION_PROPERTY_STRING.

string_var

[out]  Переменная типа string, принимающая  значение запрашиваемого свойства.

Возвращаемое значение

Значение типа string. В случае неудачного выполнения возвращает пустую строку.

Примечание

При "неттинговом" учете позиций (ACCOUNT_MARGIN_MODE_RETAIL_NETTING и ACCOUNT_MARGIN_MODE_EXCHANGE) по каждому символу в любой момент времени может быть открыта только одна позиция, которая является результатом одной или более сделок. Не следует путать между собой позиции и действующие отложенные ордера, которые также отображаются на вкладке "Торговля" в панели "Инструменты".

При независимом представлении позиций (ACCOUNT_MARGIN_MODE_RETAIL_HEDGING) по каждому символу одновременно может быть открыто несколько позиций.

Для гарантированного получения свежих данных о позиции рекомендуется вызывать функцию PositionSelect() непосредственно перед обращением за ними.

Пример:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- в цикле по всем позициям на счёте
   int total=PositionsTotal();
   for(int i=0; i<total; i++)
     {
      //--- получаем тикет очередной позиции, автоматически выбирая позицию для доступа к её свойствам
      ulong ticket=PositionGetTicket(i);
      if(ticket==0)
         continue;
      
      //--- получаем тип позиции и выводим заголовок для списка строковых свойств позиции
      string type=(PositionGetInteger(POSITION_TYPE)==POSITION_TYPE ? "Buy" : "Sell");
      PrintFormat("String properties of an open position %s #%I64u:", type, ticket);
      
      //--- распечатываем под заголовком все строковые свойства выбранной позиции
      PositionPropertiesStringPrint(15);
     }
   /*
   результат:
   String properties of an open position Buy #2810798881:
   Symbol:        EURUSD
   Comment:       Test PositionGetString
   External ID:   
   */
  }
//+------------------------------------------------------------------+
//| Выводит в журнал строковые свойства выбранной позиции            |
//+------------------------------------------------------------------+
void PositionPropertiesStringPrint(const uint header_width=0)
  {
   uint   w=0;
   string header="";
   string value="";
   
//--- определяем текст заголовка и ширину поля заголовка
//--- если ширина заголовка передана в функцию равной нулю, то шириной будет размер строки заголовка + 1
   header="Symbol:";
   w=(header_width==0 ? header.Length()+1 : header_width);
//--- получаем и выводим в журнал символ позиции с заголовком установленной ширины
   if(!PositionGetString(POSITION_SYMBOL, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
   
//--- выводим в журнал значение комментария позиции
   header="Comment:";
   w=(header_width==0 ? header.Length()+1 : header_width);
   if(!PositionGetString(POSITION_COMMENT, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
   
//--- выводим в журнал значение идентификатора позиции во внешней системе 
   header="External ID:";
   w=(header_width==0 ? header.Length()+1 : header_width);
   if(!PositionGetString(POSITION_EXTERNAL_ID, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
  }

Смотри также

PositionGetSymbol(), PositionSelect(), Свойства позиций