//--- 설명
#property description "스크립트는 \"갠 선\" 그래픽 개체를 그립니다."
#property description "고정점 좌표는 백분율로 설정됩니다"
#property description "차트 창 크기."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="GannLine"; // 선 이름
input int InpDate1=20; // 첫 번째 점 날짜(%)
input int InpPrice1=75; // 첫 번째 점 가격(%)
input int InpDate2=80; // 두 번째 점 날짜(%)
input double InpAngle=0.0; // 갠 각도
input double InpScale=1.0; // 스케일
input color InpColor=clrRed; // 선 색상
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // 선 스타일
input int InpWidth=2; // 선 너비
input bool InpBack=false; // 배경 선
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpRayLeft=false; // 좌측으로 선 연장
input bool InpRayRight=true; // 우측으로 선 연장
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 주어진 좌표, 각도 및 스케일로 갠 그리드 생성 |
//+------------------------------------------------------------------+
bool GannLineCreate(const long chart_ID=0, // 차트의 ID
const string name="GannLine", // 선 이름
const int sub_window=0, // 하위 창 인덱스
datetime time1=0, // 첫 번째 점 시간
double price1=0, // 첫 번째 점 가격
datetime time2=0, // 두 번째 점 시간
const double angle=1.0, // 갠 각도
const double scale=1.0, // 스케일
const color clr=clrRed, // 선 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 선 스타일
const int width=1, // 선 너비
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool ray_left=false, // 좌측으로 선 연장
const bool ray_right=true, // 우측으로 선 연장
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 고정점이 설정되지 않은 경우 고정점의 좌표 설정
ChangeGannLineEmptyPoints(time1,price1,time2);
//--- 오류 값 재설정
ResetLastError();
//--- 주어진 좌표를 기준으로 갠 선 생성
//--- 두 번째 고정점의 정확한 좌표가 재정의 됨
//--- 자동으로 갠 각도 및/또는 척도가 변경되면,
if(!ObjectCreate(chart_ID,name,OBJ_GANNLINE,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": \"갠 선\" 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 갠 각도 변경
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- 스케일(막대당 pips 수) 변경
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- 선 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 선 표시 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 선 굵기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 이동하기 위해 선을 강조 표시 모드를 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 선 디스플레이의 좌측 연속 모드를 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- 선 디스플레이의 우측 연속 모드를 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 갠 선 고정점 이동 point |
//+------------------------------------------------------------------+
bool GannLinePointChange(const long chart_ID=0, // 차트의 ID
const string name="GannLine", // 선 이름
const int point_index=0, // 고정점 인덱스
datetime time=0, // 고정점 시간 좌표
double price=0) // 고정점 가격 좌표
{
//--- 포인트 위치가 설정되지 않은 겨우 입찰 가격이 있는 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 선의 고정점 이동
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 갠 각도 변경 |
//+------------------------------------------------------------------+
bool GannLineAngleChange(const long chart_ID=0, // 차트의 ID
const string name="GannLine", // 선 이름
const double angle=1.0) // 갠 각도
{
//--- 오류 값 재설정
ResetLastError();
//--- 갠 각도 변경
if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
{
Print(__FUNCTION__,
": 갠 각도 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 갠 선 스케일 변경 |
//+------------------------------------------------------------------+
bool GannLineScaleChange(const long chart_ID=0, // 차트의 ID
const string name="GannLine", // 선 이름
const double scale=1.0) // 스케일
{
//--- 오류 값 재설정
ResetLastError();
//--- 스케일(막대당 pips 수) 변경
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": 스케일 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 차트에서 갠 선 제거 기능 |
//+------------------------------------------------------------------+
bool GannLineDelete(const long chart_ID=0, // 차트의 ID
const string name="GannLine") // 선 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 갠 선 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": \"갠 선\" 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 갠 선 고정점 값을 확인하고 기본 값을 설정 |
//| 빈 곳의 값 |
//+------------------------------------------------------------------+
void ChangeGannLineEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- 두 번재 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time2)
time2=TimeCurrent();
//--- 첫 번째 점의 시간이 설정되지 않은 경우 두 번째 점에 남은 9 막대가 위치합니다
if(!time1)
{
//--- 마지막 10개 막대가 열린 시간을 수신하기 위한 배열
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- 두 번째 막대에서 남은 9개 막대에 첫 번째 점을 설정
time1=temp[0];
}
//--- 첫 번째 점의 가격이 설정되지 않은 경우 입찰 값을 갖습니다
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 가격 배열 크기
int accuracy=1000;
//--- 사용할 날짜 및 가격 값을 저장하기 위한 배열
//--- 선 고정점 좌표 설정 및 변경
datetime date[];
double price[];
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 가격 배열 채우기
//--- 차트의 최고값과 최저값을 찾기
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 가격의 변경 단계를 정의 하고 배열 채우기
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 갠 선을 그리기 위한 점 지정
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- 갠 선 생성
if(!GannLineCreate(0,InpName,0,date[d1],price[p1],date[d2],InpAngle,InpScale,InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 선의 고정점을 이동하고 각도를 변경합니다
//--- 루프 카운터
int v_steps=accuracy/2;
//--- 첫 번째 고정점을 수직방향으로 이동합니다
for(int i=0;i<v_steps;i++)
{
//--- 다음의 값 사용
if(p1>1)
p1-=1;
//--- 점 이동
if(!GannLinePointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 0.5초 지연
Sleep(500);
//--- 갠 각도의 현재 값 지정(변경됨-
//--- 첫 번째 고정점 이동 후)
double curr_angle;
if(!ObjectGetDouble(0,InpName,OBJPROP_ANGLE,0,curr_angle))
return;
//--- 루프 카운터
v_steps=accuracy/8;
//--- 갠 각도 변경
for(int i=0;i<v_steps;i++)
{
if(!GannLineAngleChange(0,InpName,curr_angle-0.05*i))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 선 삭제
GannLineDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
}
|
