#define DEVIATION 5 // допустимое отклонение от цены
#define VOLUME 1.0 // объем ордера
#define EXPERT_MAGIC 123 // MagicNumber
#define DIRECTION ORDER_TYPE_BUY // направление открываемой позиции (ORDER_TYPE_BUY или ORDER_TYPE_SELL)
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- объявление и инициализация структур запроса, проверки и результата
MqlTradeRequest request={};
MqlTradeCheckResult check ={};
MqlTradeResult result ={};
//--- подготовим параметры торгового запроса
PrepareRequest(_Symbol, DIRECTION, VOLUME, request);
//--- проверим параметры торгового запроса
ResetLastError();
bool res=OrderCheck(request, check);
if(!res)
{
PrintFormat("Trade request verification completed with error %d\nServer retcode: %u, comment: %s", GetLastError(), check.retcode, check.comment);
return;
}
//--- проверка торгового запроса прошла успешно - выведем в журнал описание полей структуры проверки торгового запроса
Print("Trade request verification completed successfully");
MqlTradeCheckResultPrint(check, 14);
//--- отправка торгового запроса
if(!OrderSend(request, result))
Print("OrderSend error ", GetLastError()); // если отправить запрос не удалось, выведем код ошибки
//--- информация об операции
PrintFormat("Trade request result: retcode=%u, deal=%I64u, order=%I64u", result.retcode, result.deal, result.order);
/*
результат с отключенной автоторговлей в клиентском терминале:
Trade request verification completed with error 4752
Server retcode: 10027, comment: AutoTrading disabled by client
включим автоторговлю и проверим ещё раз на закрытом рынке:
Experts automated trading is enabled
Trade request verification completed successfully
Retcode: 0
Balance: 10779.50 USD
Equity: 10779.50 USD
Profit: 0.00 USD
Margin: 1104.79 USD
Margin free: 9674.71 USD
Margin level: 975.71 %
Comment: Done
OrderSend error 4756
Trade request result: retcode=10018, deal=0, order=0
проверим на открытом рынке:
Trade request verification completed successfully
Retcode: 0
Balance: 10779.50 USD
Equity: 10779.50 USD
Profit: 0.00 USD
Margin: 110.46 USD
Margin free: 10669.04 USD
Margin level: 9758.74 %
Comment: Done
Trade request result: retcode=10009, deal=2777010968, order=2802818813
*/
}
//+------------------------------------------------------------------+
//| Подготовка параметров для торгового запроса |
//+------------------------------------------------------------------+
void PrepareRequest(const string symbol, const ENUM_ORDER_TYPE order_type, const double volume, MqlTradeRequest &request)
{
ENUM_ORDER_TYPE type=(DIRECTION !=ORDER_TYPE_BUY ? ORDER_TYPE_SELL : DIRECTION);
double price=(DIRECTION==ORDER_TYPE_BUY ? SymbolInfoDouble(Symbol(), SYMBOL_ASK) : SymbolInfoDouble(Symbol(), SYMBOL_BID));
//--- параметры запроса
request.action = TRADE_ACTION_DEAL; // тип торговой операции
request.symbol = symbol; // символ
request.volume = volume; // объем
request.type = type; // тип ордера
request.price = price; // цена для открытия
request.deviation = DEVIATION; // допустимое отклонение от цены
request.magic = EXPERT_MAGIC; // MagicNumber ордера
}
//+------------------------------------------------------------------+
//| Распечатывает в журнале поля структуры |
//| результата проверки торгового запроса |
//+------------------------------------------------------------------+
void MqlTradeCheckResultPrint(const MqlTradeCheckResult &check, const uint header_width=0)
{
//--- получаем валюту счёта и количество знаков после запятой для валюты счета
string currency=AccountInfoString(ACCOUNT_CURRENCY);
int digits =(int)AccountInfoInteger(ACCOUNT_CURRENCY_DIGITS);
//--- определяем текст заголовка и ширину поля заголовка
//--- если ширина заголовка передана в функцию равной нулю, то шириной будет размер строки заголовка + 1
string header="Retcode:";
uint w=(header_width==0 ? header.Length()+1 : header_width);
//--- выводим в журнал код возврата с заголовком установленной ширины
PrintFormat("%-*s%-u", w, header, check.retcode);
//--- выводим в журнал значение баланса, которое будет после выполнения торговой операции
header="Balance:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.balance, currency);
//--- выводим в журнал значение собственных средств, которое будет после выполнения торговой операции
header="Equity:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.equity, currency);
//--- выводим в журнал значение плавающей прибыли, которое будет после выполнения торговой операции
header="Profit:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.profit, currency);
//--- выводим в журнал размер маржи, необходимый для требуемой торговой операции
header="Margin:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.margin, currency);
//--- выводим в журнал размер свободных собственных средств, которые останутся после выполнения требуемой торговой операции
header="Margin free:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.margin_free, currency);
//--- выводим в журнал уровень маржи, который установится после выполнения требуемой торговой операции
header="Margin level:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.2f %%", w, header, check.margin_level);
//--- выводим в журнал комментарий к коду ответа, описание ошибки
header="Comment:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-s", w, header, check.comment);
}
|