DokumentationKategorien
Nachschlagewerk MQL5Operationen mit ChartsChartOpen 

ChartOpen

Eröffnet einen neuen Chart mit dem angegebenen Symbol und Zeitrahmen.

long  ChartOpen(
   string           symbol,     // Symbolname
   ENUM_TIMEFRAMES  period      // Zeitrahmen
   );

Parameter

symbol

[in]  Symbol des Charts. NULL bedeutet das Symbol des aktuellen Charts (auf dem der Experte läuft).

period

[in]  Zeitrahmen des Charts (Timeframe). Kann einen der Werte der Enumeration ENUM_TIMEFRAMES annehmen. 0 bedeutet der Zeitrahmen des aktuellen Charts.

Rückgabewert

Bei der erfolgreichen Eröffnung des Charts gibt die Funktion Identifikator des Charts zurück. Anderenfalls gibt sie 0 zurück.

Hinweis

Die maximal mögliche Zahl der gleichzeitig geöffneten Charts im Terminal kann nicht mehr als der Wert von CHARTS_MAX sein.

Beispiel:

#define CHART_SYMBOL  NULL
#define CHART_PERIOD  PERIOD_CURRENT
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- ein neues Chartsymbol und einen neuen Zeitrahmen festlegen
   string symbol=CHART_SYMBOL;
   if(symbol==NULL)
      symbol=Symbol();
   ENUM_TIMEFRAMES timeframe = (CHART_PERIOD==PERIOD_CURRENT ? Period() : CHART_PERIOD);
   
//--- ein neues Chart mit dem angegebenen Symbol und Zeitrahmen öffnen
   long chart_id=ChartOpen(symbol, timeframe);
   if(chart_id==0)
     {
      Print("ChartOpen() failed. Error ", GetLastError());
      return;
     }
 
//--- Parameter des geöffneten Charts im Journal ausdrucken
   PrintFormat("A new chart of the %s symbol has been opened with a period of %s and ChartID %I64u",
               symbol, StringSubstr(EnumToString(timeframe), 7), chart_id);
   /*
   Ergebnis:
   A new chart of the GBPUSD symbol has been opened with a period of M1 and ChartID 133346697706632016
   */
  }