Descargar MetaTrader 5

OBJ_VLINE

Linea vertical.

ObjVLine

Nota

Cuando se crea una línea vertical, se puede indicar el modo de visualización de la línea en todas las ventanas del gráfico (propiedad OBJPROP_RAY).

Ejemplo

El siguiente script crea y desplaza una línea vertical en el gráfico. Para la creación y modificación de las propiedades del objeto gráfico han sido escritas unas funciones especiales que Usted puede utilizar "como son" en sus propias aplicaciones.

//--- descripción
#property description "El script construye el objeto gráfico \"Línea vertical\"."
#property description "La fecha del punto de anclaje se establece en por cientos del ancho"
#property description "de la ventana del gráfico en barras."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string          InpName="VLine";     // Nombre de la línea
input int             InpDate=25;          // Fecha de la línea en %
input color           InpColor=clrRed;     // Color de la línea
input ENUM_LINE_STYLE InpStyle=STYLE_DASH// Estilo de la línea
input int             InpWidth=3;          // Grosor de la línea
input bool            InpBack=false;       // Línea al fondo
input bool            InpSelection=true;   // Seleccionar para mover
input bool            InpRay=true;         // Continuación de la línea abajo
input bool            InpHidden=true;      // Ocultar en la lista de objetos
input long            InpZOrder=0;         // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crear línea vertical                                       |
//+------------------------------------------------------------------+
bool VLineCreate(const long            chart_ID=0,        // ID del gráfico
                 const string          name="VLine",      // nombre de la línea
                 const int             sub_window=0,      // índice de subventana
                 datetime              time=0,            // hora de la línea
                 const color           clr=clrRed,        // color de la línea
                 const ENUM_LINE_STYLE style=STYLE_SOLID// estilo de la línea
                 const int             width=1,           // grosor de la línea
                 const bool            back=false,        // al fondo
                 const bool            selection=true,    // seleccionar para mover
                 const bool            ray=true,          // continuación de la línea abajo
                 const bool            hidden=true,       // ocultar en la lista de objetos
                 const long            z_order=0)         // prioridad para el clic del ratón
  {
//--- si la hora de la línea no está definida, la trazamos en la última barra
   if(!time)
      time=TimeCurrent();
//--- anulamos el valor del error
   ResetLastError();
//--- creamos la línea vertical
   if(!ObjectCreate(chart_ID,name,OBJ_VLINE,sub_window,time,0))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al crear la línea vertical! Código del error = ",GetLastError());
      return(false);
     }
//--- establecemos el color de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de visualización de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el grosor de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostramos en el primer plano (false) o al fondo (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de desplazamiento de la línea con ratón
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- activar (true) o desactivar (false) el modo de visualización de la línea en las subventanas del gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY,ray);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Mover línea vertical                                   |
//+------------------------------------------------------------------+
bool VLineMove(const long   chart_ID=0,   // ID del gráfico
               const string name="VLine"// nombre de la línea
               datetime     time=0)       // hora de la línea
  {
//--- si la hora de la línea no está definida, la movemos a la última barra
   if(!time)
      time=TimeCurrent();
//--- anulamos el valor del error
   ResetLastError();
//--- movemos la línea vertical
   if(!ObjectMove(chart_ID,name,0,time,0))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al mover la línea vertical! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Eliminar línea vertical                                       |
//+------------------------------------------------------------------+
bool VLineDelete(const long   chart_ID=0,   // ID del gráfico
                 const string name="VLine"// nombre de la línea
  {
//--- anulamos el valor del error
   ResetLastError();
//--- eliminamos la línea vertical
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al eliminar la línea vertical! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- comprobamos si los parámetros de entrada son correctos
   if(InpDate<0 || InpDate>100)
     {
      Print("¡Error. Los parámetros de entrada no son correctos!");
      return;
     }
//--- número de barras visibles en la ventana del gráfico
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- array para guardar los valores de las fechas que van a utilizarse
//--- para establecer y cambiar las coordenadas del punto de anclaje de la línea
   datetime date[];
//--- asignación de la memoria
   ArrayResize(date,bars);
//--- llenamos el array de datos
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
      return;
     }
//--- definimos puntos para trazar la línea
   int d=InpDate*(bars-1)/100;
//--- creamos la línea vertical
   if(!VLineCreate(0,InpName,0,date[d],InpColor,InpStyle,InpWidth,InpBack,
      InpSelection,InpRay,InpHidden,InpZOrder))
      return;
//--- redibujamos el gráfico y esperamos 1 segundo
   ChartRedraw();
   Sleep(1000);
//--- ahora vamos a mover la línea
//--- contador del ciclo
   int h_steps=bars/2;
//--- movemos la línea
   for(int i=0;i<h_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(d<bars-1)
         d+=1;
      //--- movemos el punto
      if(!VLineMove(0,InpName,date[d]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
      // retardo de 0,03 segundo
      Sleep(30);
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- eliminamos el canal desde el gráfico
   VLineDelete(0,InpName);
   ChartRedraw();
//--- retardo de 1 segundo
   Sleep(1000);
//---
  }


Actualizado: 2015.12.03