Descargar MetaTrader 5

OBJ_ELLIOTWAVE5

Onda de impulso de Elliott.

ObjElliotWave5

Nota

Para la "Onda de impulso de Elliott" se puede activar/desactivar el modo de unión de los puntos con líneas (propiedad OBJPROP_DRAWLINES), así como establecer el nivel de trazado ondular (desde la enumeración ENUM_ELLIOT_WAVE_DEGREE).

Ejemplo

El siguiente script crea y desplaza la "Onda de impulso de Elliott" en el gráfico. Para la creación y modificación de las propiedades del objeto gráfico han sido escritas unas funciones especiales que Usted puede utilizar "como son" en sus propias aplicaciones.

 

//--- descripción
#property description "El script construye el objeto gráfico \"Onda de impulso de Elliott\"."
#property description "Las coordenadas de los puntos de anclaje se establecen en por cientos de las dimensiones"
#property description "de la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string                  InpName="ElliotWave5";   // Nombre del objeto
input int                     InpDate1=10;             // Fecha del 1-er punto en %
input int                     InpPrice1=90;            // Precio del 1-er punto en %
input int                     InpDate2=20;             // Fecha del 2-do punto en %
input int                     InpPrice2=40;            // Precio del 2-do punto en %
input int                     InpDate3=30;             // Fecha del 3-er punto en %
input int                     InpPrice3=60;            // Precio del 3-er punto en %
input int                     InpDate4=40;             // Fecha del 4-to punto en %
input int                     InpPrice4=10;            // Precio del 4-to punto en %
input int                     InpDate5=60;             // Fecha del 5-to punto en %
input int                     InpPrice5=40;            // Precio del 5-to punto en %
input ENUM_ELLIOT_WAVE_DEGREE InpDegree=ELLIOTT_MINOR// Nivel
input bool                    InpDrawLines=true;       // Mostrar líneas
input color                   InpColor=clrRed;         // Color de las líneas
input ENUM_LINE_STYLE         InpStyle=STYLE_DASH;     // Estilo de las líneas
input int                     InpWidth=2;              // Grosor de las líneas
input bool                    InpBack=false;           // Objeto al fondo
input bool                    InpSelection=true;       // Seleccionar para mover
input bool                    InpHidden=true;          // Ocultar en la lista de objetos
input long                    InpZOrder=0;             // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crea la "Onda de impulso de Elliott" según las coordinadas establecidas       |
//+------------------------------------------------------------------+
bool ElliotWave5Create(const long                    chart_ID=0,              // ID del gráfico
                       const string                  name="ElliotWave5",      // nombre de la onda
                       const int                     sub_window=0,            // número de subventana 
                       datetime                      time1=0,                 // hora del primer punto
                       double                        price1=0,                // precio del primer punto
                       datetime                      time2=0,                 // hora del segundo punto
                       double                        price2=0,                // precio del segundo punto
                       datetime                      time3=0,                 // hora del tercer punto
                       double                        price3=0,                // precio del tercer punto
                       datetime                      time4=0,                 // hora del cuarto punto
                       double                        price4=0,                // precio del cuarto punto
                       datetime                      time5=0,                 // hora del quinto punto
                       double                        price5=0,                // precio del quinto punto
                       const ENUM_ELLIOT_WAVE_DEGREE degree=ELLIOTT_MINUETTE// grado
                       const bool                    draw_lines=true,         // mostrar líneas
                       const color                   clr=clrRed,              // color del objeto
                       const ENUM_LINE_STYLE         style=STYLE_SOLID,       // estilo de las líneas
                       const int                     width=1,                 // grosor de las líneas
                       const bool                    back=false,              // al fondo
                       const bool                    selection=true,          // seleccionar para mover
                       const bool                    hidden=true,             // ocultar en la lista de objetos
                       const long                    z_order=0)               // prioridad para el clic del ratón
  {
//--- establecemos las coordenadas de los puntos de anclaje si todavía no han sido establecidas
   ChangeElliotWave5EmptyPoints(time1,price1,time2,price2,time3,price3,time4,price4,time5,price5);
//--- anulamos el valor del error
   ResetLastError();
//--- creamos la "Onda de impulso de Elliott" según las coordinadas establecidas
   if(!ObjectCreate(chart_ID,name,OBJ_ELLIOTWAVE5,sub_window,time1,price1,time2,price2,time3,
      price3,time4,price4,time5,price5))
     {
      Print(__FUNCTION__,
            ": ¡Falo al crear la \"Onda de impulso de Elliott\"! Código del error = ",GetLastError());
      return(false);
     }
//--- establecemos el grado (tamaño de la onda)
   ObjectSetInteger(chart_ID,name,OBJPROP_DEGREE,degree);
//--- activar (true) o desactivar (false) el modo de visualización de las líneas
   ObjectSetInteger(chart_ID,name,OBJPROP_DRAWLINES,draw_lines);
//--- establecemos el color del objeto
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de las líneas
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- fijamos el grosor de las líneas
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostramos en el primer plano (false) o al fondo (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de selección del objeto para mover
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Mueve el punto de anclaje de la "Onda de impulso de Elliott"                    |
//+------------------------------------------------------------------+
bool ElliotWave5PointChange(const long   chart_ID=0,         // ID del gráfico
                            const string name="ElliotWave5"// nombre del objeto
                            const int    point_index=0,      // número del punto de anclaje
                            datetime     time=0,             // coordenada del tiempo del punto de anclaje
                            double       price=0)            // coordenada del precio del punto de anclaje
  {
//--- si las coordenadas del punto de anclaje no han sido establecidas, lo movemos a la barra actual con el precio Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
   ResetLastError();
//--- movemos el punto de anclaje
   if(!ObjectMove(chart_ID,name,point_index,time,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al mover el punto de anclaje! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Elimina la "Onda de impulso de Elliott"                               |
//+------------------------------------------------------------------+
bool ElliotWave5Delete(const long   chart_ID=0,         // ID del gráfico
                       const string name="ElliotWave5"// nombre del objeto
  {
//--- anulamos el valor del error
   ResetLastError();
//--- eliminamos el objeto
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": ¡Falo al eliminar la \"Onda de impulso de Elliott\"! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| //| Comprueba los valores de los puntos de anclaje de la "Onda de impulso de Elliott" y     |
//| para los valores vacíos establece los valores por defecto              |
//+------------------------------------------------------------------+
void ChangeElliotWave5EmptyPoints(datetime &time1,double &price1,
                                  datetime &time2,double &price2,
                                  datetime &time3,double &price3,
                                  datetime &time4,double &price4,
                                  datetime &time5,double &price5)
  {
//--- array para recibir la hora de apertura de las últimas 10 barras
   datetime temp[];
   ArrayResize(temp,10);
//--- recibimos los datos
   CopyTime(Symbol(),Period(),TimeCurrent(),10,temp);
//--- obtenemos el valor de un punto en al gráfico actual
   double point=SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- si la hora del primer punto no ha sido establecida, se colocará en la 9 barra a la izquierda de la última barra
   if(!time1)
      time1=temp[0];
//--- si el precio del primer punto no ha sido establecido, tendrá el valor Bid
   if(!price1)
      price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si la hora del segundo punto no ha sido establecida, se colocará en la 7 barra a la izquierda de la última barra
   if(!time2)
      time2=temp[2];
//--- si el precio del segundo punto no ha sido establecido, lo moveremos a 300 puntos por debajo del primer punto
   if(!price2)
      price2=price1-300*point;
//--- si la hora del tercer punto no ha sido establecida, se colocará en la 5 barra a la izquierda de la última barra
   if(!time3)
      time3=temp[4];
//--- si el precio del tercer punto no ha sido establecido, lo moveremos a 250 puntos por debajo del primer punto
   if(!price3)
      price3=price1-250*point;
//--- si la hora del cuarto punto no ha sido establecida, se colocará en la 3 barra a la izquierda de la última barra
   if(!time4)
      time4=temp[6];
//--- si el precio del cuarto punto no ha sido establecido, lo moveremos a 550 puntos por debajo del primer punto
   if(!price4)
      price4=price1-550*point;
//--- si la hora del quinto punto no ha sido establecida, se colocará en la última barra
   if(!time5)
      time5=temp[9];
//--- si el precio del quinto punto no ha sido establecido, lo moveremos a 450 puntos por debajo del primer punto
   if(!price5)
      price5=price1-450*point;
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- comprobamos si los parámetros de entrada son correctos
   if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 || 
      InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 || 
      InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100 || 
      InpDate4<0 || InpDate4>100 || InpPrice4<0 || InpPrice4>100 || 
      InpDate5<0 || InpDate5>100 || InpPrice5<0 || InpPrice5>100)
     {
      Print("¡Error. Los parámetros de entrada no son correctos!");
      return;
     }
//--- número de barras visibles en la ventana del gráfico
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamaño del array price
   int accuracy=1000;
//--- arrays para guardar los valores de las fechas y precios que van a utilizarse
//--- para establecer y modificar las coordenadas de los puntos de anclaje del objeto
   datetime date[];
   double   price[];
//--- asignación de la memoria
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- llenamos el array de datos
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
      return;
     }
//--- llenamos el array de precios
//--- encontramos el valor máximo y mínimo del gráfico
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- determinamos el paso del cambio del precio y llenamos el array
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- definimos los puntos para trazar la "Onda de impulso de Elliott"
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
   int d3=InpDate3*(bars-1)/100;
   int d4=InpDate4*(bars-1)/100;
   int d5=InpDate5*(bars-1)/100;
   int p1=InpPrice1*(accuracy-1)/100;
   int p2=InpPrice2*(accuracy-1)/100;
   int p3=InpPrice3*(accuracy-1)/100;
   int p4=InpPrice4*(accuracy-1)/100;
   int p5=InpPrice5*(accuracy-1)/100;
//--- creamos la "Onda de impulso de Elliott"
   if(!ElliotWave5Create(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
      date[d4],price[p4],date[d5],price[p5],InpDegree,InpDrawLines,InpColor,InpStyle,InpWidth,
      InpBack,InpSelection,InpHidden,InpZOrder))
     {
      return;
     }
//--- redibujamos el gráfico y esperamos 1 segundo
   ChartRedraw();
   Sleep(1000);
//--- ahora vamos a mover los puntos de anclaje
//--- contador del ciclo
   int v_steps=accuracy/5;
//--- movemos el quinto punto de anclaje
   for(int i=0;i<v_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(p5<accuracy-1)
         p5+=1;
      //--- movemos el punto
      if(!ElliotWave5PointChange(0,InpName,4,date[d5],price[p5]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- contador del ciclo
   v_steps=accuracy/5;
//--- movemos el segundo y el tercer punto de anclaje
   for(int i=0;i<v_steps;i++)
     {
      //--- cogemos los siguientes valores
      if(p2<accuracy-1)
         p2+=1;
      if(p3>1)
         p3-=1;
      //--- movemos los puntos
      if(!ElliotWave5PointChange(0,InpName,1,date[d2],price[p2]))
         return;
      if(!ElliotWave5PointChange(0,InpName,2,date[d3],price[p3]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- contador del ciclo
   v_steps=accuracy*4/5;
//--- movemos el primero y el cuarto punto de anclaje
   for(int i=0;i<v_steps;i++)
     {
      //--- cogemos los siguientes valores
      if(p1>1)
         p1-=1;
      if(p4<accuracy-1)
         p4+=1;
      //--- movemos los puntos
      if(!ElliotWave5PointChange(0,InpName,0,date[d1],price[p1]))
         return;
      if(!ElliotWave5PointChange(0,InpName,3,date[d4],price[p4]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- eliminamos el objeto desde el gráfico
   ElliotWave5Delete(0,InpName);
   ChartRedraw();
//--- retardo de 1 segundo
   Sleep(1000);
//---
  }