PositionSelectByTicket

bool  PositionSelectByTicket(
   ulong   ticket     // ticket da posição
   );

#define   EXPERT_MAGIC  123456   // MagicNumber
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- declaramos e inicializamos as estruturas de solicitação e resultado
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   
//--- preenchemos os parâmetros da solicitação de negociação para abrir uma posição longa
   request.action    = TRADE_ACTION_DEAL; // tipo de operação de negociação
   request.symbol    = symbol;            // símbolo
   request.volume    = 0.1;                                    // volume de 0.1 lote
   request.type      = ORDER_TYPE_BUY;                         // tipo de ordem
   request.price     = SymbolInfoDouble(Symbol(), SYMBOL_ASK); // preço para abertura
   request.deviation = 5;                                      // desvio admissível em relação ao preço
   request.magic     = EXPERT_MAGIC;      // MagicNumber da ordem
   
//--- enviamos a solicitação, se o envio falhar, imprimimos o código de erro e encerramos o trabalho
   if(!OrderSend(request, result))
     {
      PrintFormat("OrderSend error ", GetLastError());
      return;
     }
      
//--- imprimimos informações sobre a operação
   PrintFormat("Trade request result: retcode: %u, deal: %I64u, order: %I64u", result.retcode, result.deal, result.order);
   
//--- obtemos o ticket da posição a partir do resultado da operação de negociação e selecionamos a posição pelo ticket
//--- o ticket da posição recém-aberta corresponde ao ticket da ordem que gerou a operação
   ulong ticket=result.order;
   ResetLastError();
   if(!PositionSelectByTicket(ticket))
     {
      PrintFormat("PositionSelectByTicket(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- imprimimos no log os dados da posição selecionada pelo ticket
   ENUM_POSITION_TYPE type  = (ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
   long               time  = PositionGetInteger(POSITION_TIME_MSC);
   double             price = PositionGetDouble(POSITION_PRICE_OPEN);
   double             volume= PositionGetDouble(POSITION_VOLUME);
   string             symbol= PositionGetString(POSITION_SYMBOL);
   int                digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected position: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, (type==POSITION_TYPE_BUY ? "Buy" : "Sell"), ticket, digits, price, TimeMscToString(time));
   /*
   Resultado:
   Trade request result: retcode: 10009, deal: 2778100901, order: 2803905975
   Current selected position: EURUSD 0.10 Buy #2803905975 at 1.10672, 2024.09.02 12:09:51.239
   */
  }
//+------------------------------------------------------------------+
//| Retorna o tempo em milissegundos                                 |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }