//--- 설명
#property description "스크립트는 \"수평선\" 그래픽 개체를 그립니다."
#property description "고정점 가격은 다음 높이의 백분율로 설정됩니다"
#property description "차트 창."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="HLine"; // 선 이름
input int InpPrice=25; // 선 가격(%)
input color InpColor=clrRed; // 선 색상
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // 선 스타일
input int InpWidth=3; // 선 너비
input bool InpBack=false; // 배경 선
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 수평선 생성 |
//+------------------------------------------------------------------+
bool HLineCreate(const long chart_ID=0, // 차트의 ID
const string name="HLine", // 선 이름
const int sub_window=0, // 하위 창 인덱스
double price=0, // 선 가격
const color clr=clrRed, // 선 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 선 스타일
const int width=1, // 선 너비
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 가격이 설정되지 않은 경우 현재 입찰 가격 수준으로 설정합니다
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 수평선 생성
if(!ObjectCreate(chart_ID,name,OBJ_HLINE,sub_window,0,price))
{
Print(__FUNCTION__,
": 수평선 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 선 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 선 표시 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 선 굵기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 선을 이동하는 모드를 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 수평선 이동 |
//+------------------------------------------------------------------+
bool HLineMove(const long chart_ID=0, // 차트의 ID
const string name="HLine", // 선 이름
double price=0) // 선 가격
{
//--- 선 가격이 설정되지 않은 경우 현재 입찰 가격 수준으로 이동합니다
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 수평선 이동
if(!ObjectMove(chart_ID,name,0,0,price))
{
Print(__FUNCTION__,
": 수평선 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 수평선 삭제 |
//+------------------------------------------------------------------+
bool HLineDelete(const long chart_ID=0, // 차트의 ID
const string name="HLine") // 선 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 수평선 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 수평선 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpPrice<0 || InpPrice>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 가격 배열 크기
int accuracy=1000;
//--- 사용할 가격 값을 저장하기 위한 배열
//--- 선 고정점 좌표 설정 및 변경
double price[];
//--- 메모리 할당
ArrayResize(price,accuracy);
//--- 가격 배열 채우기
//--- 차트의 최고값과 최저값을 찾기
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 가격의 변경 단계를 정의 하고 배열 채우기
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 선을 그리기 위한 점 지정
int p=InpPrice*(accuracy-1)/100;
//--- 수평선 생성
if(!HLineCreate(0,InpName,0,price[p],InpColor,InpStyle,InpWidth,InpBack,
InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 선을 이동합니다
//--- 루프 카운터
int v_steps=accuracy/2;
//--- 선 이동
for(int i=0;i<v_steps;i++)
{
//--- 다음의 값 사용
if(p<accuracy-1)
p+=1;
//--- 점 이동
if(!HLineMove(0,InpName,price[p]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 삭제
HLineDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
}
|