PositionSelectByTicket

bool  PositionSelectByTicket(
   ulong   ticket     // Ticket della posizione
   );

#define   EXPERT_MAGIC  123456   // MagicNumber
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- dichiarare e inizializzare le strutture di richiesta e risultato
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   
//--- Inserire i parametri della richiesta di trade per aprire una posizione lunga
   request.action    = TRADE_ACTION_DEAL;                      // tipo di operazione di trading
   request.symbol    = Symbol();                               // simbolo
   request.volume    = 0.1;                                    // volume di 0.1 lotti
   request.type      = ORDER_TYPE_BUY;                         // tipo di ordine
   request.price     = SymbolInfoDouble(Symbol(), SYMBOL_ASK); // prezzo di apertura
   request.deviation = 5;                                      // deviazione consentita dal prezzo
   request.magic     = EXPERT_MAGIC;                           // MagicNumber dell'ordine
   
//--- inviare una richiesta. Se l'invio di una richiesta fallisce, visualizzare il codice di errore e completare l'operazione
   if(!OrderSend(request, result))
     {
      PrintFormat("OrderSend error ", GetLastError());
      return;
     }
      
//--- visualizzare i dati dell'operazione
   PrintFormat("Trade request result: retcode: %u, deal: %I64u, order: %I64u", result.retcode, result.deal, result.order);
   
//--- ottenere il ticket della posizione dal risultato dell'operazione di trade e selezionare la posizione per ticket
//--- il ticket di una posizione appena aperta corrisponde al ticket dell'ordine che ha generato l'operazione
   ulong ticket=result.order;
   ResetLastError();
   if(!PositionSelectByTicket(ticket))
     {
      PrintFormat("PositionSelectByTicket(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- visualizzare i dati di una posizione, selezionata tramite ticket, nel journal
   ENUM_POSITION_TYPE type  = (ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
   long               time  = PositionGetInteger(POSITION_TIME_MSC);
   double             price = PositionGetDouble(POSITION_PRICE_OPEN);
   double             volume= PositionGetDouble(POSITION_VOLUME);
   string             symbol= PositionGetString(POSITION_SYMBOL);
   int                digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected position: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, (type==POSITION_TYPE_BUY ? "Buy" : "Sell"), ticket, digits, price, TimeMscToString(time));
   /*
   risultato:
   Trade request result: retcode: 10009, deal: 2778100901, order: 2803905975
   Current selected position: EURUSD 0.10 Buy #2803905975 at 1.10672, 2024.09.02 12:09:51.239
   */
  }
//+------------------------------------------------------------------+
//| Restituisce il tempo con millisecondi                            |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }