GetMicrosecondCount

ulong  GetMicrosecondCount();

//+------------------------------------------------------------------+
//| テスト関数　                                                         |
//+------------------------------------------------------------------+
void Test()
 {
  int    res_int=0;
  double res_double=0;
//---  
  for(int i=0;i<10000;i++)
    {
     res_int+=i*i;
     res_int++;
     res_double+=i*i;
     res_double++;
    }
 }
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  uint   ui=0,ui_max=0,ui_min=INT_MAX;
  ulong  ul=0,ul_max=0,ul_min=INT_MAX;
//--- 測定値の数
  for(int count=0;count<1000;count++)
    {
    uint  ui_res=0;
    ulong ul_res=0;
    //---
    for(int n=0;n<2;n++)
       {
        //--- 測定の種類を選ぶ
        if(n==0) ui=GetTickCount();
        else     ul=GetMicrosecondCount();
        //--- コードを実行する
        Test();
        //--- 測定結果を追加する（種類に応じて）
        if(n==0) ui_res+=GetTickCount()-ui;
        else     ul_res+=GetMicrosecondCount()-ul;        
       }
    //--- 測定値の最小時間と最大時間を計算する
    if(ui_min>ui_res) ui_min=ui_res;
    if(ui_max<ui_res) ui_max=ui_res;
    if(ul_min>ul_res) ul_min=ul_res;
    if(ul_max<ul_res) ul_max=ul_res;
    }
//---
  Print("GetTickCount error(msec): ",ui_max-ui_min);
  Print("GetMicrosecondCount error(msec): ",DoubleToString((ul_max-ul_min)/1000.0,2));
 }