DokumentationKategorien
Nachschlagewerk MQL5Operationen mit ChartsChartIndicatorName 

ChartIndicatorName

Gibt den Kurznamen des Indikators an der Index-Position in der Indikatorenliste des Chartfensters zurück.

string  ChartIndicatorName(
   long  chart_id,      // Identifikator des Charts
   int   sub_window     // Nummer des Unterfensters
   int   index          // Index des Indikators in der Liste der Indikatoren, die zu diesem Unterfenster hinzugefügt werden
   );

Parameter

chart_id

[in]  Identifikator des Charts. 0 bedeutet das aktuelle

sub_window

[in]  Nummer des Unterfensters des Charts. 0 bedeutet das Hauptfenster des Charts.

index

[in] Index des Indikators in der Liste der Indikatoren. Die Indexierung der Indikatorenliste beginnt bei Null, das heißt, der erste Indikator in der Liste hat den Index Null. Um die Anzahl der Indikatoren in der Liste zu erhalten, benutzen Sie die Funktion ChartIndicatorsTotal().

Rückgabewert

Kurzname des Indikators, der in der Eigenschaft INDICATOR_SHORTNAME mit Hilfe der Funktion IndicatorSetString() angegeben wird. Sie können den Kurznamen eines Indikators mit der Funktion ChartIndicatorName() abrufen. Um die Information über einen Fehler zu erhalten, muss man die Funktion GetLastError() aufrufen.

Hinweis

Mann darf den Kurznamen des Indikators nicht mit dem Dateinamen verwechseln, der bei der Verwendung des Indikators mit den Funktionen iCustom() und IndicatorCreate() gezeigt wird. Wenn der Kurzname des Indikators nicht explizit festgelegt wird, dann wird bei der Kompilation der Name der Quelldatei des Indikators angegeben.

Sie sollten einen richtig formierten Kurznamen des Indikators bilden, der in der Eigenschaft INDICATOR_SHORTNAME mit Hilfe der FunktionIndicatorSetString() geschrieben wird. Wir empfehlen, dass der Kurzname die Werte der Eingabeparameter des Indikators enthält, da der Indikator, der aus dem Chart gelöscht wird, mit der Funktion ChartIndicatorDelete() über den Kurznamen identifiziert wird.

Beispiel:

//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Abrufen der ID des aktuellen Charts und die Anzahl seiner Unterfenster, einschließlich des Hauptfensters
   long chart_id = ChartID();
   int  wnd_total= (int)ChartGetInteger(0,CHART_WINDOWS_TOTAL);
   
//--- Iteration über alle aktuellen Chartfenster in einer Schleife
   for(int w=0; w<wnd_total; w++)
     {
      //--- abrufen der Anzahl der Indikatoren, die in dem durch den Schleifenindex spezifizierte Chartfenster laufen
      int ind_total=ChartIndicatorsTotal(chart_id, w);
      
      //--- Ausdruck der Kopfzeile für das ausgewählte Chartfenster
      PrintFormat("Chart window %d indicators: ", w);
      
      //--- In der Schleife alle Namen der Indikatoren der Variablen ausdrucken, die dem ausgewählten Fenster zugeordnet sind.
      string ind_names="";
      for(int i=0; i<ind_total; i++)
        {
         ind_names+="  "+ChartIndicatorName(chart_id, w, i)+(i<ind_total-1 ? "\n": "");
        }
      //--- die erhaltene Liste der Namen aller Indikatoren, die an das angegebene Chartfenster angehängt sind, in das Journal drucken
      Print(ind_names);
     }
   /*
   Ergebnis:
   Chart window 0 indicators: 
     AMA(9,2,30)
     SAR(0.02,0.20)
     Fractals
   Chart window 1 indicators: 
     RSI(14)
     AMA(9,2,30)
   Chart window 2 indicators: 
     MFI(14)
   */
  }

Siehe auch

ChartIndicatorAdd(), ChartIndicatorDelete(), ChartIndicatorsTotal(), iCustom(), IndicatorCreate(), IndicatorSetString()