GetPointer

この関数はオブジェクトポインタを返します。

void*  GetPointer(
  any_class anyobject      // 任意のクラスオブジェクト
  );

パラメータ

anyobject

[in]  任意のクラスオブジェクト

戻り値

オブジェクトポインタ

注意事項

クラスオブジェクトのみがポインタを持ちます。構造体インスタンスと基本データ型の変数にはポインタはありません。new() 演算子によって作成されなくても、例えばオブジェクトの配列で自動的に作成されたクラスオブジェクトにはポインタがあります。しかし、このポインタは POINTER_AUTOMATIC 型の自動型であり、delete() 演算子が適用出来ません。これ以外の点では、ポインタ型は POINTER_AUTOMATIC 型の動的ポインタとは異なりません。

構造体型また基本データ型の変数はポインタを持っていないので、それらに GetPointer() 関数を適用することは禁じられています。また、ポインタを関数の引数として渡すことも禁止されています。これらの場合全てで、コンパイラはエラーを通知します。

不正なポインタを呼び出す試みはプログラムの緊急終了を生じます。これが、ポインタを使用する前に CheckPointer() 関数を呼び出すのが必要な理由です。ポインタは、次のような場合に不正であることがあります。

  • ポインタが NULL
  • オブジェクトが delete 演算子で削除された

この関数は、ポインタの有効性を確認するために使用することが出来ます。ゼロ以外の値はポインタアクセスを保証します。

例:

//+------------------------------------------------------------------+
//|                                             Check_GetPointer.mq5 |
//|                        Copyright 2009, MetaQuotes Software Corp. |
//|                                             https://www.MQL5.com |
//+------------------------------------------------------------------+
#property copyright "2009, MetaQuotes Software Corp."
#property link     "https://www.mql5.com"
#property version   "1.00"
 
//+------------------------------------------------------------------+
//| リスト要素を実装するクラス                                               |
//+------------------------------------------------------------------+
class CItem
 {
  int               m_id;
  string            m_comment;
  CItem*            m_next;
public:
                    CItem() { m_id=0; m_comment=NULL; m_next=NULL; }
                   ~CItem() { Print("Destructor of ",m_id,
                                    (CheckPointer(GetPointer(this))==POINTER_DYNAMIC)?
                                    "dynamic":"non-dynamic"); }
  void              Initialize(int id,string comm) { m_id=id; m_comment=comm; }
  void              PrintMe() { Print(__FUNCTION__,":",m_id,m_comment); }
  int               Identifier() { return(m_id); }
  CItem*            Next() {return(m_next); }
  void              Next(CItem *item) { m_next=item; }
 };
//+------------------------------------------------------------------+
//| リストの最も単純なクラス                                                 |
//+------------------------------------------------------------------+
class CMyList
 {
  CItem*            m_items;
public:
                    CMyList() { m_items=NULL; }
                   ~CMyList() { Destroy(); }
  bool             InsertToBegin(CItem* item);
  void             Destroy();
 };
//+------------------------------------------------------------------+
//| 先頭にリスト要素を挿入する                                              |
//+------------------------------------------------------------------+
bool CMyList::InsertToBegin(CItem* item)
 {
  if(CheckPointer(item)==POINTER_INVALID) return(false);
//---
  item.Next(m_items);
  m_items=item;
//---
  return(true);
 }
//+------------------------------------------------------------------+
//| 要素の削除によってリストを削除する                                         |
//+------------------------------------------------------------------+
void CMyList::Destroy()
 {
//--- ループの中で作業するためのサービスポインタ
  CItem* item;
//--- ループを通過し、動的なポインタの削除を試みる
  while(CheckPointer(m_items)!=POINTER_INVALID)
    {
     item=m_items;
     m_items=m_items.Next();
    if(CheckPointer(item)==POINTER_DYNAMIC)
       {
        Print("Dynamyc object ",item.Identifier()," to be deleted");
        delete (item);
       }
    else Print("Non-dynamic object ",item.Identifier()," cannot be deleted");
    }
//---
 }
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数                                          |
//+------------------------------------------------------------------+
void OnStart()
 {
  CMyList list;
  CItem   items[10];
  CItem*  item;
//--- 作成し、リスト動的オブジェクトのポインタに追加
  item=new CItem;
  if(item!=NULL)
    {
     item.Initialize(100,"dynamic");
     item.PrintMe();
     list.InsertToBegin(item);
    }
//--- 自動ポインタをリストに追加する
  for(int i=0; i<10; i++)
    {
     items[i].Initialize(i,"automatic");
     items[i].PrintMe();
     item=GetPointer(items[i]);
    if(CheckPointer(item)!=POINTER_INVALID)
        list.InsertToBegin(item);
    }
//--- リスト先頭に動的なオブジェクトポインタをあと 1 つ追加する
  item=new CItem;
  if(item!=NULL)
    {
     item.Initialize(200,"dynamic");
     item.PrintMe();
     list.InsertToBegin(item);
    }
//--- リスト要素を全て削除する
  list.Destroy();
//--- スクリプト終了後、全てのリスト要素が削除される
//--- 端末内の「エキスパート」タブを参照する
 }

参照

オブジェクトポインタオブジェクトポインタのチェックdelete オブジェクト解除演算子