Скачать MetaTrader 5

Пошаговое руководство по написанию MQL5-советников для начинающих

9 июня 2010, 11:43
Samuel Olowoyo
86
73 109

Введение

Эта статья предназначена для начинающих, для тех, кто хочет научиться написанию простых советников на новом языке MQL5. Сначала мы определимся с тем, что требуется от нашего советника, а затем приступим к написанию того, каким образом он будет это делать.


1. Торговая стратегия

Что будет делать наш советник:

  • Он будет следить за некоторыми индикаторами и при определенном условии (или условиях) помещать торговый запрос (на продажу или покупку) в зависимости от условий.

Это называется торговой стратегией. Перед тем, как писать советник, сначала нужно разработать стратегию, которую вы хотите автоматизировать в советнике. Давайте конкретизируем нашу стратегию, которую будем применять в советнике.

  1. Мы будем использовать индикатор Moving Average (скользящие средние) с периодом 8 (вы можете выбрать любой период, но в данной стратегии мы будем использовать период 8).
  2. Мы хотим, чтобы наш советник покупал, если 8-периодная скользящая средняя (далее для удобства будем называть ее MA-8) возрастает и текущая цена закрытия находится выше ее; советник должен продавать, когда MA-8 падает и цена закрытия находится ниже MA-8.
  3. Также мы собираемся использовать другой индикатор, называемый Average Directional Movement (ADX) с периодом 8 для определения факта наличия тренда на рынке. Это нужно для того, чтобы входить в рынок, когда он находится в состоянии тренда. Для того, чтобы это реализовать, мы будем помещать торговый запрос (на покупку или продажу) при наступлении условий, указанных выше, а также при значениях ADX, больших 22. Если ADX>22, но уменьшается или ADX<22, мы не будем помещать торговые запросы даже при наступлении условий, изложенных в пункте 2.
  4. Мы хотим защитить себя установкой ордеров Stop Loss в 30 пунктов, Take Proft установим на уровне 100 пунктов.
  5. Также мы хотим, чтобы советник проверял возможности для продажи/покупки только при формировании нового бара, при этом советник должен помещать ордер на покупку только в случае сигнала на покупку и отсутствия открытых длинных позиций. Аналогично в случае продажи - условия на продажу и отсутствие открытых коротких позиций.

Стратегия разработана, теперь время начать писать код.


2. Пишем советник

2.1 Мастер MQL5

Начнем с запуска редактора MetaQuotes Language Editor 5. Затем нажимаем Ctrl-N или на кнопку "Создать" в панели инструментов.

Рисунок 1. Создание нового документа MQL5

Рисунок 1. Создание нового документа MQL5

В окне Мастера MQL5 выбираем "Советник" и нажимаем "Далее", как показано на рис. 2:

Рисунок 2. Выбор типа создаваемой программы

Рисунок 2. Выбор типа создаваемой программы

В следующем окне в поле "Имя" напишите имя, которое вы хотите дать вашему советнику, я написал "My_First_EA". Вы можете указать свое имя в поле "Автор" и адрес в виде ссылки на ваш сайт или e-mail (если есть).

Рисунок 3. Общие свойства советника

Рисунок 3. Общие параметры советника

Поскольку мы хотим иметь возможность менять некоторые параметры нашего советника, для того, чтобы найти лучшие, мы добавим их при помощи кнопки "Добавить".

Рисунок 4. Входные параметры советника

Рисунок 4. Входные параметры советника

В нашем советнике нам нужно иметь возможность изменять Stop Loss, Take Profit, ADX Period and Moving Average Period, так что укажем их здесь.

Дважды кликнем мышкой по колонке "Имя" в параметрах и напишем наименование параметра, аналогично в колонках "Тип" и "Начальное значение" укажем тип данных параметра и начальные значения.

После этого, результат будет примерно следующий:

Рисунок 5. Типы данных входных параметров советника

Рисунок 5. Типы данных входных параметров советника

Как видно, мы выбрали тип integer (int) для всех параметров. Рассмотрим подробнее типы данных.

  • char: Целый тип char занимает в памяти 1 байт (8 бит) и позволяет выразить в двоичной системе счисления 2^8 значений=256. Тип char может содержать как положительные, так и отрицательные значения. Диапазон изменения значений составляет от -128 до 127.
  • uchar: Целый тип uchar также занимает в памяти 1 байт, как и тип char, но в отличие от него, uchar предназначен только для положительных значений. Минимальное значение равно нулю, максимальное значение равно 255. Первая буква u в названии типа uchar является сокращением слова unsigned (беззнаковый).
  • short: Целый тип short имеет размер 2 байта(16 бит) и, соответственно, позволяет выразить множество значений равное 2 в степени 16:  2^16=65 536. Так как тип short является знаковым и содержит как положительные, так и отрицательные значения, то диапазон значений находится между -32 768 и 32 767.
  • ushort: Беззнаковым типом short является тип ushort, который также имеет размер 2 байта. Минимальное значение равно 0, максимальное значение 65 535.
  • int: Целый тип int имеет размер 4 байта (32 бита). Минимальное значение -2 147 483 648, максимальное значение 2 147 483 647.
  • uint: Беззнаковый целый тип uint занимает в памяти 4 байта и позволяет выражать целочисленные значения от 0 до 4 294 967 295.
  • long: Целый тип long имеет размер 8 байт (64 бита). Минимальное значение -9 223 372 036 854 775 808, максимальное значение 9 223 372 036 854 775 807.
  • ulong: Целый тип ulong также занимает 8 байт и позволяет хранить значения от 0 до 18 446 744 073 709 551 615.

Как видно из описания различных типов данных, беззнаковые целые (uint) не предназначены для хранения отрицательных значений, любые попытки установить отрицательные значения могут привести к непредсказуемым результатам. Например, если вы хотите хранить отрицательные значения, нельзя для них использовать переменные типа uchar, uint, ushort, ulong.

Вернемся к нашему советнику. Для значений, меньших 127 или 255, для экономии памяти можно использовать значения типа char or uchar, соответственно, однако для удобства мы зададим их значения как тип int.

После того, как закончено определение необходимых входных параметров индикатора, нажмем на кнопку "Finish" и MetaQuotes Editor5 создаст шаблон кода, представленный ниже:


Для лучшего понимания, рассмотрим отдельно различные секции кода.

В верхней части кода (заголовок) определяются свойства советника. Как видно, это значения, которые были установлены в Мастере MQL5 на рис. 3.

В этой части кода также можно задать дополнительные параметры, например description (текст с кратким описанием советника), определить константы, включить дополнительные файлы или импортируемые функции.


Для выражений, начинающихся с символа "#", не нужно ставить точку с запятой в конце строки, это директивы препроцессора. Другой пример:

  • #define
    Директива #define используется для определения констант. Записывается в виде:
  • #define identifier token_string
    Это означает, что компилятор заменит в коде переменные
    identifier численным значением, равным token_string.

Например:

#define ABC               100
#define COMPANY_NAME      "MetaQuotes Software Corp."

В данном случае COMPANY_NAME будет означать строку "MetaQuotes Software Corp.", вместо ABC будет подразумеваться число, равное 100.

Более подробнее о директивах препроцессора можно прочитать в руководстве по MQL5. Идем далее.

Вторая часть заголовка в нашем коде - это секция входных параметров.

 

Здесь мы задаем входные параметры, которые будут использоваться в советнике как переменные, они могут быть использованы во всех функциях нашего советника.

Переменные, определенные на этом уровне, называются глобальными переменными, поскольку они доступны из любой функции советника. Входные параметры могут быть изменены только вне кода советника при запуске. Также мы можем определить другие переменные, которые будем использовать в нашем советнике, они не будут доступны для модификации извне.

Далее идет функция инициализации советника. Это функция вызывается первой после запуска советника или смены графика и вызывается только один раз.


Этот раздел - лучшее место для проведения проверок, чтобы убедиться в правильности работы нашего советника.

Например, можно проверить, достаточно ли баров на графике для работы нашего советника и т.п.

Также это лучшее место для получения хэндлов технических индикаторов, которые будут использоваться (в нашем случае это индикаторы ADX и Moving Average).


Функция OnDeinit вызывается при удалении советника с графика.

В нашем советнике, в данной функции мы будем освобождать хэндлы индикаторов, созданных в разделе инициализации.


Данная функция производит обработку события NewTick, которое генерируется при приходе новой котировки для символа.

Большая часть кода, отвечающего за реализацию нашей торговой стратегии будет содержаться в данной функции.

Отметим, что советник не сможет производить торговые операции, если в авто-трейдинг не разрешен в клиентском терминале:

Рисунок 6. Авто-торговля включена

Рисунок 6. Торговля советником разрешена

Теперь, когда мы рассмотрели разделы кода нашего советника, начнем добавления кода в шаблон.

2.2. Раздел входных параметров

//--- входные параметры
input int      StopLoss=30;      // Stop Loss
input int      TakeProfit=100;   // Take Profit
input int      ADX_Period=8;     // Период ADX
input int      MA_Period=8;      // Период Moving Average
input int      EA_Magic=12345;   // Magic Number советника
input double   Adx_Min=22.0;     // Минимальное значение ADX
input double   Lot=0.1;          // Количество лотов для торговли
//--- глобальные переменные
int adxHandle; // хэндл индикатора ADX
int maHandle;  // хэндл индикатора Moving Average
double plsDI[],minDI[],adxVal[]; // динамические массивы для хранения численных значений +DI, -DI и ADX для каждого бара
double maVal[]; // динамический массив для хранения значений индикатора Moving Average для каждого бара
double p_close; // переменная для хранения значения close бара
int STP, TKP; // будут использованы для значений Stop Loss и Take Profit

Как видно, мы добавили новые параметры. Перед тем, как обсудить их предназначение, посмотрим на код. При помощи двойного слэша "//" в код можно помещать комментарии. При помощи комментариев мы можем описывать предназначение наших переменных или производимые нами действия. Комментарии позволяют улучшить понимание кода. Существуют два основных способа написания комментариев:

// глобальные переменные …

Это однострочный комментарий.

/*

  Это многострочный комментарий

*/

Это многострочный комментарий. Многострочные комментарии начинаются с пары символов "/*" и заканчиваются "*/".

При компиляции кода комментарии игнорируются компилятором.

Использование однострочных комментариев для входных параметров позволяет описать предназначение входных параметров. В этом случае вместо наименования параметров будут показаны комментарии, как показано ниже:

Рисунок 7. Входные параметры советника

Рисунок 7. Входные параметры советника

Вернемся к нашему коду.

Мы решили добавить дополнительные параметры в наш советник. Параметр EA_Magic (Magic Number)  будет использован для всех ордеров нашего советника. Минимальное значение ADX задано как переменная типа double. Значения типа double используются для констант, которые, наряду с целой частью, также могут содержать и дробную часть.

Например:

double mysum = 123.5678;

double b7 = 0.09876;

Количество лотов для торговли (Lot) представляет собой объем финансового инструмента, который мы хотим торговать.

Далее мы также объявили дополнительные переменные, которые будут использованы следующим образом: переменная adxHandle будет использоваться для хранения хэндла индикатора ADX, переменная maHandle для хэндла индикатора Moving Average. Динамические массивы plsDI[], minDI[], adxVal[] are будут использованы для хранения значений +DI, -DI и самого значения ADX для каждого бара графика. Численные значения индикатора Moving Average для каждого бара графика будут храниться в динамическом массиве maVal[].

Кстати, что представляют собой динамические массивы? Динамический массив - это массив, объявленный без указания размера. Другими словами, в квадратных скобках при его описании нет конкретного числа, указывающего его размер.

С другой стороны, для статических массивов их размер определяется при объявлении.

Пример:

double allbars[20]; // этот массив содержит 20 элементов - от 0 до 19

Переменная p_close будет использоваться для хранения численного значения цены Close  для бара, который мы собираемся отслеживать в процессе проверки торговых сигналов на покупку и продажу.

Переменные STP и TKP нужны для установки значений Stop Loss и Take Profit ордеров нашего советника.

2.3. Секция инициализации советника

int OnInit()
  {
//--- Получить хэндл индикатора ADX
   adxHandle=iADX(NULL,0,ADX_Period);
//--- Получить хэндл индикатора Moving Average
   maHandle=iMA(_Symbol,_Period,MA_Period,0,MODE_EMA,PRICE_CLOSE);
//--- Нужно проверить, не были ли возвращены значения Invalid Handle
   if(adxHandle<0 || maHandle<0)
     {
      Alert("Ошибка при создании индикаторов - номер ошибки: ",GetLastError(),"!!");
     }

Далее мы получаем хэндлы индикаторов, используя соответствующие функции индикаторов.

Хэндл индикатора ADX получаем при помощи функции iADX. В качестве аргументов ей передается символ графика symbol (NULL  также означает символ текущего графика), период/таймфрейм (0 означает таймфрейм текущего графика), период индикатора ADXкоторый будет использоваться для вычисления индикатора (ADX_Period мы определили в разделе входных параметров индикатора):

int  iADX(
   string          symbol,       // имя символа
   ENUM_TIMEFRAMES  period,       // период
   int            adx_period     // период усреднения индикатора ADX
   );

Хэндл индикатора Moving Average получаем при помощи функции iMA. Аргументы этой функции следующие:

  • symbol - Символьное имя инструмента, на данных которого будет вычисляться индикатор (можно использовать _symbol, symbol() или NULL для текущего символа).
  • period - Значение периода может быть одним из значений перечисления ENUM_TIMEFRAMES, (можно использовать  _period, period() или 0 для таймфрейма текущего графика).
  • ma_period - Период усреднения для вычисления скользящего среднего (который мы определили ранее в разделе входных параметров индикатора).
  • ma_shift - Сдвиг индикатора относительно ценового графика (мы используем 0).
  • ma_method - Метод усреднения. Может быть любым из значений MODE_SMA, MODE_EMA, MODE_SMMA или MODE_LWMA.
  • applied_price - Используемая цена. Может быть любой из ценовых констант ENUM_APPLIED_PRICE или хендлом другого индикатора.
int  iMA(
   string              symbol,        // имя символа
   ENUM_TIMEFRAMES      period,        // период
   int                 ma_period,    // период усреднения
   int                 ma_shift,     // смещение индикатора по горизонтали
   ENUM_MA_METHOD       ma_method,    // тип сглаживания
   ENUM_APPLIED_PRICE   applied_price  // тип цены или handle
   );

Для получения более подробной информации, посмотрите справку по этим индикатным функциям в документации по MQL5. Это даст лучшее понимание того, как использовать этот индикатор.

Мы проверяем результат выполнения функций на наличие ошибок, в случае неудачи можем получить ошибку INVALID_HANDLE. В этом случае выводим сообщение об ошибке и ее код, используя функцию   GetlastError и завершаем работу советника.

 

Мы решили хранить значения Stop Loss и Take Profit в определенных ранее переменных STP и TKP. Почему мы это сделали?

Это сделано потому, что значения входных параметров не могут быть модифицированы, они только для чтения.

Мы должны быть уверены в том, что наш советник будет корректно работать со всеми брокерами. Для определения точности цены котировок по текущему символу графика можно воспользоваться

Предопределенной переменной _Digits или функцией Digits(). Для 3-х и 5-ти значных котировок мы умножаем значения Stop Loss и Take Profit на 10.

2.4. Раздел деинициализации советника


Поскольку эта функция вызывается при прекращении работы советника или удалении советника с графика, здесь мы освобождаем хэндлы индикаторов, созданные в процессе инициализации. Мы создали два индикатора, ADX и Moving Average.

Для их удаления мы используем функцию IndicatorRelease(). Эта функция имеет лишь один параметр (хэндл индикатора).

bool  IndicatorRelease(
   int       indicator_handle,     // хэндл индикатора
   );

Функция удаляет хэндл индикатора и освобождает расчетную часть индикатора, если ею больше никто не пользуется.

2.5 Раздел OnTick советника

Первое, что мы здесь делаем - проверяем достаточно ли баров на текущем графике. Количество баров на любом графике можно узнать при помощи функции Bars. У нее есть два входных параметра, первый - symbol, (символ текущего графика можно получить используя предопределенную переменную _Symbol или функцию Symbol()) и period  или timeframe  текущего графика (для текущего графика  - предопределенная переменная _Period или функция Period()).

При количестве баров на графике менее 60, наш советник не будет работать и выйдет из функции OnTick. Функция Alert показывает сообщение в отдельном окне. Эта функция выводит значения аргументов/параметров, разделенных запятыми. В нашем случае выводится только одно значение в виде строки и завершается работа функции OnTick.

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- Достаточно ли количество баров для работы
   if(Bars(_Symbol,_Period)<60) // общее количество баров на графике меньше 60?
     {
      Alert("На графике меньше 60 баров, советник не будет работать!!");
      return;
     }

// Для сохранения значения времени бара мы используем static-переменную Old_Time.
// При каждом выполнении функции OnTick мы будем сравнивать время текущего бара с сохраненным временем.
// Если они не равны, это означает, что начал строится новый бар.

   static datetime Old_Time;
   datetime New_Time[1];
   bool IsNewBar=false;

// копируем время текущего бара в элемент New_Time[0]
   int copied=CopyTime(_Symbol,_Period,0,1,New_Time);
   if(copied>0) // ok, успешно скопировано
     {
      if(Old_Time!=New_Time[0]) // если старое время не равно
        {
         IsNewBar=true;   // новый бар
         if(MQL5InfoInteger(MQL5_DEBUGGING)) Print("Новый бар",New_Time[0],"старый бар",Old_Time);
         Old_Time=New_Time[0];   // сохраняем время бара
        }
     }
   else
     {
      Alert("Ошибка копирования времени, номер ошибки =",GetLastError());
      ResetLastError();
      return;
     }

//--- советник должен проверять условия совершения новой торговой операции только при новом баре
   if(IsNewBar==false)
     {
      return;
     }

//--- Имеем ли мы достаточное количество баров на графике для работы
   int Mybars=Bars(_Symbol,_Period);
   if(Mybars<60) // если общее количество баров меньше 60
     {
      Alert("На графике менее 60 баров, советник работать не будет!!");
      return;
     }

//--- Объявляем структуры, которые будут использоваться для торговли
   MqlTick latest_price;       // Будет использоваться для текущих котировок
   MqlTradeRequest mrequest;    // Будет использоваться для отсылки торговых запросов
   MqlTradeResult mresult;      // Будет использоваться для получения результатов выполнения торговых запросов
   MqlRates mrate[];           // Будет содержать цены, объемы и спред для каждого бара
   ZeroMemory(mrequest);       // Инициализация полей структуры mrequest

Наш советник должен производить торговые операции только при начале нового бара, поэтому нужно решить задачу определения факта появления нового бара. Другими словами, советник не будет работать на каждом тике, проверка условий и торговля будет производиться только после окончания формирования бара.

Мы начнем с объявления статической переменной Old_Time, в которой будем хранить время бара. Мы определили ее статической, поскольку нам нужно, чтобы ее значение сохранялось при новом вызове функции. Тогда у нас будет возможность проверять ее значение с переменной New_Time, которая также объявлена типа datetime, но в виде массива из одного элемента, она будет использоваться для хранения времени текущего бара. Также мы объявляем переменную IsNewBar типа boolean, и устанавливаем ее значение в false. Ее значение будет установлено в true только в  случае определения факта появления нового бара.

Для получения времени бара используется функция CopyTime. Она копирует время бара в массив New_Time, состоящий из одного элемента. В случае успеха, мы сравниваем значение времени бара с сохраненным ранее временем предыдущего бара. Если они различны, это означает, что появился новый бар и переменная IsNewBar устанавливается в true, а значение текущего времени бара сохраняется в переменной Old_Time.

Таким образом, переменная IsNewBar будет указывать на факт появления нового бара. Если ее значение равно false, мы завершаем выполнение функции OnTick.

Обратите внимание на строчку:

if(MQL5InfoInteger(MQL5_DEBUGGING)) Print("Новый бар",New_Time[0],"старый бар",Old_Time);

здесь проверяется исполнение советника в режиме отладки, если он запущен в отладчике, будет выводится сообщение о значениях времен баров, режим отладки мы рассмотрим позже.

Следующее, что мы собираемся cделать - проверить наличие достаточного количества баров для работы. Зачем делать это снова?

Мы хотим быть уверены в том, что наш советник работает корректно.

Следует отметить, что функция OnInit вызывается только один раз при присоединении советника к графику, а функция OnTick вызывается каждый раз при поступлении нового тика (ценовой котировки).

Как можно видеть, мы это делаем по-другому. Мы сохраняем общее количество баров в истории в новой переменной Mybars, определенной внутри функции OnTick:

   int Mybars=Bars(_Symbol,_Period);

Этот тип переменной является локальной переменной, в отличие от переменных, декларированных в разделе входных параметров нашего кода.

Глобальные переменные доступны для всех функций советника, локальные переменные определяются внутри функций, их видимость ограничена лишь функцией, внутри которой они декларированы. Они не могут быть использованы вне функции.

Далее мы определили несколько переменных типа структур MQL5, которые будут использованы в данном разделе нашего советника. В языке MQL5 есть множество готовых структур, что значительно облегчает жизнь разработчикам советников. Давайте последовательно рассмотрим их.

MqlTick

Эта структура используется для хранения последних цен по символу.

struct MqlTick
  {
   datetime     time;          //
Время последнего обновления цен
   double       bid;           //
Текущая цена Bid
   double       ask;           //
Текущая цена Ask
   double       last;          //
Текущая цена последней сделки (Last)
   ulong        volume;        //
Объем для текущей цены Last
  };

Любая переменная, объявленная типа может быть легко использована для получения текущих значений цен Ask, Bid, Last и Volume, достаточно вызвать функцию SymbolInfoTick.

Мы объявили переменную latest_price как структуру MqlTick, так что мы можем использовать ее для получения цен Bid и Ask.

MqlTradeRequest

Эта структура используется в запросах на проведение торговых операций. Она содержит все поля, необходимые для заключения торговых сделок.

struct MqlTradeRequest
  {
   ENUM_TRADE_REQUEST_ACTIONS    action;       //
Тип выполняемого действия
   ulong                         magic;        //
Идентификатор magic number эксперта
   ulong                         order;        //
Тикет ордера
   string                        symbol;       //
Имя торгового инструмента
   double                        volume;       //
Запрашиваемый объем сделки в лотах
   double                        price;        //
Цена
   double                        stoplimit;    //
Уровень StopLimit ордера
   double                        sl;           //
Уровень Stop Loss ордера
   double                        tp;           //
Уровень Take Profit ордера
   ulong                         deviation;    //
Максимально приемлемое отклонение от запрашиваемой цены
   ENUM_ORDER_TYPE               type;          //
Тип ордера
   ENUM_ORDER_TYPE_FILLING       type_filling;  //
Тип ордера по исполнению
   ENUM_ORDER_TYPE_TIME          type_time;     //
Тип ордера по времени действия
   datetime                      expiration;    //
Срок истечения ордера (для ордеров типа ORDER_TIME_SPECIFIED)
   string                        comment;       //
Комментарий к ордеру
  };

Любая переменная, объявленная как структура MqlTradeRequest может быть использована для отправки запросов на совершение торговых операций. В нашем случае мы объявили переменную mrequest как структуру MqlTradeRequest.

MqlTradeResult

Результат выполнения торговой операции возвращается в специальную предопределенную структуру типа MqlTradeResult. Любая переменная типа MqlTradeResult может быть использована для доступа к результату выполнения торгового запроса.

struct MqlTradeResult
  {
   uint     retcode;          //
Код результата операции
   ulong    deal;             //
Тикет сделки, если она совершена
   ulong    order;            //
Тикет ордера, если он выставлен
   double   volume;           //
Объем сделки, подтверждённый брокером
   double   price;            //
Цена в сделке, подтверждённая брокером
   double   bid;              //
Текущая рыночная цена Bid
   double   ask;              //
Текущая рыночная цена Ask
   string   comment;          //
Комментарий брокера к операции (по умолчанию заполняется расшифровкой)
  };

В нашем случае переменная mresult объявлена как структура тип MqlTradeResult.

MqlRates

Цены (Open, Close, High, Low), время, объем каждого бара, и спред символа хранятся в этой структуре. Любой массив, определенный как массив типа MqlRates может быть использован для хранения значений цен, объемов и спредов по символу.

struct MqlRates
  {
   datetime time;         //
Время начала периода
   double   open;         //
Цена открытия
   double   high;         //
Наивысшая цена за период
   double   low;          //
Наименьшая цена за период
   double   close;        //
Цена закрытия
   long     tick_volume;  //
Тиковый объем
   int      spread;       // С
пред
   long     real_volume;  //
Биржевой объем
  };

Для наших целей мы определили массив mrate[], который будет использоваться для хранения этой информации.

/*
     Установим индексацию в массивах котировок и индикаторов 
     как в таймсериях
*/
// массив котировок
   ArraySetAsSeries(mrate,true);
// массив значений индикатора ADX DI+
   ArraySetAsSeries(plsDI,true);
// массив значений индикатора ADX DI-
   ArraySetAsSeries(minDI,true);
// массив значений индикатора ADX
   ArraySetAsSeries(adxVal,true);
// массив значений индикатора MA-8
   ArraySetAsSeries(maVal,true);

Здесь мы устанавливаем индексацию как в таймсериях для всех массивов, которые будут использоваться нами. Это позволит нам быть уверенными в том, что скопированные массивы будут иметь нумерацию как в таймсериях (справа налево т.е. 0, 1, 2, 3 и т.д.). Это производится при помощи функции ArraySetAsSeries().

bool  ArraySetAsSeries(
   
void  array[],     // массив по ссылке
   bool  set          // true означает обратный порядок индексации
   );

Следует отметить, что это можно сделать однократно в функции инициализации советника. Тем не менее, для последовательности изложения я решил рассмотреть этот вопрос здесь.

//--- Получить текущее значение котировки в структуру типа MqlTick
   if(!SymbolInfoTick(_Symbol,latest_price))
     {
      Alert("Ошибка получения последних котировок - ошибка:",GetLastError(),"!!");
      return;
     }

Мы используем функцию SymbolInfoTick для получения текущих котировок. Эта функция имеет два аргумента - символ графика и структура типа MqlTick (latest_price). Снова, проверяем корректность выполнения функции и выводим сообщение в случае ошибки.

//--- Получить исторические данные последних 3-х баров
   if(CopyRates(_Symbol,_Period,0,3,mrate)<0)
     {
      Alert("Ошибка копирования исторических данных - ошибка:",GetLastError(),"!!");
      return;
     }

Затем, при помощи функции CopyRates мы копируем информацию последних трех баров в массив типа MqlRates. Функция CopyRates используется для получения исторических данных по указанному символу, периоду и запрашиваемому количеству данных, которые затем помещаются  в массив типа MqlRates.

int  CopyRates(
   string           symbol_name,       // имя символа
   ENUM_TIMEFRAMES  timeframe,         // период
   int              start_pos,         // откуда начнем
   int              count,             // количество данных для копирования
   MqlRates         rates_array[]      // массив, куда будут скопированы данные
   );

Имя символа и текущий таймфрей получаем используя предопределенные переменные _Symbol и _Period. Начиная с текущего бара Bar 0, имеющего индекс 0, мы возьмем только три бара: Bars 0, 1, и 2. Результат будет помещен в наш массив mrate[].

Массив mrate[] теперь содержит все данные по ценам, времени, объемам и спредам для баров 0, 1 и 2. Поэтому для того, чтобы получить нужное свойство любого бара, мы используем выражение типа:

mrate[bar_number].bar_property

например, для каждого из этих баров:

mrate[1].time   // время начала бара 1
mrate[1].open   // цена открытия бара 1
mrate[0].high   // наибольшая цена бара 0 (текущий бар), и т.д.

В этом коде мы убеждаемся в том, что дальнейшие условия проверки условий для проведения торговых операций производятся только при начале формирования нового бара. Новый бар характеризуется величиной тикового объема, равной 1, если он больше 1, то выполнение функции OnTick завершается.

Далее, используя функцию CopyBuffer, мы копируем значения индикаторов в динамические массивы:

int  CopyBuffer(
   int       indicator_handle,     // хэндл индикатора
   int       buffer_num,           // номер буфера индикатора
   int       start_pos,            // откуда начнем 
   int       count,                // сколько копируем
   double    buffer[]              // массив, куда будут скопированы данные
   );

В качестве хэндла индикатора указывается хэндл, полученный в функции OnInit. Что касается номеров буферов индикатора, то индикатор ADX имеет 3 (три) буфера:

  • 0 - MAIN_LINE,
  • 1 - PLUSDI_LINE,
  • 2 - MINUSDI_LINE. 

Индикатор The Moving Average имеет только 1 (один) буфер:

  • 0 – MAIN_LINE.

Начиная с текущего бара (0), мы копируем также еще два бара. Таким образом, полное количество баров равно 3 (бары 0-й,1-й и 2-й). Массив buffer[] в параметре функции CopyBuffer, это массив, куда будут помещены данные. В нашем случае это динамические массивы adxVal, plsDI, minDI и maVal.

//--- Используя хэндлы индикаторов, копируем новые значения индикаторных буферов в массивы
   if(CopyBuffer(adxHandle,0,0,3,adxVal)<0 || CopyBuffer(adxHandle,1,0,3,plsDI)<0
      || CopyBuffer(adxHandle,2,0,3,minDI)<0)
     {
      Alert("Ошибка копирования буферов индикатора ADX - номер ошибки:",GetLastError(),"!!");
      return;
     }
   if(CopyBuffer(maHandle,0,0,3,maVal)<0)
     {
      Alert("Ошибка копирования буферов индикатора Moving Average - номер ошибки:",GetLastError());
      return;
     }

Как видно, мы должны отслеживать любые ошибки, которые могут произойти в процессе копирования, вывести соответствующее сообщение и завершить работу функции в случае ошибки, поскольку в таком случае нет смысла продолжать исполнение функции.

Важно отметить, что функции CopyBuffer() and the CopyRates() возвращают общее количество скопированных данных или -1 в случае ошибки. Вот почему мы проверяем возвращаемые значения, они будут меньше 0 в случае ошибки.

Теперь мы должны проверить, есть ли в данный момент открытые позиции, иными словами, мы не будем открывать новых позиций на покупку в случае наличия длинной позиции, и позиции на продажу, если короткая позиция уже открыта.

Для того, чтобы реализовать это, сначала объявим две переменные типа boolean (Buy_opened и Sell_opened), которые будут установлены в TRUE в случае наличия соответствующих открытых позиций.

//--- есть ли открытые позиции?
    bool Buy_opened=false;  // переменные, в которых будет храниться информация 
    bool Sell_opened=false; // о наличии соответствующих открытых позиций
    
    if (PositionSelect(_Symbol) ==true)  // есть открытая позиция
    {
         if (PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_BUY)
         {
            Buy_opened = true;  // это длинная позиция
         }
         else if(PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_SELL)
         {
            Sell_opened = true; // это короткая позиция
         }
    }

Для того, чтобы узнать наличие открытой позиции, мы использовали функцию PositionSelect, которая возвращает TRUE в случае наличия открытой позиции по указанному символу и FALSE при отсутствии открытой позиции.

bool  PositionSelect(
   string  symbol      // имя символа
   );

В качестве основного аргумента функции передается наименование символа, наличие позиции по которому следует проверить. Здесь для имени символа мы использовали предопределенную переменную _Symbol.

В случае, если функция вернула TRUE (позиция существует), мы хотим проверить ее тип (покупка или продажа). Для этого мы используем функцию PositionGetInteger, она возвращает тип открытой позиции, в случае, если в качестве параметра задан запрос свойства POSITION_TYPE. В результате возвращается одно из значений перечисления  ENUM_POSITION_PROPERTY_INTEGER: POSITION_TYPE_BUY или POSITION_TYPE_SELL.

long  PositionGetInteger(
   ENUM_POSITION_PROPERTY  property_id    // идентификатор свойства
   );

В нашем случае, мы используем это для того, чтобы определить факт наличия уже открытой позиции. Если открыта позиция на продажу, мы устанавливаем значение переменной Sell_opened в TRUE, если открыта позиция на покупку, мы устанавливаем значение переменной Buy_opened в TRUE. В дальнейшем мы используем значения этих переменных при проверке условий открытия позиций.

Теперь пришло время поместить цену закрытия бара в переменную, которую мы будем использовать для проверки условий торговли. Вспомним, что переменная p_close была определена ранее.

// Скопируем текущую цену закрытия предыдущего бара (это бар 1)
p_close=mrate[1].close;  // цена закрытия предыдущего бара

После того, как это сделано, перейдем к следующему шагу.

/*
    1. Проверка условий для покупки : MA-8 растет, 
    предыдущая цена закрытия бара больше MA-8, ADX > 22, +DI > -DI
*/
//--- объявляем переменные типа boolean, они будут использоваться при проверке условий для покупки
   bool Buy_Condition_1 = (maVal[0]>maVal[1]) && (maVal[1]>maVal[2]); // MA-8 растет
   bool Buy_Condition_2 = (p_close > maVal[1]);         // предыдущая цена закрытия выше скользяшей средней MA-8
   bool Buy_Condition_3 = (adxVal[0]>Adx_Min);          // текущее значение ADX больше, чем минимальное (22)
   bool Buy_Condition_4 = (plsDI[0]>minDI[0]);          // +DI больше, чем -DI

//--- собираем все вместе
   if (Buy_Condition_1 && Buy_Condition_2)
     {
      if(Buy_Condition_3 && Buy_Condition_4)
        {
         // есть ли в данный момент открытая позиция на покупку?
         if (Buy_opened) 
         {
            Alert("Уже есть позиция на покупку !!!");
            return; // не добавлять к открытой позиции на покупку
         }
         mrequest.action = TRADE_ACTION_DEAL;                                 // немедленное исполнение
         mrequest.price = NormalizeDouble(latest_price.ask,_Digits);          // последняя цена ask
         mrequest.sl = NormalizeDouble(latest_price.ask - STP*_Point,_Digits); // Stop Loss
         mrequest.tp = NormalizeDouble(latest_price.ask + TKP*_Point,_Digits); // Take Profit
         mrequest.symbol = _Symbol;                                         // символ
         mrequest.volume = Lot;                                            // количество лотов для торговли
         mrequest.magic = EA_Magic;                                        // Magic Number
         mrequest.type = ORDER_TYPE_BUY;                                     // ордер на покупку
         mrequest.type_filling = ORDER_FILLING_FOK;                          // тип исполнения ордера - все или ничего
         mrequest.deviation=100;                                           // проскальзывание от текущей цены
         //--- отсылаем ордер
         OrderSend(mrequest,mresult);

Рассмотрим условия покупки.

Отметим, что выражения, приведенные выше, соответствуют стратегии, которая обсуждалась ранее. Мы объявили переменные типа bool для каждого из условий, которые должны быть выполнены перед установкой ордера. Переменные типа bool могут принимать только одно из значений: TRUE или FALSE.

Поэтому, наша стратегия на покупку может быть представлена как одновременное выполнение четырех условий. Если условие выполнено, то соответствующая переменная примет значение TRUE, иначе FALSE. Рассмотрим подробнее каждое из условий.

bool Buy_Condition_1 = (maVal[0]>maVal[1]) && (maVal[1]>maVal[2]);

Здесь мы проверяем значение скользящей средней MA-8 на барах 0, 1 и 2. Если значение MA-8 на текущем баре больше, чем на предыдущем (бар 1), и при этом значение MA-8 на баре 1 больше, чем на баре 2, это означает, что скользящая средняя MA-8 возрастает. Это одно из условий покупки.

bool Buy_Condition_2 = (p_close > maVal[1]); 

Это выражение - проверка факта, является ли цена закрытия бара 1 (предыдущий завершенный бар) больше, чем значение скользящей средней MA-8 того же периода (периода бара 1). Если цена закрытия выше, значит второе наше условие выполняется. Если оба этих условий не выполнены, в принципе не имеет смысла проверять следующие.

bool Buy_Condition_3 = (adxVal[0]>Adx_Min);

Теперь мы хотим проверить, является ли значение ADX (ADX для бара 0), больше, чем минимальное значение, указанное во входных параметрах советника. Если это условие выполнено, это означает, что текущее значение ADX больше минимального необходимого, также нам нужно убедиться в том, что значение plusDI больше, чем minusDI. Это производится следующим выражением:

bool Buy_Condition_4 = (plsDI[0]>minDI[0]);

Если все эти условия соблюдаются, то в случае наличия открытой позиции на покупку сообщаем о ее наличии и завершаем выполнение функции. Если нет открытой длинной позиции, для отправки торгового запроса мы подготавливаем переменную mrequest типа MqlTradeRequest, которая была объявлена ранее.

  • Поле action, являющееся типом торговой операции задается как TRADE_ACTION_DEAL, поскольку мы помещаем ордер в режиме немедленного исполнения. Для модификации ранее установленного отложенного ордера нужно указать TRADE_ACTION_MODIFY, для его удаления - TRADE_ACTION_REMOVE. Для цены открытия ордера мы используем значение поля Ask структуры latest_price. Значение цены Stop Loss получается вычистанием из цены Ask заданного значения StopLoss в пунктах. Цена Take Profit вычисляется прибавлением заданного значения TakeProfit в пунктах. Как видно, при указании цен мы использовали функцию NormalizeDouble, которая округляет числа до заданной точности - при отправке запроса на торговый сервер следует указывать нормализованные цены.
  • В поле symbol указывается текущий символ (_Symbol или Symbol()),
  • В поле type - тип ордера, здесь ORDER_TYPE_BUY. Для ордера на продажу нужно указать тип ORDER_TYPE_SELL.
  • В поле type_filling - тип  исполнения ордера, значение ORDER_FILLING_FOK означает что сделка должна быть выполнена в указанном объеме по указанной (или лучше) цене. Если на рынке отсутствует возможность исполнить указанный объем, ордер не будет выполнен.

У функции OrderSend() два аргумента - переменные типа  MqlTradeRequest и MqlTradeResult.

bool  OrderSend(
   MqlTradeRequest&  request      // структура запроса
   MqlTradeResult&   result       // структура ответа
   );

Как видно, мы использовали наши переменные mrequest и mresult в качестве аргументов функции OrderSend().

         // анализируем код возврата торгового сервера
         if(mresult.retcode==10009 || mresult.retcode==10008) // запрос выполнен или ордер успешно помещен
           {
            Alert("Ордер Buy успешно помещен, тикет ордера #:",mresult.order,"!!");
           }
         else
           {
            Alert("Запрос на установку ордера Buy не выполнен - код ошибки:",GetLastError());
            return;
           }

После отправки ордера, мы теперь используем значение переменной mresult для проверки результата. Если наш ордер был успешно выполнен, нужно дать об этом знать, также в случае ошибки также нужно информировать о результате. Доступ к коду ошибки и номеру ордера можно получить, используя поля mresult.retcode и mresult,order соответственно.

Код возврата торгового сервера 10009 означает, что запрос OrderSend был успешно выполнен, а код 10008 показывает, что ордер помещен в очередь на исполнение. Поэтому мы должны проверить любой из этих вариантов - в таком случае мы уверены в том, что ордер был выполнен или помещен в очередь на исполнение.

Для проверки условий для продажи, мы производим проверку, противоположную той, которая была для покупки, за исключением того, что DI- должен быть больше, чем DI+.

/*
    2. Проверка условий для продажи : MA-8 падает, 
    предыдущая цена закрытия бара меньше MA-8, ADX > 22, -DI > +DI
*/
//--- объявляем переменные типа boolean, они будут использоваться при проверке условий для продажи
   bool Sell_Condition_1 = (maVal[0]<maVal[1]) && (maVal[1]<maVal[2]);  // MA-8 падает
   bool Sell_Condition_2 = (p_close <maVal[1]);                         // предыдущая цена закрытия ниже MA-8
   bool Sell_Condition_3 = (adxVal[0]>Adx_Min);                         // текущее значение ADX value больше заданного (22)
   bool Sell_Condition_4 = (plsDI[0]<minDI[0]);                         // -DI больше, чем +DI
   
 //--- собираем все вместе
   if (Sell_Condition_1 && Sell_Condition_2)
       {
         if (Sell_Condition_3 && Sell_Condition_4)
           {
            // есть ли в данный момент открытая позиция на продажу?
            if (Sell_opened) 
            {
               Alert("Уже есть позиция на продажу!!!");
               return; // не добавлять к открытой позиции на продажу
            }
            mrequest.action = TRADE_ACTION_DEAL;                                // немедленное исполнение
            mrequest.price = NormalizeDouble(latest_price.bid,_Digits);          // последняя цена Bid
            mrequest.sl = NormalizeDouble(latest_price.bid + STP*_Point,_Digits); // Stop Loss
            mrequest.tp = NormalizeDouble(latest_price.bid - TKP*_Point,_Digits); // Take Profit
            mrequest.symbol = _Symbol;                                         // символ
            mrequest.volume = Lot;                                            // количество лотов для торговли
            mrequest.magic = EA_Magic;                                        // Magic Number
            mrequest.type= ORDER_TYPE_SELL;                                     // ордер на продажу
            mrequest.type_filling = ORDER_FILLING_FOK;                          // тип исполнения ордера - все или ничего
            mrequest.deviation=100;                                           // проскальзывание от текущей цены
            //--- отсылаем ордер
            OrderSend(mrequest,mresult);

Точно так же, в разделе выше, мы объявили переменные типа bool для каждого из условий, которые должны удовлетворяться для помещения ордера на продажу. Поэтому торговая стратегия для продажи также состоит из четырех условий. Если условие выполняется, соответствующая переменная устанавливается в TRUE, иначе FALSE. Как и для случая с покупкой, рассмотрим их подробней.

   bool Sell_Condition_1 = (maVal[0]<maVal[1]) && (maVal[1]<maVal[2]);

Здесь мы проверяем значения MA-8 для баров 0, 1 и 2. Если значение MA-8 текущего бара (0) меньше, чем значение предыдущего бара 1, а также MA-8 для бара 1 меньше, чем значение для бара 2, это значит, что MA-8 падает. В этом случае одно условий для продажи удовлетворяется.

   bool Sell_Condition_2 = (p_close <maVal[1]); 

В этом выражении проверяется условие того, что цена закрытия меньше чем значение MA-8 соответствующего бара (бара 1). Если цена закрытия меньше значения скользящей средней, это значит второе условие удовлетворяется. Затем проверяются следующие условия.

   bool Sell_Condition_3 = (adxVal[0]>Adx_Min); 

Здесь проверяется условие того, что текущее значение ADX (бара 0) больше чем значение, указанное во входных параметрах советника. Также нужно проверить условие того, что значение MinusDI больше, чем plusDI. Это делается следующим образом:

bool Sell_Condition_4 = (plsDI[0]<minDI[0]);

Если одновременно выполняются все эти условия, подготавливаем запрос на продажу тем же способом, как и в случае покупки.

Главное отличие в способе вычисления цен Stop Loss и Take Profit. Поскольку производится продажа, используется Bid цена, которая была получена ранее в структуру latest_price. Также здесь указан другой тип ордера - ORDER_TYPE_SELL.

Аналогично, мы используем функцию NormalizedDouble для цены ордера и цен StopLoss и TakeProfit - всегда нужно использовать нормализованные цены при отсылке запроса на торговый сервер.

Так же, как и для ордеров Buy, мы должны проверить результат торгового запроса. Мы используем тот же код, как и для случая покупки.

         // получаем код ответа торгового сервера
         if(mresult.retcode==10009 || mresult.retcode==10008) // запрос выполнен или ордер успешно помещен
           {
            Alert("Ордер Sell успешно помещен, тикет ордера #:",mresult.order,"!!");
           }
         else
           {
            Alert("Запрос на установку ордера Sell не выполнен - код ошибки:",GetLastError());
            return;
           }


3. Отладка и тестирование советника

В этом разделе мы разберем, как можно проверить работает ли наша стратегия или нет. Также возможно, что в коде советника могут быть и ошибки, есть возможность отлаживать работу программ на MQL5.

3.1 Отладка

Режим отладки позволяет нам увидеть построчное исполнение нашего кода (если мы установили точки останова, breakpoints) и затем, в случае ошибок быстро сделать необходимые правки перед тем, как использовать его в реальной торговле.

Далее мы рассмотрим процесс отладки советника, сначала без установки точек останова, затем с ними. Для этого, нужно в редакторе выбрать таймфрейм, на котором будет производится отладка нашего советника. В меню "Сервис" главного меню нужно выбрать "Настройки...":


Рисунок 8. Настройка параметров отладки

Рисунок 8. Настройка параметров отладки

После появления окна "Параметры", выберите валютную пару, нужный период/таймфрейм и нажмите кнопку OK:

Рисунок 9. Установка параметров отладки

Рисунок 9. Установка параметров отладки

Перед тем, как начать отладку установим точки останова. Точки останова позволяют нам следить за работой определенных строк кода. В отличие от обычного запуска программы, при отладке в случае наличия точек останова отладчик остановит работу, ожидая дальнейших действий. Таким образом мы способны проанализировать работу нашего кода и следить за  текущими значениями переменных в каждой из точек останова для того, чтобы проверить, работает ли все так, как следует.

Для того, чтобы добавить точку останова, нужно перейти к строке, на которой нужно остановиться. В левой части редактора, рядом с границей редактора кода, нужно дважды кликнуть мышкой, при этом появится маленький голубой круг с белым квадратом внутри (рис. 10). Альтернативным вариант добавления точки останова - перейти на строку и нажать клавишу F9. Для того, чтобы убрать точку останова следует повторно нажать F9, либо дважды кликнуть по кругу.

Рисунок 10. Ставим точку останова

Рисунок 10. Ставим точку останова

В нашем коде мы собираемся установить точки останова на 5 различных строк кода. 

Для удобства описания, они пронумерованы от 1 до 5.

Установим эти 5 точек останова на строки, указанные на рис. 11. Точку останова 1 мы установили ранее.

Рисунок 11. Установка дополнительных точек останова

Рисунок 11. Установка дополнительных точек останова

Мы закончили установку точек останова, теперь время начать отладку нашего кода.

Для начала запуска режима отладки, нажмите клавишу F5 или зеленкую кнопку в панели инструментов редактора MetaEditor:

Рисунок 12. Запуск отладчика

Рисунок 12. Запуск отладчика

Сначала редактор откомпилирует код, если при компиляции не возникло ошибок, он покажет их в отчете во вкладке "Ошибки":

Рисунок 13. Отчет компиляции


Рисунок 13. Отчет компиляции

Имейте ввиду, что факт успешной компиляции не означает отсутствия ошибок в коде. В зависимости от того, как написан ваш код, могут возникать ошибки времени выполнения (runtime errors). Например, некоторые выражения могут компилироваться правильно, но работать неверно. Давайте лучше посмотрим режим отладки в работе.

После того, как компиляция кода завершена, отладчик передает управление клиентскому терминалу и присоединяет советник к графику, который был указан в настройках отладчика MetaEditor. В то же время, он показывает входные параметры советника. Поскольку нашей целью не является улучшение параметров, нажмем кнопку OK.

Рисунок 14. Установка входных параметров советника для отладки

Рисунок 14. Установка входных параметров советника для отладки

В левом верхнем углу графика видно, что советник присоеден к графику.

При запуске функции OnTick(), произойдет остановка работы советника, он остановится в точку останова 1.

Рисунок 15. Режим отладки: остановка работы советника в первой точке останова

Рисунок 15. Режим отладки: остановка работы советника в первой точке останова

Об этом свидетельствует зеленая стрелка в строке. Она говорит нам о том, что предыдущая строка была выполнена, теперь будет выполнена текущая строка.

Перед тем, как продолжить, имеет смысл познакомиться с командами отладчика. Если посмотреть на панель инструментов редактора MetaEditor, можно увидеть, что теперь стали доступны три кнопки, которые ранее были серого цвета. Причина этого в том, что теперь мы находимся в режиме отладки. Эти три команды используются для исполнения в режиме отладки (Step into, Step over, Step out)"

Рисунок 16. Режим отладки: команда "Step into"

Рисунок 16. Режим отладки: команда "Step into" (Шаг с заходом)

Команда Step Into (Шаг с заходом) переходит к следующему шагу, при этом производится заход внутрь любой вызываемой функции в коде. Для исполнения данной команды, нажмите эту кнопку или клавишу F11. Далее мы будем использовать данную команду при пошаговой отладке нашего кода.

Рисунок 17. Режим отладки: команда "Step over"

Рисунок 17. Режим отладки: команда "Step over" (Шаг с обходом)

Команда Step over (Шаг с обходом), в свою очередь, не производит заход отладчика в функции, которые вызываются в коде. Для исполнения данной команды нужно нажать эту кнопку или клавишу F10.

Рисунок 18. Режим отладки: команда "Step out"

Рисунок 18. Режим отладки: команда "Step out" (Шаг наружу)

Для перехода к выполнению одного шага программы на один уровень выше есть команда Step Out (Шаг наружу), которая вызывается нажатием на соответствующую кнопку или комбинацией клавиш Shift+F11.

В нижней части редактора, вы видите окно "Инструменты"(Toolbox). Вкладка "Отладка" содержит следующие колонки:

  • Файл : Имя файла, с которым производится работа.
  • Функция : Имя функции, которая вызывается в настоящий момент.
  • Строка : Номер строки кода.
  • Выражение : В этой колонке вы можете указать любое выражение или переменную, за значениями которых вы желаете наблюдать в процессе выполнения программы.
  • Значение : В этой колонке показываются текущие значения указанных выражений/переменных.
  • Тип : В данной колонке показан тип данных, для которых установлен режим наблюдения.

Вернемся к процессу отладки...

Следущий шаг, который мы хотим сделать, указать переменные/выражения нашего кода, за которыми мы хотели бы провести наблюдение. Мы будем смотреть за значениями следующих переменных:

  • Old_Time (старое время бара)
  • New_Time[0] (время текущего бара)
  • copied (количество скопированных данных времени)
  • IsNewBar (флаг, показывающий появление нового бара)
  • Mybars (полное количество баров в истории) – наш советник использует это значение

Также можно добавить в мониторинг и другие переменные, например значения технических индикаторов ADX, MA-8 и т.д.

Для добавления выражения/переменной в список наблюдаемых, дважды щелкните на колонке "Выражение" или используйте пункт "Добавить" контекстного меню и укажите наименование переменных или выражения, которые нужно включить в режим наблюдение

Рисунок 19. Монитор выражений

Рисунок 19. Монитор выражений

Укажите переменные/выражения для наблюдения:

Рисунок 20. Добавление выражений или переменных для наблюдения

Рисунок 20. Добавление выражений или переменных для наблюдения

Идем дальше...

Рисунок 21. Конманда "Step into" (Шаг с заходом) в действии

Рисунок 21. Конманда "Step into" (Шаг с заходом) в действии

Нажмите кнопку Шаг с заходом или клавишу F11, и посмотрим, что происходит. Нажимая эту кнопку или клавишу F11, пройдите последовательно по точкам останова и понаблюдайте за значениями выражений в окне мониторинга выражений.

Рисунок 22. Наблюдение за выражениями или переменными

Рисунок 22. Наблюдение за выражениями или переменными

Рисунок 23. Наблюдение за выражениями или переменными

Рисунок 23. Наблюдение за выражениями или переменными

Рисунок 24. Наблюдение за выражениями или переменными

Рисунок 24. Наблюдение за выражениями или переменными

При наступлении нового тика, мы заходим в функцию OnTick(). В случае объявления переменных статическими, переменные останутся декларированными, их значения сохраняться.при новом вызове функции OnTick мы будем наблюдать следующее:

Рисунок 25. Значения переменных при новом вызове функции OnTick

Рисунок 25. Значения переменных при новом вызове функции OnTick


Теперь запустим программу снова, на этот раз без точек останова. 

Рисунок 26. В режиме отладки при новом баре советник выводит сообщение

Рисунок 26. В режиме отладки при новом баре советник выводит сообщение

При каждом баре программа будет проверять условия на покупку/продажу, при наступлении условий будет производиться торговля и выводиться сообщение о результатах выполнения торговой операции:

Рисунок 27. Торговля советника

Рисунок 27. Торговля советника

Я думаю, можно оставить советник поработать еще несколько минут и попить кофе. Вернувшись обратно и сделав немного денег (шутка), нажмите красную кнопку Stop в MetaEditor для остановки процесса отладки.

Рисунок 25. Остановка режима отладки

Рисунок 28. Остановка режима отладки

Мы убедились, что наш советник работает, однако отметим, что клиентский терминал должен быть подключен к Интернет, в противном случае, он не будет работать.

3.2 Тестируем стратегию нашего советника

Теперь мы хотим проверить нашего советника используя встроенный Тестер стратегий клиентского терминала. Для запуска Тестера Стратегий нажмите клавишу Ctrl-R или выберите пункт "Тестер стратегий" в меню "Вид" главного меню, как показано на рисунке 26:

Рисунок 25. Запуск Тестера стратегий

Рисунок 29. Запуск Тестера стратегий

Окно тестера стратегий появится в нижней части клиентского терминала. Для того, чтобы увидеть настройки Тестера стратегий, нужно увеличить его окно. Для этого передвиньте указатель мыши в точку, отмеченную на рисунке 27:

Рисунок 27. Окно Тестера стратегий

Рисунок 30. Окно Тестера стратегий

Указатель мыши изменит свой вид, превратившись в двойные стрелки, удерживая мышь, нужно увеличить окно Тестера до высоты, при которой все его настройки видны.

Рисунок 28. Вкладка "Настройки" Тестера

Рисунок 31. Вкладка "Настройки" Тестера

  1. Выберите советника, который нужно протестировать.
  2. Выбор валютной пары для тестирования.
  3. Выбор периода/таймфрейма для тестирования (выберем H2).
  4. Выберите "Select Custom" чтобы производить тестирование на указанном историческом интервале.
  5. Выбор дат начала и окончания тестирования.
  6. Выберем режим торговли "Обычный".
  7. Выбор начального депозита для тестирования.
  8. Не будем использовать оптимизицию параметров советника (Отключена)
  9. Нажмите кнопку "Старт", когда будете готовы начать тестирование.

Перед тем, как нажать кнопку "Старт", посмотрим на другие вкладки Тестера.

Вкладка "Агенты"

В процессе тестирования могут использоваться агенты (локальные и удаленные), их количество определяется количеством ядер процессора (если другие компьютеры не используются) и настройками удаленных агентов, если используются сетевые компьютеры.

Рисунок 29. Вкладка "Агенты" Тестера стратегий.


Рисунок 32. Вкладка "Агенты" Тестера стратегий

Для одного агента в процессе тестирования вкладка "Агенты" имеет вид:

Рисунок 30. Агенты Тестера стратегий в процессе тестирования

Рисунок 33. Агенты Тестера стратегий в процессе тестирования

Вкладка "Журнал"

В этой вкладке показываются все события, которые происходят в течение процесса тестирования.

Рисунок 31. Вкладка "Журнал" Тестера стратегий показывает активность советника при тестировании

Рисунок 34. Вкладка "Журнал" Тестера стратегий показывает активность советника при тестировании

Вкладка "Входные параметры"

Здесь можно указать входные параметры советника.

Рисунок 32. Вкладка "Входные параметры" советника в Тестере стратегий

Рисунок 35. Вкладка "Входные параметры" советника в Тестере стратегий

Если используется оптимизация параметров при тестировании, нужно указать значения переменных, выделенных на рис. 31.

  • Старт - начальное значение параметра
  • Шаг - шаг изменения параметра
  • Стоп - конечное значение параметра для тестера.

Тем не менее, в нашем советнике мы не будем производить поиск оптимальных параметров, поэтому нам они не нужны.

После того, как все установлено, вернемся обратно во вкладку "Настройки" и нажмем кнопку "Старт". Тестер начнет свою работу. Все, что нужно сейчас - это подготовить еще одну кружку кофе, если же вы, как и я, хотите наблюдать за процессом, откройте вкладку "Журнал", в процессе тестирования там появятся сообщения о запросах и результатах проведения торговых операций.

Вкладка "График"

После ознакомления с содержимым вкладки "Журнал" можно посмотреть на новую вкладку "График", которая появилась в процессе тестирования. При переключении на вкладку "График" вы увидите график, показывающий увеличение и уменьшение баланса, в зависимости от результатов торговли в истории.

Рисунок 33. График результатов тестирования

Рисунок 36. График результатов тестирования

Вкладка "Результаты"

После завершения тестирования появится другая вкладка, называемая "Результаты" тестирования. Переключившись во вкладку результаты, вы увидите отчет о проведенном тестировании.

Рисунок 34. Отчет результатов Тестера стратегий

Рисунок 37. Отчет результатов Тестера стратегий

Видны чистая прибыль, общая прибыль, общее количество сделок, кол-во убыточных сделок и другие. 

Нажав правую кнопку мыши во вкладке "Результаты", вы увидите контектное меню. Выберите пункт "Сохранить как отчет":

Рисунок 35. Сохранение результатов тестирования

Рисунок 38. Сохранение результатов тестирования

Появится диалог сохранения файла, напишите имя файла для отчета (если хотите, можно использовать имя, преложенное по умолчанию) и нажимте кнопку "Сохранить". Полный отчет будет сохранен в файле формата HTML.

Для того, чтобы увидеть результаты торговли на графике, выберите пункт "Открыть график" и увидите график вида:

Рисунок 36. График с результатами тестирования на истории

Рисунок 39. График с результатами тестирования на истории

Мы успешно написали и протестировали наш советник на истории и теперь имеем заготовку для дальнейшей работы. Можно опять вернуться во вкладку "Настройки" Тестера стратегий и протестировать его на другом временном интервале.

Интересно посмотреть, как он покажет себя на различных парах и таймфреймах, буду рад, если вы поделитесь со мной результатами.


Выводы

В этом пошаговом руководстве мы смогли рассмотреть основные шаги, необходимые для написания простого советника, основанного на заданной торговой стратегии. Мы рассмотрели, как можно проверить работу советника на наличие ошибок с использованием отладчика. Также мы обсудили, как протестировать результаты торговли нашего советника, используя Тестер стратегий. Мы смогли увидеть мощь и робастность нового языка MQL5.

Полученный в результате советник пока не является безупречным или завершенным, многие улучшения еще предстоит сделать для его использования в реальной торговле.

Еще многому необходимо научиться, я рекомендую еще раз прочитать эту статью вместе с документацией по MQL5, попробуйте все, чему вы научились в статье, и смею вас заверить, что вскоре в недалеком будущем вы сможете сами писать торговых советников.

Happy coding.


Перевод с английского произведен MetaQuotes Software Corp.
Оригинальная статья: https://www.mql5.com/en/articles/100

Прикрепленные файлы |
my_first_ea.mq5 (24.02 KB)
Последние комментарии | Перейти к обсуждению на форуме трейдеров (86)
Vladimir Karputov
Vladimir Karputov | 26 фев 2016 в 06:10
Dadayance:

Доброго времени суток всем.

Подскажите, как адаптировать советника MT5 для торговли на фондовой секции ммвб?

Ни один советник не работает... 

Скорее всего всё дело в:

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

Неполные сведения FOK заявки

Karputov Vladimir, 2015.10.06 09:10

Если с помощью визарда собрали советника, то попробуйте дописать такой код:

//+------------------------------------------------------------------+
//| Initialization function of the expert                            |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Initializing expert
   if(!ExtExpert.Init(Symbol(),Period(),Expert_EveryTick,Expert_MagicNumber))
     {
      //--- failed
      printf(__FUNCTION__+": error initializing expert");
      ExtExpert.Deinit();
      return(INIT_FAILED);
     }
//---
   CExpertTrade *MyTrade=new CExpertTrade;
      if(MyTrade==NULL)
     {
      //--- failed
      printf(__FUNCTION__+": error creating MyTrade");
     }
   MyTrade.SetTypeFilling(ORDER_FILLING_RETURN);
   ExtExpert.InitTrade(1,MyTrade);
//--- Creating signal
   CExpertSignal *signal=new CExpertSignal;
   if(signal==NULL)

Dadayance
Dadayance | 27 фев 2016 в 15:41
Karputov Vladimir:

Скорее всего всё дело в:


Спасибо, Владимир, попробую в понедельник
Stairway_2_7
Stairway_2_7 | 23 мар 2016 в 20:51

Добрый день!

Снова

My_First_EA (EURUSD,H1) 2016.03.01 07:00:00   Alert: Запрос на установку ордера Sell не выполнен - код ошибки:4756.

ZeroMemory(mrequest)  добавил перед    mrequest.action = TRADE_ACTION_DEAL;  

В коде еще

MqlRates mrate[];           // Будет содержать цены, объемы и спред для каждого бара

   ZeroMemory(mrequest);

/*

     Установим индексацию в массивах котировок и индикаторов 

     как в таймсериях

*/

// массив котировок

   ArraySetAsSeries(mrate,true); 

 

Подскажите, как пофиксить, пожалуйста!

 

Upd.        

 

 mrequest.type_filling = ORDER_FILLING_IOC; 

 mrequest.type_time    = ORDER_TIME_DAY;  

 

Спасибо, Karputov Vladimir 2016.02.26 06:10!

 https://www.mql5.com/ru/forum/15020#comment_1950544

travs
travs | 21 апр 2016 в 01:55
Сделки, указанные на приведённой части графика цены при тестировании у меня совпадают, однако график баланса/средств разительно отличается. ))  Я не понимаю, просто, за каким фигом вставлять в такие статьи липовые графики, изображая прибыльность? Это же пример! Никто не будет в претензии, если пример даёт стабильный убыток, но зачем вводить людей в заблуждение?! Я кучу времени потратил, разбираясь, что я делаю не так, почему у меня график баланса другой. Я, конечно, извиняюсь, что был слегка наивен, ожидая графика как на картинке. Может тут типа все в курсе, что это "для красоты" делается, но я, вот, не знал.
travs
travs | 22 апр 2016 в 00:56
AsketSD:

После некоторых трудностей тестер отработал полностью и выдал результаты, совпадаюшие с заявленными результатами в статье.

А как это может такое быть: одинаковый код, одинаковые входные данные, а результат разный? ))

Я не понимаю. У меня ничего похоже на приведённый график баланса не выходит.

Создание и публикация отчетов о результатах торговли, отправка SMS-сообщений Создание и публикация отчетов о результатах торговли, отправка SMS-сообщений

Трейдер не всегда имеет возможность и желание находиться часами перед торговым терминалом. Особенно, если торговая система в той или иной степени формализована и позволяет автоматически идентифицировать некоторые состояния рынка. В данной статье описано, как с помощью советника, индикатора или скрипта сформировать отчет о результатах торговли в виде html-файла и загрузить его по протоколу FTP на WWW-сервер, рассмотрен вопрос отправки уведомлений о торговых событиях на мобильный телефон в виде SMS-сообщений.

Обработка торговых событий в эксперте при помощи функции OnTrade() Обработка торговых событий в эксперте при помощи функции OnTrade()

В 5-ой версии языка MQL появилась масса нововведений, в том числе работа с событиями различных типов (события таймера, торговые события, пользовательские и т.д.). Возможность обработки событий позволяет создавать совершенно новый тип программ для автоматического и полуавтоматического трейдинга. В этой статье мы рассмотрим торговые события и напишем для функции OnTrade() код, который будет обрабатывать событие Trade.

Как заказать торгового робота на MQL5 и MQL4 Как заказать торгового робота на MQL5 и MQL4

С запуском сервиса "Работа" MQL5.community становится идеальным местом для размещения заказов и оказания услуг программирования. Тысячи трейдеров и разработчиков ежедневно посещают этот ресурс и с легкостью могут помочь друг другу. Для трейдера сервис "Работа" - это легкая возможность получить свой собственный эксперт. Для MQL5-разработчика это возможность легко найти новых клиентов. В данной статье мы рассмотрим возможности этого сервиса.

Библиотека для построения  диаграмм средствами Google Chart API Библиотека для построения диаграмм средствами Google Chart API

Построение разного рода диаграмм является неотъемлемой частью анализа рыночной ситуации и тестирования торговой системы. Зачастую, чтобы построить красивую наглядную диаграмму приходится организовать вывод данных в файл, после чего использовать его в приложениях типа MS Excel, что не слишком удобно и лишает нас возможности динамического обновления данных. Google Charts API предоставляет средства для создания диаграмм в он-лайн режиме путём отправки специального запроса на сервер. В статье делается попытка автоматизировать процесс создания запроса и получения диаграммы с сервера Google.