OBJ_ARROW_SELL

Signo "Sell".

ObjArrowSell

Ejemplo

El siguiente script crea y desplaza el signo "Sell" en el gráfico. Para la creación y modificación de las propiedades del objeto gráfico han sido escritas unas funciones especiales que Usted puede utilizar "como son" en sus propias aplicaciones.

 

//--- descripción
#property description "El script dibuja el signo \"Sell\" en la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input color InpColor=C'225,68,29'// Color de signos
//+------------------------------------------------------------------+
//| Crea el signo "Sell"                                              |
//+------------------------------------------------------------------+
bool ArrowSellCreate(const long            chart_ID=0,        // ID del gráfico
                     const string          name="ArrowSell",  // nombre del signo
                     const int             sub_window=0,      // número de subventana
                     datetime              time=0,            // hora del punto de anclaj
                     double                price=0,           // precio del punto de anclaj
                     const color           clr=C'225,68,29',  // color del signo
                     const ENUM_LINE_STYLE style=STYLE_SOLID// estilo de la línea (durante la selección)
                     const int             width=1,           // tamaño de la línea (durante la selección)
                     const bool            back=false,        // al fondo
                     const bool            selection=false,   // seleccionar para mover
                     const bool            hidden=true,       // ocultar en la lista de objetos
                     const long            z_order=0)         // prioridad para el clic del ratón
  {
//--- establecemos las coordenadas del punto de anclaje si todavía no han sido establecidas
   ChangeArrowEmptyPoint(time,price);
//--- anulamos el valor del error
   ResetLastError();
//--- creamos el signo
   if(!ObjectCreate(chart_ID,name,OBJ_ARROW_SELL,sub_window,time,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al crear el signo \"Sell\"! Código del error = ",GetLastError());
      return(false);
     }
//--- establecemos el color del signo
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de la línea (durante la selección)
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el tamaño de la línea (durante la selección)
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostramos en el primer plano (false) o al fondo (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de desplazamiento del signo con ratón
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Mueve el punto de anclaje                                        |
//+------------------------------------------------------------------+
bool ArrowSellMove(const long   chart_ID=0,       // ID del gráfico
                   const string name="ArrowSell"// nombre del objeto
                   datetime     time=0,           // coordenada del tiempo del punto de anclaje
                   double       price=0)          // coordenada del precio del punto de anclaje
  {
//--- si las coordenadas del punto de anclaje no han sido establecidas, lo movemos a la barra actual con el precio Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
   ResetLastError();
//--- movemos el punto de anclaje
   if(!ObjectMove(chart_ID,name,0,time,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al mover el punto de anclaje! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Elimina el signo "Sell"                                              |
//+------------------------------------------------------------------+
bool ArrowSellDelete(const long   chart_ID=0,       // ID del gráfico
                     const string name="ArrowSell"// nombre del gráfico
  {
//--- anulamos el valor del error
   ResetLastError();
//--- eliminamos el signo
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al eliminar el signo \"Sell\"! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Comprueba los valores de los puntos de anclaje y para          |
//| los valores vacíos establece los valores por defecto                              |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
  {
//--- si la hora del punto no ha sido establecida, se colocará en la barra actual
   if(!time)
      time=TimeCurrent();
//--- si el precio del punto no ha sido establecido, tendrá el valor Bid
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date[]; // array para guardar las fechas de las barras visibles
   double   low[];  // array para guardar los precios Low de las barras visibles
   double   high[]; // array para guardar los precios High de las barras visibles
//--- número de barras visibles en la ventana del gráfico
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- asignación de la memoria
   ArrayResize(date,bars);
   ArrayResize(low,bars);
   ArrayResize(high,bars);
//--- llenamos el array de datos
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
      return;
     }
//--- llenamos el array de precios Low
   if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
     {
      Print("¡Fallo al copiar los valores de los precios Low! Código del error = ",GetLastError());
      return;
     }
//--- llenamos el array de precios High
   if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
     {
      Print("¡Fallo al copiar los valores de los precios High! Código del error = ",GetLastError());
      return;
     }
//--- creamos los signos "Sell" en el punto High para barra visible
   for(int i=0;i<bars;i++)
     {
      if(!ArrowSellCreate(0,"ArrowSell_"+(string)i,0,date[i],high[i],InpColor))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
      // retardo de 0,05 segundo
      Sleep(50);
     }
//--- movemos los signos "Sell" al punto Low para cada barra visible
   for(int i=0;i<bars;i++)
     {
      if(!ArrowSellMove(0,"ArrowSell_"+(string)i,date[i],low[i]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
      // retardo de 0,05 segundo
      Sleep(50);
     }
//--- eliminamos los signos "Sell"
   for(int i=0;i<bars;i++)
     {
      if(!ArrowSellDelete(0,"ArrowSell_"+(string)i))
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
      // retardo de 0,05 segundo
      Sleep(50);
     }
//---
  }