ResourceReadImage

ResourceCreate() 関数で作成されたまたはコンパイル中に EX5 ファイルに保存されたグラフィックリソースからデータを読みます。

bool ResourceReadImage(
const string resource_name, // 読まれるグラフィックリソース名
uint& data[], // リソースからデータを受け取るための配列
uint& width, // リソースの画像幅を受け取る
uint& height, // リソースの画像の高さを受け取る
);

パラメータ

resource_name

[in] 画像を含むグラフィクリソースの名称。自身のリソースにアクセスするには、「::ResourceName」が名称として使用されます。コンパイルされた EX5 ファイルからリソースをダウンロードする場合、完全な名称は「path\\filename.ex5::resourcename」のようにMQL5ディレクトリ、ファイル名とリソース名の相対パスが使用されるべきです。

data[][]

[in] グラフィックリソースからデータを受け取るための 1 次元または 2 次元の配列。

img_width

[out] グラフィックリソース画像の幅（ピクセル単位）。

img_height

[out] グラフィックリソース画像の高さ（ピクセル単位）。

戻り値

成功の場合は true、それ以外の場合は false 。エラー情報を取得するには、GetLastError() 関数が呼ばれます。

注意事項

data[] 配列がグラフィックリソースの作成に使用される場合, COLOR_FORMAT_ARGB_NORMALIZE または COLOR_FORMAT_XRGB_NOALPHA カラーフォーマットが使用されるべきです。

data[] 配列が 2 次元で、2 番目の次元が、グラフィカルリソースサイズのX（幅）より小さい場合、ResourceReadImage() 関数はfalseを返し、読み込みが行われません。しかし、もしリソースが存在すれば、実際の画像サイズが幅と高さのパラメータに返されます。これで、リソースからのデータ受けとりをもう一度試むことが可能になります。

例：

//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- グラフィックリソースのパラメータを宣言する
string rc_name="Resource";
uint rc_width=100;
uint rc_height=100;
uint rc_data[];
uint rc_size=rc_width*rc_height;

ResetLastError();
//--- ピクセル配列のサイズを設定する
if(ArrayResize(rc_data,rc_size)!=rc_size)
{
Print("ArrayResize() failed. Error code: ",GetLastError());
return;
}
//--- ピクセル配列を透明色で塗りつぶし、それに基づいてグラフィックリソースを作成する
ArrayInitialize(rc_data,0x00FFFFFF);
if(!ResourceCreate(rc_name,rc_data,rc_width,rc_height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
{
Print("ResourceCreate() failed. Error code: ",GetLastError());
return;
}
Print("Size of created recource array: ",rc_data.Size());

//--- 作成されたグラフィックリソースを確認する
//--- 現在の足の時間と価格のデータを取得する
MqlTick tick={};
if(!SymbolInfoTick(Symbol(),tick))
{
Print("SymbolInfoTick() failed. Error code: ",GetLastError());
return;
}
//--- 最後のティック価格と時刻の座標を使用してBitmapオブジェクトを作成する
string obj_name="Bitmap";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP,0,tick.time,tick.bid))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- 作成されたビットマップオブジェクトの幅と高さを、グラフィックリソースの幅と高さに等しく設定する
//--- オブジェクトのアンカーポイントをその中心に設定する
ObjectSetInteger(0,obj_name,OBJPROP_XSIZE,rc_width);
ObjectSetInteger(0,obj_name,OBJPROP_YSIZE,rc_height);
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- ビットマップオブジェクト用に以前に作成したグラフィックリソースを画像ファイルとして指定する
//--- この場合、使用されるグラフィックリソースの名前を示すために、その名前の前に「::」を追加する必要がある
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"::"+rc_name);

//--- 透明度200でDodgerBlue色を設定する
uint clr=ColorToARGB(clrDodgerBlue,200);
//--- グラフィックリソースのピクセル配列全体を設定された色で塗りつぶす
ArrayInitialize(rc_data,clr);
//--- グラフィックリソースデータを更新する
Update(rc_name,rc_data,rc_width,rc_height,true);

//--- グラフィカルリソースデータを読み取る前に3秒待機する
Print("Wait 3 seconds before ResourceReadImage()");
Sleep(3000);
//--- 画像をリソースから新しいピクセル配列に読み込む
uint rc_data_copy[];
uint w=0,h=0;
ResetLastError();
if(!ResourceReadImage("::"+rc_name,rc_data_copy,w,h))
{
Print("ResourceReadImage() failed. Error code: ",GetLastError());
return;
}

//--- 透明度200でOrangeRed色を設定する
clr=ColorToARGB(clrOrangeRed,200);
//--- グラフィックリソースのピクセル配列全体を設定された色で塗りつぶし、それに基づいて新しいグラフィックリソースを作成する
ArrayInitialize(rc_data_copy,clr);
if(!ResourceCreate(rc_name+"Copy",rc_data_copy,rc_width,rc_height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
{
Print("New ResourceCreate() failed. Error code: ",GetLastError());
return;
}
Print("Size of created new recource array: ",rc_data_copy.Size());

//--- 最後のティック価格と時刻の座標を使用して「グラフィックラベル」オブジェクトを作成する
string obj_name2="BitmapLabel";
if(!ObjectCreate(0,obj_name2,OBJ_BITMAP_LABEL,0,0,0))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- 以前に受け取った価格と時間を使用して画面座標を取得する
int x=0,y=0;
if(!ChartTimePriceToXY(0,0,tick.time,tick.bid,x,y))
{
Print("New ChartTimePriceToXY() failed. Error code: ",GetLastError());
return;
}
//--- 作成されたグラフィカルラベルオブジェクトの幅と高さを、グラフィカルリソースの幅と高さに等しく設定する
//--- オブジェクトのアンカーポイントをその中心に設定する
ObjectSetInteger(0,obj_name2,OBJPROP_XSIZE,rc_width);
ObjectSetInteger(0,obj_name2,OBJPROP_YSIZE,rc_height);
ObjectSetInteger(0,obj_name2,OBJPROP_ANCHOR,ANCHOR_LEFT_UPPER);
ObjectSetInteger(0,obj_name2,OBJPROP_XDISTANCE,x);
ObjectSetInteger(0,obj_name2,OBJPROP_YDISTANCE,y);
//--- コピーしたグラフィックリソースをグラフィックラベルオブジェクトの画像ファイルとして設定する
//--- この場合、使用されるグラフィックリソースの名前を示すために、その名前の前に「::」を追加する必要がある
ObjectSetString(0,obj_name2,OBJPROP_BMPFILE,"::"+rc_name+"Copy");

//--- 新しいグラフィカルラベルオブジェクトの色を変更する
Print("Wait 3 seconds before changing color to GreenYellow");
Sleep(3000);
//--- 透明度200でGreenYellow色を設定する
clr=ColorToARGB(clrGreenYellow,200);
//--- 新しいグラフィックリソースのピクセル配列全体を設定された色で塗りつぶす
ArrayInitialize(rc_data_copy,clr);
//--- グラフィックリソースデータを更新する
Update(rc_name+"Copy",rc_data_copy,rc_width,rc_height,true);

//--- 3秒待ってリソースと両方のオブジェクトを削除する
Print("Wait 3 seconds before deleting both objects");
Sleep(3000);
Print("Deleting Resource and all Bitmap objects");
ResourceFree("::"+rc_name);
ResourceFree("::"+rc_name+"Copy");
ObjectDelete(0,obj_name);
ObjectDelete(0,obj_name2);
}
//+------------------------------------------------------------------+
//| グラフィックリソースデータを更新する　　　　　　　 |
//+------------------------------------------------------------------+
void Update(const string res_name,const uint &pixel_data[],const uint width,const uint height,const bool redraw)
{
//--- ゼロ次元が渡された場合は終了する
if(width==0 || height==0)
return;
//--- リソースデータを更新し、チャートを再描画する
if(ResourceCreate(res_name,pixel_data,width,height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}

参照

リソース、ObjectCreate()、ObjectSetString()、OBJPROP_BMPFILE

ResourceFree

ResourceSave