PositionSelectByTicket

bool  PositionSelectByTicket(
   ulong   ticket     // Ticket de la position
   );

#define   EXPERT_MAGIC  123456   // MagicNumber
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- déclare et initialise les structures de requête et de résultat
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   
//--- remplit les paramètres de la demande de trade pour ouvrir une position longue
   request.action    = TRADE_ACTION_DEAL;                      // type de l'opération de trading
   request.symbol    = Symbol();                               // symbole
   request.volume    = 0.1;                                    // volume de 0,1 lot
   request.type      = ORDER_TYPE_BUY;                         // type d'ordre
   request.price     = SymbolInfoDouble(Symbol(), SYMBOL_ASK); // prix d'ouverture
   request.deviation = 5;                                      // déviation autorisée par rapport au prix
   request.magic     = EXPERT_MAGIC;                           // MagicNumber de l'ordre
   
//--- envoie une demande. En cas d'échec de l'envoi d'une demande, affiche le code d'erreur et termine l'opération
   if(!OrderSend(request, result))
     {
      PrintFormat("OrderSend error ", GetLastError());
      return;
     }
      
//--- affiche les données de l'opération
   PrintFormat("Trade request result: retcode: %u, deal: %I64u, order: %I64u", result.retcode, result.deal, result.order);
   
//--- récupère le ticket de position à partir du résultat de l'opération de trading et sélectionne la position par ticket
//--- le ticket d'une position nouvellement ouverte correspond au ticket de l'ordre qui a généré la transaction
   ulong ticket=result.order;
   ResetLastError();
   if(!PositionSelectByTicket(ticket))
     {
      PrintFormat("PositionSelectByTicket(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- affiche les données d'une position, sélectionné par ticket, dans le journal
   ENUM_POSITION_TYPE type  = (ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
   long               time  = PositionGetInteger(POSITION_TIME_MSC);
   double             price = PositionGetDouble(POSITION_PRICE_OPEN);
   double             volume= PositionGetDouble(POSITION_VOLUME);
   string             symbol= PositionGetString(POSITION_SYMBOL);
   int                digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected position: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, (type==POSITION_TYPE_BUY ? "Buy" : "Sell"), ticket, digits, price, TimeMscToString(time));
   /*
   résultat :
   Trade request result: retcode: 10009, deal: 2778100901, order: 2803905975
   Current selected position: EURUSD 0.10 Buy #2803905975 at 1.10672, 2024.09.02 12:09:51.239
   */
  }
//+------------------------------------------------------------------+
//| Retourne l'heure en millisecondes                                |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }