#define DEVIATION 5 // déviation autorisée du prix
#define VOLUME 1.0 // volume de l'ordre
#define EXPERT_MAGIC 123 // MagicNumber
#define DIRECTION ORDER_TYPE_BUY // direction de la position ouverte (ORDER_TYPE_BUY ou ORDER_TYPE_SELL)
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- déclare et initialise les structures de la requête, de la vérification et du résultat
MqlTradeRequest request={};
MqlTradeCheckResult check ={};
MqlTradeResult result ={};
//--- prépare les paramètres de la demande de trade
PrepareRequest(_Symbol, DIRECTION, VOLUME, request);
//--- vérifie les paramètres de la demande de trade
ResetLastError();
bool res=OrderCheck(request, check);
if(!res)
{
PrintFormat("Trade request verification completed with error %d\nServer retcode: %u, comment: %s", GetLastError(), check.retcode, check.comment);
return;
}
//--- la vérification de la demande de trade a réussi - affiche la description des champs de structure de vérification de la demande de trade
Print("Trade request verification completed successfully");
MqlTradeCheckResultPrint(check, 14);
//--- envoie la demande de trade
if(!OrderSend(request, result))
Print("OrderSend error ", GetLastError()); // if unable to send the request, display the error code
//--- information sur l'opération
PrintFormat("Trade request result: retcode=%u, deal=%I64u, order=%I64u", result.retcode, result.deal, result.order);
/*
résultat avec le trading automatique désactivé dans le terminal client :
Trade request verification completed with error 4752
Server retcode: 10027, comment: AutoTrading disabled by client
enable auto trading and check again on a closed market:
Experts automated trading is enabled
Trade request verification completed successfully
Retcode: 0
Balance: 10779.50 USD
Equity: 10779.50 USD
Profit: 0.00 USD
Margin: 1104.79 USD
Margin free: 9674.71 USD
Margin level: 975.71 %
Comment: Done
OrderSend error 4756
Trade request result: retcode=10018, deal=0, order=0
check on the open market:
Trade request verification completed successfully
Retcode: 0
Balance: 10779.50 USD
Equity: 10779.50 USD
Profit: 0.00 USD
Margin: 110.46 USD
Margin free: 10669.04 USD
Margin level: 9758.74 %
Comment: Done
Trade request result: retcode=10009, deal=2777010968, order=2802818813
*/
}
//+------------------------------------------------------------------+
//| Prépare les paramètres pour une demande de trade |
//+------------------------------------------------------------------+
void PrepareRequest(const string symbol, const ENUM_ORDER_TYPE order_type, const double volume, MqlTradeRequest &request)
{
ENUM_ORDER_TYPE type=(DIRECTION !=ORDER_TYPE_BUY ? ORDER_TYPE_SELL : DIRECTION);
double price=(DIRECTION==ORDER_TYPE_BUY ? SymbolInfoDouble(Symbol(), SYMBOL_ASK) : SymbolInfoDouble(Symbol(), SYMBOL_BID));
//--- paramètres de la demande
request.action = TRADE_ACTION_DEAL; // type de l'opération de trading
request.symbol = symbol; // symbole
request.volume = volume; // volume
request.type = type; // type d'ordre
request.price = price; // prix d'ouverture
request.deviation = DEVIATION; // déviation autorisée par rapport au prix
request.magic = EXPERT_MAGIC; // Nombre magique de l'ordre
}
//+------------------------------------------------------------------+
//| Affiche dans le journal les champs du résultat de la |
//| vérification de la demande de trade |
//+------------------------------------------------------------------+
void MqlTradeCheckResultPrint(const MqlTradeCheckResult &check, const uint header_width=0)
{
//--- récupère la devise du compte et le nombre de décimales pour la devise du compte
string currency=AccountInfoString(ACCOUNT_CURRENCY);
int digits =(int)AccountInfoInteger(ACCOUNT_CURRENCY_DIGITS);
//--- définit le texte d'en-tête et la largeur du champ d'en-tête
//--- si la largeur de l'en-tête est passée à la fonction égale à zéro, alors la largeur sera la taille de la ligne d'en-tête + 1
string header="Retcode:";
uint w=(header_width==0 ? header.Length()+1 : header_width);
//--- affiche dans le journal le code retour avec l'en-tête de la largeur spécifiée
PrintFormat("%-*s%-u", w, header, check.retcode);
//--- affiche dans le journal la valeur du solde après avoir exécuté une opération de trading
header="Balance:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.balance, currency);
//--- affiche dans le journal la valeur des capitaux propres après avoir exécuté une opération de trading
header="Equity:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.equity, currency);
//--- affiche dans le journal la valeur du profit flottant après avoir exécuté une opération de trading
header="Profit:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.profit, currency);
//--- affiche dans le journal le montant de la marge, nécessaire à l'opération de trading nécessaire
header="Margin:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.margin, currency);
//--- affiche dans le journal la valeur des capitaux propres restant après avoir effectué une opération de trading
header="Margin free:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.*f %s", w, header, digits, check.margin_free, currency);
//--- affiche dans le journal le niveau de marge à définir après avoir terminé l'opération de trading requise
header="Margin level:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-.2f %%", w, header, check.margin_level);
//--- affiche dans le journal le commentaire sur le code de réponse et la description de l'erreur
header="Comment:";
w=(header_width==0 ? header.Length()+1 : header_width);
PrintFormat("%-*s%-s", w, header, check.comment);
}
|