PositionSelectByTicket

bool  PositionSelectByTicket(
   ulong   ticket     // das Ticket der Position
   );

#define   EXPERT_MAGIC  123456   // MagicNumber
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Anforderungs- und Ergebnisstrukturen deklarieren und initialisieren
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   
//--- Handelsanforderungsparameter ausfüllen, um eine Kaufposition zu eröffnen
   request.action    = TRADE_ACTION_DEAL;                      // Typ der Handelsoperation
   request.symbol    = Symbol();                               // Symbol
   request.volume    = 0.1;                                    // Volumen von 0.1 Lot
   request.type      = ORDER_TYPE_BUY;                         // Auftragstyp
   request.price     = SymbolInfoDouble(Symbol(), SYMBOL_ASK); // Eröffnungspreis
   request.deviation = 5;                                      // erlaubte Abweichung vom Preis
   request.magic     = EXPERT_MAGIC;                           // MagicNumber des Auftrags
   
//--- eine Anfrage senden. Wenn das Senden einer Anfrage fehlgeschlagen ist, zeige den Fehlercode an und beende den Vorgang
   if(!OrderSend(request, result))
     {
      PrintFormat("OrderSend error ", GetLastError());
      return;
     }
      
//--- Operationsdaten anzeigen
   PrintFormat("Trade request result: retcode: %u, deal: %I64u, order: %I64u", result.retcode, result.deal, result.order);
   
//--- Abrufen des Positionstickets aus dem Ergebnis der Handelsoperation und Auswahl der Position nach dem Ticket.
//--- Das Ticket einer neu eröffneten Position entspricht dem Ticket des Auftrags, der den Deal generiert hat.
   ulong ticket=result.order;
   ResetLastError();
   if(!PositionSelectByTicket(ticket))
     {
      PrintFormat("PositionSelectByTicket(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- Daten einer per Ticket ausgewählten Position im Journal anzeigen
   ENUM_POSITION_TYPE type  = (ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
   long               time  = PositionGetInteger(POSITION_TIME_MSC);
   double             price = PositionGetDouble(POSITION_PRICE_OPEN);
   double             volume= PositionGetDouble(POSITION_VOLUME);
   string             symbol= PositionGetString(POSITION_SYMBOL);
   int                digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected position: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, (type==POSITION_TYPE_BUY ? "Buy" : "Sell"), ticket, digits, price, TimeMscToString(time));
   /*
   Ergebnis:
   Trade request result: retcode: 10009, deal: 2778100901, order: 2803905975
   Current selected position: EURUSD 0.10 Buy #2803905975 at 1.10672, 2024.09.02 12:09:51.239
   */
  }
//+------------------------------------------------------------------+
//| Rückgabe der Zeit in Millisekunden                               |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }