//--- descrizione
#property description "Lo script disegna l'oggetto grafico \"Onda Movente di Elliott\"."
#property description "Le coordinate del punto di ancoraggio sono impostate in percentuale della grandezza della"
#property description "finestra del chart."
//--- mostra la finestra dei parametri di input durante il lancio dello script
#property script_show_inputs
//--- parametri di input dello script
input string InpName="ElliotWave5"; // Nome Oggetto
input int InpDate1=10; // data del 1mo punto, %
input int InpPrice1=90; // prezzo del 1mo punto, %
input int InpDate2=20; // data del secondo punto, %
input int InpPrice2=40; // prezzo del 2ndo punto, %
input int InpDate3=30; // data del 3zo punto, %
input int InpPrice3=60; // prezzo del 3zo punto, %
input int InpDate4=40; // data del 4to punto, %
input int InpPrice4=10; // prezzo del 4to punto, %
input int InpDate5=60; // data del 5to punto, %
input int InpPrice5=40; // prezzo del 5to punto, %
input ENUM_ELLIOT_WAVE_DEGREE InpDegree=ELLIOTT_MINOR; // Livello
input bool InpDrawLines=true; // Mostra le linee
input color InpColor=clrRed; // Colore delle linee
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Stile delle linee
input int InpWidth=2; // Spessore delle linee
input bool InpBack=false; // Oggetti in sottofondo
input bool InpSelection=true; // Evidenzia movimento
input bool InpHidden=true; // Nascosto nella lista oggetti
input long InpZOrder=0; // Priorità per il click del mouse
//+--------------------------------------------------------------------------------+
//| Crea l' "Onda Movente di Elliott" dalle coordinate date |
//+--------------------------------------------------------------------------------+
bool ElliotWave5Create(const long chart_ID=0, // ID del chart
const string name="ElliotWave5", // nome dell'onda
const int sub_window=0, // indice sottofinestra
datetime time1=0, // orario del primo punto
double price1=0, // prezzo del primo punto
datetime time2=0, // orario del secondo punto
double price2=0, // prezzo del secondo punto
datetime time3=0, // orario del terzo punto
double price3=0, // prezzo del terzo punto
datetime time4=0, // orario del quarto punto
double price4=0, // prezzo del quarto punto
datetime time5=0, // orario del quinto punto
double price5=0, // prezzo del quinto punto
const ENUM_ELLIOT_WAVE_DEGREE degree=ELLIOTT_MINUETTE, // gradi
const bool draw_lines=true, // mostra le linee
const color clr=clrRed, // colore dell'oggetto
const ENUM_LINE_STYLE style=STYLE_SOLID, // stile delle linee
const int width=1, // spessore delle linee
const bool back=false, // in sottofondo
const bool selection=true, // evidenzia movimento
const bool hidden=true, // nascosto nella lista oggetti
const long z_order=0) // priorità per il click del mouse
{
//--- imposta coordinate punto di ancoraggio se non sono impostate
ChangeElliotWave5EmptyPoints(time1,price1,time2,price2,time3,price3,time4,price4,time5,price5);
//--- resetta il valore dell' errore
ResetLastError();
//--- Crea l' "Onda Movente di Elliott" dalle coordinate date
if(!ObjectCreate(chart_ID,name,OBJ_ELLIOTWAVE5,sub_window,time1,price1,time2,price2,time3,
price3,time4,price4,time5,price5))
{
Print(__FUNCTION__,
": fallimento nel creare l' \"Onda Movente di Elliott\"! Error code = ",GetLastError());
return(false);
}
//--- imposta grado (grandezza onda)
ObjectSetInteger(chart_ID,name,OBJPROP_DEGREE,degree);
//--- abilita (true) o disabilita (false) la modalità di visualizzazione delle righe
ObjectSetInteger(chart_ID,name,OBJPROP_DRAWLINES,draw_lines);
//--- imposta il colore dell'oggetto
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- imposta lo stile delle linee
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- imposta lo spessore delle linee
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- mostra in primo piano (false) o sottofondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- abilita (true) o disabilita (false) la modalità di evidenzia del canale per lo spostamento
//--- quando si crea un oggetto grafico utilizzando la funzione ObjectCreate, l'oggetto non può esser
//--- evidenziato e mosso, per default. All'interno di questo metodo, la selezione dei parametri
//--- è true per default, il che consente di evidenziare e spostare l'oggetto
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- nascondi (true) o mostra (falso) il nome di oggetto grafico nella lista degli oggetti
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- imposta la priorità per ricevere l'evento di un clic del mouse nel grafico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Sposta il punto di ancoraggio dell' Onda Movente di Elliott |
//+--------------------------------------------------------------------------------+
bool ElliotWave5PointChange(const long chart_ID=0, // ID del chart
const string name="ElliotWave5", // nome dell'oggetto
const int point_index=0, // indice del punto di ancoraggio
datetime time=0, // coordinate tempo, del punto di ancoraggio
double price=0) // coordinate prezzo, del punto di ancoraggio
{
//--- se il punto della posizione non è impostato, spostarlo nella barra corrente che ha il prezzo Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- resetta il valore dell' errore
ResetLastError();
//--- sposta il punto di ancoraggio
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": fallimento nello spostare il punto di ancoraggio! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Elimina l'Onda Movente di Elliott |
//+--------------------------------------------------------------------------------+
bool ElliotWave5Delete(const long chart_ID=0, // ID del chart
const string name="ElliotWave5") // nome dell'oggetto
{
//--- resetta il valore dell' errore
ResetLastError();
//--- elimina l'oggetto
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": fallimento nell'eliminare l' \"Onda Movente di Elliott\"! Error code = ",GetLastError());
return(false);
}
//--- esecuzione avvenuta
return(true);
}
//+--------------------------------------------------------------------------------+
//| Imposta i valori del punto di ancoraggio dell' Onda Movente di Elliott |
//| imposta i valore di default per quelle vuote |
//+--------------------------------------------------------------------------------+
void ChangeElliotWave5EmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2,
datetime &time3,double &price3,
datetime &time4,double &price4,
datetime &time5,double &price5)
{
//--- array per ricevere l'orario di apertura delle ultime 10 barre
datetime temp[];
ArrayResize(temp,10);
//--- ricezione dati
CopyTime(Symbol(),Period(),TimeCurrent(),10,temp);
//--- riceve il valore di un punto sul corrente chart
double point=SymbolInfoDouble(Symbol(),SYMBOL_POINT);
//--- se l'orario del primo punto non è impostato, sarà 0 barre dietro dall'ultima barra
if(!time1)
time1=temp[0];
//--- se il prezzo del punto non è impostato, avrà un valore Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- se l'orario del secondo punto non è impostato, sarà 7 barre dietro dall'ultima barra
if(!time2)
time2=temp[2];
//--- se il prezzo del secondo punto non è impostato, lo sposta di 300 punti in meno rispetto al primo
if(!price2)
price2=price1-300*point;
//--- se l'orario del terzo punto non è impostato, sarà 5 barre dietro dall'ultima barra
if(!time3)
time3=temp[4];
//--- se il prezzo del terzo punto non è impostato, lo sposta di 200 punti in meno rispetto al primo
if(!price3)
price3=price1-250*point;
//--- se l'orario del quarto punto non è impostato, sarà 3 barre dietro dall'ultima barra
if(!time4)
time4=temp[6];
//--- se il prezzo del quarto punto non è impostato, lo sposta di 550 punti in meno rispetto al primo
if(!price4)
price3=price1-200*point;
//--- se l'orario del primo punto non è impostato, sarà sulla barra corrente
if(!time5)
time5=temp[9];
//--- se il prezzo del terzo punto non è impostato, lo sposta di 250 punti in meno rispetto al primo
if(!price5)
price5=price1-450*point;
}
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script |
//+--------------------------------------------------------------------------------+
voidOnStart()
{
//--- imposta la correttezza dei parametri di input
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100 ||
InpDate4<0 || InpDate4>100 || InpPrice4<0 || InpPrice4>100 ||
InpDate5<0 || InpDate5>100 || InpPrice5<0 || InpPrice5>100)
{
Print("Error! Valori non corretti dei parametri di input!");
return;
}
//--- Numero di barre visibili nella finestra del chart
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- grandezza dell'array prezzo
int accuracy=1000;
//--- array per la memorizzazione dei valori di data e prezzo da essere usati
//--- per impostare e cambiare i punti delle coordinate di ancoraggio dell'oggetto
datetime date[];
double price[];
//--- allocazione della memoria
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- riempie l'array delle date
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Fallimento nella copia dei valori tempo! Error code = ",GetLastError());
return;
}
/--- riempie l'array dei prezzi
//--- trova i valori più alti e più bassi del chart
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- definisce un cambio di step del prezzo e riempie l'array
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- definisce i punti per disegnare l'Onda Movente di Elliott
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int d4=InpDate4*(bars-1)/100;
int d5=InpDate5*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
int p4=InpPrice4*(accuracy-1)/100;
int p5=InpPrice5*(accuracy-1)/100;
//--- Crea l'Onda Movente di Elliott
if(!ElliotWave5Create(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
date[d4],price[p4],date[d5],price[p5],InpDegree,InpDrawLines,InpColor,InpStyle,InpWidth,
InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redisegna il chart ed attende per 1 secondo
ChartRedraw();
Sleep(1000);
//--- ora, sposta i punti di ancoraggio
//---contatore del ciclo
int v_steps=accuracy/5;
//--- sposta il quinto punto di ancoraggio
for(int i=0;i<v_steps;i++)
{
//--- usa il seguente valore
if(p5<accuracy-1)
p5+=1;
//--- sposta il punto
if(!ElliotWave5PointChange(0,InpName,4,date[d5],price[p5]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//---contatore del ciclo
v_steps=accuracy/5;
//--- sposta il secondo ed il terzo punto di ancoraggio
for(int i=0;i<v_steps;i++)
{
//--- usa i seguenti valori
if(p2<accuracy-1)
p2+=1;
if(p3>1)
p3-=1;
//--- slitta i punti
if(!ElliotWave5PointChange(0,InpName,1,date[d2],price[p2]))
return;
if(!ElliotWave5PointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//---contatore del ciclo
v_steps=accuracy*4/5;
//--- sposta il primo ed il quarto punto di ancoraggio
for(int i=0;i<v_steps;i++)
{
//--- usa i seguenti valori
if(p1>1)
p1-=1;
if(p4<accuracy-1)
p4+=1;
//--- slitta i punti
if(!ElliotWave5PointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!ElliotWave5PointChange(0,InpName,3,date[d4],price[p4]))
return;
//--- controlla se l'operazione dello script è stata disabilitata per forza
if(IsStopped())
return;
//--- ridisegna il chart
ChartRedraw();
}
//--- 1 secondo di ritardo
Sleep(1000);
//--- elimina l'oggetto dal chart
ElliotWave5Delete(0,InpName);
ChartRedraw();
//--- 1 secondo di ritardo
Sleep(1000);
//---
}
|
