Manual de referencia de MQL5Funciones comercialesPositionGetString

PositionGetString

La función devuelve la propiedad solicitada de una posición abierta que previamente ha sido elegida a través de la función PositionGetSymbol o PositionSelect. La propiedad de la posición tiene que ser del tipo string. Existen 2 variantes de la función.

1. Inmediatamente devuelve el valor de la propiedad.

string  PositionGetString(
   ENUM_POSITION_PROPERTY_STRING  property_id      // identificador de la propiedad
   );

2. Devuelve true o false dependiendo del éxito de ejecución de la función. En caso del éxito el valor de la propiedad se coloca en una variable receptora que el último parámetro pasa por referencia.

bool  PositionGetString(
   ENUM_POSITION_PROPERTY_STRING  property_id,     // identificador de la propiedad
   string&                        string_var       // aquí recibimos el valor de la propiedad
   );

Parámetros

property_id

[in] Identificador de la propiedad de la posición. Su valor puede ser uno de los valores de la enumeración ENUM_POSITION_PROPERTY_STRING.

string_var

[out] Variable del tipo string que recibe el valor de la propiedad requerida.

Valor devuelto

Valor del tipo string.

Nota

En el registro de posiciones con "compensación" (ACCOUNT_MARGIN_MODE_RETAIL_NETTING y ACCOUNT_MARGIN_MODE_EXCHANGE) de cada símbolo en cualquier momento solo puede abrirse una posición, que es el resultado de una o más operaciones. Es mejor no confundir las posiciones con las órdenes pendientes en activo, que también se muestran en la pestaña "Trading" en el panel "Herramientas".

En el caso de que las posiciones se representen independientemente (ACCOUNT_MARGIN_MODE_RETAIL_HEDGING), de cada símbolo pueden abrirse a la vez varias posiciones.

Para garantizar la recepción de datos recientes sobre una posición, se recomienda llamar a la función PositionSelect() justamente antes de solicitarlos.

Ejemplo:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- en un ciclo por todas las posiciones en la cuenta
   int total=PositionsTotal();
   for(int i=0; i<total; i++)
     {
      //--- obtenemos el ticket de la siguiente posición, seleccionando una posición de forma automática para acceder a sus propiedades
      ulong ticket=PositionGetTicket(i);
      if(ticket==0)
         continue;

      //--- obtenemos el tipo de la posición y mostramos el encabezado de la lista de propiedades string de la posición
      string type=(PositionGetInteger(POSITION_TYPE)==POSITION_TYPE ? "Buy" : "Sell");
      PrintFormat("String properties of an open position %s #%I64u:", type, ticket);

      //--- imprimimos bajo el encabezado todas las propiedades string de la posición seleccionada
      PositionPropertiesStringPrint(15);
     }
   /*
   resultado:
   String properties of an open position Buy #2810798881:
   Symbol:        EURUSD
   Comment:       Test PositionGetString
   External ID:
   */
  }
//+------------------------------------------------------------------+
//| Muestra en el registro las propiedades string de la posición seleccionada
//+------------------------------------------------------------------+
void PositionPropertiesStringPrint(const uint header_width=0)
  {
   uint   w=0;
   string header="";
   string value="";

//--- definimos el texto del encabezado y la anchura del campo del encabezado
//--- si la anchura del encabezado se ha transmitido a la función como igual a cero, entonces la anchura será el tamaño de la línea del encabezado + 1
   header="Symbol:";
   w=(header_width==0 ? header.Length()+1 : header_width);
//--- obtenemos y mostramos en el registro el símbolo de la posición con un encabezado de la anchura establecida
   if(!PositionGetString(POSITION_SYMBOL, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);

//--- mostramos en el registro el valor del comentario de la posición
   header="Comment:";
   w=(header_width==0 ? header.Length()+1 : header_width);
   if(!PositionGetString(POSITION_COMMENT, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);

//--- mostramos en el registro el valor del identificador de la posición en el sistema comercial externo
   header="External ID:";
   w=(header_width==0 ? header.Length()+1 : header_width);
   if(!PositionGetString(POSITION_EXTERNAL_ID, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
  }

Véase también

PositionGetSymbol(), PositionSelect(), Propiedades de posiciones

PositionGetInteger

PositionGetTicket