MetaTrader 5 herunterladen

IndicatorSetString

Gibt den Wert der entsprechenden Eigenschaft des Indikators vor. Eigenschaft des Indikators muss des Typs string sein. Es gibt 2 Varianten der Funktion.

Aufruf mit Andeutung des Identifikatoren der Eigenschaft.

bool  IndicatorSetString(
   int     prop_id,           // Identifikator
   string  prop_value         // der eingestellte Wert
   );

Aufruf mit Andeutung des Identifikatoren und Modifikatoren der Eigenschaft.

bool  IndicatorSetString(
   int     prop_id,           // Identifikator
   int     prop_modifier,     // Modifikator 
   string  prop_value         // der eingestellte Wert
   )

Parameter

prop_id

[in]  Identifikator der Eigenschaft des Indikators. Wert kann einer der Enumerationswerte ENUM_CUSTOMIND_PROPERTY_STRING sein.

prop_modifier

[in]  Modifikator der angegebenen Eigenschaft. Nur Leveleigenschaften erfordern einen Modifikator.

prop_value

[in]  Wert der Eigenschaft.

Rückgabewert

Im Erfolgsfall gibt true zurück, anderenfalls false.

Hinweis

Nummerierung der Eigenschaften (Modifikatoren) durch Direktive #property beginnt bei 1 (eins), während die Funktion verwendet Nummerierung bei 0 (Null). Bei die falsche Eingabe einer Nummer des Stands, kann Anzeige des Indikators verschieden sein.

Zum Beispiel, um die Beschreibung der ersten horizontalen Ebene anzugeben, verwenden Sie Null-Index:

  • IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - 0 wird für Angabe des Textbeschreibung für ersten Stand verwendet.

Beispiel: der Indikator setzt Texte für horizontale Linien des Indikators.

Beispiel der Funktion IndicatorSetString()

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- Anzeige der Indikatorebene in einem separaten Indikatorfenster angeben
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- Farbe der horizontale Linien angeben 
#property indicator_levelcolor clrRed
//--- Stil der horizontale Linien angeben 
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Beschreibungen der horizontale Linien angeben 
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"First Level (index 0)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"Second Level (index 1)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Third Level (index 2)");
//--- Kurzname des Indikators angeben
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
 ;}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   
//--- return value of prev_calculated for next call
   return(rates_total);
 ;}

Sehen Sie auch

Eigenschaften der Benutzerobjekte, Programmeigenschaften (#property)