OBJ_HLINE

Línea horizontal.

ObjHLine

Ejemplo

El siguiente script crea y desplaza una línea horizontal en el gráfico. Para la creación y modificación de las propiedades del objeto gráfico han sido escritas unas funciones especiales que Usted puede utilizar "como son" en sus propias aplicaciones.

 

//--- descripción
#property description "El script construye el objeto gráfico \"Línea horizontal\"."
#property description "El precio del punto de anclaje se establece en por cientos del alto"
#property description "de la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string          InpName="HLine";     // Nombre de la línea
input int             InpPrice=25;         // Precio de la línea en %
input color           InpColor=clrRed;     // Color de la línea
input ENUM_LINE_STYLE InpStyle=STYLE_DASH// Estilo de la línea
input int             InpWidth=3;          // Grosor de la línea
input bool            InpBack=false;       // Línea al fondo
input bool            InpSelection=true;   // Seleccionar para mover
input bool            InpHidden=true;      // Ocultar en la lista de objetos
input long            InpZOrder=0;         // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crear línea horizontal                                     |
//+------------------------------------------------------------------+
bool HLineCreate(const long            chart_ID=0,        // ID del gráfico
                 const string          name="HLine",      // nombre de la línea
                 const int             sub_window=0,      // índice de subventana
                 double                price=0,           // precio de la línea
                 const color           clr=clrRed,        // color de la línea
                 const ENUM_LINE_STYLE style=STYLE_SOLID// estilo de la línea
                 const int             width=1,           // grosor de la línea
                 const bool            back=false,        // al fondo
                 const bool            selection=true,    // seleccionar para mover
                 const bool            hidden=true,       // ocultar en la lista de objetos
                 const long            z_order=0)         // prioridad para el clic del ratón
  {
//--- si el precio no ha sido establecido, la ponemos en el nivel del precio Bid actual
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
   ResetLastError();
//--- creamos la línea horizontal
   if(!ObjectCreate(chart_ID,name,OBJ_HLINE,sub_window,0,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al crear la línea horizontal! Código del error = ",GetLastError());
      return(false);
     }
//--- establecemos el color de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de visualización de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el grosor de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostramos en el primer plano (false) o al fondo (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de desplazamiento de la línea con ratón
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Desplazamiento de la línea horizontal                                 |
//+------------------------------------------------------------------+
bool HLineMove(const long   chart_ID=0,   // ID del gráfico
               const string name="HLine"// nombre de la línea
               double       price=0)      // precio de la línea
  {
//--- si el precio de la línea no ha sido establecido, la movemos en el nivel del precio Bid actual
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
   ResetLastError();
//--- movemos la línea horizontal
   if(!ObjectMove(chart_ID,name,0,0,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al mover la línea horizontal! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Eliminar la línea horizontal                                     |
//+------------------------------------------------------------------+
bool HLineDelete(const long   chart_ID=0,   // ID del gráfico
                 const string name="HLine"// nombre de la línea
  {
//--- anulamos el valor del error
   ResetLastError();
//--- eliminamos la línea horizontal
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al eliminar la línea horizontal! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- comprobamos si los parámetros de entrada son correctos
   if(InpPrice<0 || InpPrice>100)
     {
      Print("¡Error. Los parámetros de entrada no son correctos!");
      return;
     }
//--- tamaño del array price
   int accuracy=1000;
//--- array para guardar los valores de los precios que van a utilizarse
//--- para establecer y cambiar las coordenadas del punto de anclaje de la línea
   double price[];
//--- asignación de la memoria
   ArrayResize(price,accuracy);
//--- llenamos el array de precios
//--- encontramos el valor máximo y mínimo del gráfico
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- determinamos el paso del cambio del precio y llenamos el array
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- definimos puntos para trazar la línea
   int p=InpPrice*(accuracy-1)/100;
//--- creamos la línea horizontal
   if(!HLineCreate(0,InpName,0,price[p],InpColor,InpStyle,InpWidth,InpBack,
      InpSelection,InpHidden,InpZOrder))
     {
      return;
     }
//--- redibujamos el gráfico y esperamos 1 segundo
   ChartRedraw();
   Sleep(1000);
//--- ahora vamos a mover la línea
//--- contador del ciclo
   int v_steps=accuracy/2;
//--- movemos la línea
   for(int i=0;i<v_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(p<accuracy-1)
         p+=1;
      //--- movemos el punto
      if(!HLineMove(0,InpName,price[p]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- eliminamos del gráfico
   HLineDelete(0,InpName);
   ChartRedraw();
//--- retardo de 1 segundo
   Sleep(1000);
//---
  }