OBJ_GANNLINE

Línea de Gann.

ObjGannLine

Nota

Para la "Línea de Gann" se puede indicar el modo de su continuación a la derecha y/o a la izquierda (propiedades OBJPROP_RAY_RIGHT y OBJPROP_RAY_LEFT respectivamente).

Para establecer la inclinación de la línea se puede usar el ángulo de Gann con la escala, o bien las coordenadas del segundo punto de anclaje.

Ejemplo

El siguiente script crea y desplaza la "Línea de Gann" en el gráfico. Para la creación y modificación de las propiedades del objeto gráfico han sido escritas unas funciones especiales que Usted puede utilizar "como son" en sus propias aplicaciones.

 

//--- descripción
#property description "El script construye el objeto gráfico \"Línea de Gann\"."
#property description "Las coordenadas de los puntos de anclaje se establecen en por cientos"
#property description "de las dimensiones de la ventana del gráfico."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string          InpName="GannLine";        // Nombre de la línea
input int             InpDate1=20;               // Fecha del 1-er punto en %
input int             InpPrice1=75;              // Precio del 1-er punto en %
input int             InpDate2=80;               // Fecha del 2-do punto en %
input double          InpAngle=0.0;              // Ángulo de Gann
input double          InpScale=1.0;              // Escala
input color           InpColor=clrRed;           // Color de la línea
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT// Estilo de la línea
input int             InpWidth=2;                // Grosor de la línea
input bool            InpBack=false;             // Línea al fondo
input bool            InpSelection=true;         // Seleccionar para mover
input bool            InpRayLeft=false;          // Continuación de la línea a la izquierda
input bool            InpRayRight=true;          // Continuación de la línea a la derecha
input bool            InpHidden=true;            // Ocultar en la lista de objetos
input long            InpZOrder=0;               // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crea la "Línea de Gann" según las coordenadas, el ángulo y la escala            |
//+------------------------------------------------------------------+
bool GannLineCreate(const long            chart_ID=0,        // ID del gráfico
                    const string          name="GannLine",   // nombre de la línea
                    const int             sub_window=0,      // número de subventana
                    datetime              time1=0,           // hora del primer punto
                    double                price1=0,          // precio del primer punto
                    datetime              time2=0,           // hora del segundo punto
                    const double          angle=1.0,         // ángulo de Gann
                    const double          scale=1.0,         // escala
                    const color           clr=clrRed,        // color de la línea
                    const ENUM_LINE_STYLE style=STYLE_SOLID// estilo de la línea
                    const int             width=1,           // grosor de la línea
                    const bool            back=false,        // al fondo
                    const bool            selection=true,    // seleccionar para mover
                    const bool            ray_left=false,    // continuación de la línea a la izquierda
                    const bool            ray_right=true,    // continuación de la línea a la derecha
                    const bool            hidden=true,       // ocultar en la lista de objetos
                    const long            z_order=0)         // prioridad para el clic del ratón
  {
//--- establecemos las coordenadas de los puntos de anclaje si todavía no han sido establecidas
   ChangeGannLineEmptyPoints(time1,price1,time2);
//--- anulamos el valor del error
   ResetLastError();
//--- creamos la "Línea de Gann" según las coordenadas establecidas
//--- la coordenada correcta del precio del segundo punto de anclaje será redefinida
//--- automáticamente después del cambio del ángulo de Gann y (o) la escala,
   if(!ObjectCreate(chart_ID,name,OBJ_GANNLINE,sub_window,time1,price1,time2,0))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al crear la \"Línea de Gann\"! Código del error = ",GetLastError());
      return(false);
     }
//--- cambiamos el ángulo de Gann
   ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- cambiamos la escala (número de pips por barra)
   ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- establecemos el color de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- establecemos el estilo de visualización de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- establecemos el grosor de la línea
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostramos en el primer plano (false) o al fondo (true)
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de selección de la línea para mover
//--- cuando el objeto gráfico se crea usando la función ObjectCreate, por defecto el objeto
//--- no se puede seleccionar y mover. Mientras que dentro de este método el parámetro selection
//--- por defecto es igual a true, lo que permite seleccionar y mover este objeto
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- activamos (true) o desactivamos (false) el modo de continuación de la línea a la izquierda
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- activamos (true) o desactivamos (false) el modo de continuación de la línea a la derecha
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Mueve el punto de anclaje de la "Línea de Gann"                          |
//+------------------------------------------------------------------+
bool GannLinePointChange(const long   chart_ID=0,      // ID del gráfico
                         const string name="GannLine"// nombre de la línea
                         const int    point_index=0,   // número del punto de anclaje
                         datetime     time=0,          // coordenada del tiempo del punto de anclaje
                         double       price=0)         // coordenada del precio del punto de anclaje
  {
//--- si las coordenadas del punto de anclaje no han sido establecidas, lo movemos a la barra actual con el precio Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- anulamos el valor del error
   ResetLastError();
//--- movemos el punto de anclaje de la línea
   if(!ObjectMove(chart_ID,name,point_index,time,price))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al mover el punto de anclaje! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Cambia el ángulo de Gann                                              |
//+------------------------------------------------------------------+
bool GannLineAngleChange(const long   chart_ID=0,      // ID del gráfico
                         const string name="GannLine"// nombre de la línea
                         const double angle=1.0)       // ángulo de Gann
  {
//--- anulamos el valor del error
   ResetLastError();
//--- cambiamos el ángulo de Gann
   if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al cambiar el ángulo de Gann! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Cambia la escala de la "Línea de Gann"                                   |
//+------------------------------------------------------------------+
bool GannLineScaleChange(const long   chart_ID=0,      // ID del gráfico
                         const string name="GannLine"// nombre de la línea
                         const double scale=1.0)       // escala
  {
//--- anulamos el valor del error
   ResetLastError();
//--- cambiamos la escala (número de pips por barra)
   if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al cambiar la escala! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| La función elimina la "Línea de Gann" desde el gráfico                          |
//+------------------------------------------------------------------+
bool GannLineDelete(const long   chart_ID=0,      // ID del gráfico
                    const string name="GannLine"// nombre de la línea
  {
//--- anulamos el valor del error
   ResetLastError();
//--- eliminamos la línea de Gann
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": ¡Fallo al eliminar la \"Línea de Gann\"! Código del error = ",GetLastError());
      return(false);
     }
//--- ejecución con éxito
   return(true);
  }
//+------------------------------------------------------------------+
//| Comprueba los valores de los puntos de anclaje de la línea de Gann y para      |
//| los valores vacíos establece los valores por defecto                     |
//+------------------------------------------------------------------+
void ChangeGannLineEmptyPoints(datetime &time1,double &price1,datetime &time2)
  {
//--- si la hora del segundo punto no ha sido establecida, se colocará en la barra actual
   if(!time2)
      time2=TimeCurrent();
//--- si la hora del primer punto no ha sido establecida, se colocará a 9 barras a la izquierda del primero
   if(!time1)
     {
      //--- array para recibir la hora de apertura de las últimas 10 barras
      datetime temp[10];
      CopyTime(Symbol(),Period(),time2,10,temp);
      //--- colocamos el primer punto a 9 barras a la izquierda del segundo
      time1=temp[0];
     }
//--- si el precio del primer punto no ha sido establecido, tendrá el valor Bid
   if(!price1)
      price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- comprobamos si los parámetros de entrada son correctos
   if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 || 
      InpDate2<0 || InpDate2>100)
     {
      Print("¡Error. Los parámetros de entrada no son correctos!");
      return;
     }
//--- número de barras visibles en la ventana del gráfico
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- tamaño del array price
   int accuracy=1000;
//--- arrays para guardar los valores de las fechas y precios que van a utilizarse
//--- para establecer y modificar las coordenadas de los puntos de anclaje de la línea
   datetime date[];
   double   price[];
//--- asignación de la memoria
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- llenamos el array de datos
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("¡Fallo al copiar el valor de la hora! Código del error = ",GetLastError());
      return;
     }
//--- llenamos el array de precios
//--- encontramos el valor máximo y mínimo del gráfico
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- determinamos el paso del cambio del precio y llenamos el array
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- definimos los puntos para trazar la línea de Gann
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
   int p1=InpPrice1*(accuracy-1)/100;
//--- creamos la línea de Gann
   if(!GannLineCreate(0,InpName,0,date[d1],price[p1],date[d2],InpAngle,InpScale,InpColor,
      InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
     {
      return;
     }
//--- redibujamos el gráfico y esperamos 1 segundo
   ChartRedraw();
   Sleep(1000);
//--- ahora vamos a mover el punto de anclaje de la línea y cambiar el ángulo
//--- contador del ciclo
   int v_steps=accuracy/2;
//--- movemos el primer punto de anclaje verticalmente
   for(int i=0;i<v_steps;i++)
     {
      //--- cogemos el siguiente valor
      if(p1>1)
         p1-=1;
      //--- movemos el punto
      if(!GannLinePointChange(0,InpName,0,date[d1],price[p1]))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de medio segundo
   Sleep(500);
//--- determinamos el valor actual del ángulo de Gann (se ha cambiado
//--- tras el desplazamiento del primer punto de anclaje)
   double curr_angle;
   if(!ObjectGetDouble(0,InpName,OBJPROP_ANGLE,0,curr_angle))
      return;
//--- contador del ciclo
   v_steps=accuracy/8;
//--- cambiamos el ángulo de Gann
   for(int i=0;i<v_steps;i++)
     {
      if(!GannLineAngleChange(0,InpName,curr_angle-0.05*i))
         return;
      //--- comprobamos si el trabajo del script ha sido finalizado forzosamente
      if(IsStopped())
         return;
      //--- redibujamos el gráfico
      ChartRedraw();
     }
//--- retardo de 1 segundo
   Sleep(1000);
//--- eliminamos la línea desde el gráfico
   GannLineDelete(0,InpName);
   ChartRedraw();
//--- retardo de 1 segundo
   Sleep(1000);
//---
  }