DokümantasyonBölümler
MQL5 ReferansıÖzel GöstergelerIndicatorSetString 

IndicatorSetString

Karşılık gelen gösterge özelliğinin değerini ayarlar. Gösterge özelliği string tipinde olmalıdır. Fonksiyonun iki çeşidi bulunmaktadır.

Özellik tanımlayıcısı (kimliği) ile çağrı.

bool  IndicatorSetString(
   int     prop_id,           // tanımlayıcı
   string  prop_value         // ayarlanacak değer
   );

Özellik tanımlayıcısının ve şekillendiricinin belirtilmesi ile yapılan çağrı.

bool  IndicatorSetString(
   int     prop_id,           // tanımlayıcı
   int     prop_modifier,     // şekillendirici
   string  prop_value         // ayarlanacak değer
   )

Parametreler

prop_id

[in]  Gösterge özelliğinin tanımlayıcısı. Bu değer, ENUM_CUSTOMIND_PROPERTY_STRING sayımının değerlerinden biri olabilir.

prop_modifier

[in]  Belirtilen özelliğin şekillendiricisi. Sadece seviye özellikleri bir şekillendirici gerektirir.

prop_value

[in]  Özellik değeri.

Dönüş değeri

Başarılı sonuç durumunda 'true', aksi durumda 'false' değerine dönüş yapar.

Not

#property direktifinin kullanımında özelliklerin numaralandırılması (şekillendiriciler) 1'den başlarken, fonksiyonlarda kullanılan numaralandırma 0'dan başlar. Seviye numarasının hatalı şekilde ayarlanmış olması durumunda, gösterge görünümü istenen görünümden farklı olabilir.

Örneğin, ilk yatay çizginin açıklamasını ayarlamak için, sıfırıncı indisi kullanın::

  • IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - 0 indisi, ilk seviyenin metin açıklamasını ayarlamak için kullanılır.

Örnek: gösterge yatay çizgilerine metin etiketleri ayarlayan gösterge.

IndicatorSetInteger() fonksiyonunun kullanım örneği

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- ayrı bir gösterge penceresinde üç yatay seviye görüntüle
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- yatay seviyelerin rengini ayarla
#property indicator_levelcolor clrRed
//--- yatay seviyelerin stilini ayarla
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- yatay seviyelerin açıklamalarını ayarla
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"İlk seviye (0 indisli)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"İkinci seviye (1 indisli)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Üçüncü seviye (2 indisli)");
//--- gösterge için kısa isim ayarla
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   
//--- bir sonraki çağrı için prev_calculated değerine dönüş yap
   return(rates_total);
  }

Ayrıca Bakınız

Özel Gösterge Özellikleri, Program Özellikleri (#property)