#property description "Ein Expert Advisor für Senden von Handelsanfragen"
" durch die Funktion OrderSendAsync().\r\n"
#property description "Verarbeitung der Handelsereignisse mit"
" Handler-Funktionen OnTrade() und OnTradeTransaction() ist angezeigt\r\n"
#property description "In Expert Advisor Parameters können Sie Magic Number"
" (eindeutiger Identifikator) "
#property description "und Nachrichtenausgabemodus in Experten Zeitschrift angeben. Standardmäßig werden alle Elemente angezeigt.\r\n"
//--- input parameters
input int MagicNumber=1234567; // Expert Advisor ID
input bool DescriptionModeFull=true; // Mode der detaillierten Ausgabe
//--- eine Variable für Nutzung im Aufruf von HistorySelect()
datetime history_start;
//+------------------------------------------------------------------+
//| Expert initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- Erlaubnis für den automatisierten Handel überprüfen
if(!TerminalInfoInteger(TERMINAL_TRADE_ALLOWED))
{
Alert("Automatisches Handle ist im Terminal verboten, EA wird gelöscht werden");
ExpertRemove();
return(-1);
}
//--- Handle auf einem Live-Konto ist nicht erlaubt
if(AccountInfoInteger(ACCOUNT_TRADE_MODE)==ACCOUNT_TRADE_MODE_REAL)
{
Alert("Dem Expert Advisor ist nicht erlaubt auf einem Live-Konto zu handeln!");
ExpertRemove();
return(-2);
}
//--- ob es möglich ist, auf dem Konto zu handeln (zB ist es nicht erlaubt mit einem Invest-Passwort)
if(!AccountInfoInteger(ACCOUNT_TRADE_ALLOWED))
{
Alert("Der Handel auf dem Konto ist nicht erlaubt");
ExpertRemove();
return(-3);
}
//--- Speichern die Laufzeit des Experts für den Handelsgeschichte
history_start=TimeCurrent();
//---
CreateBuySellButtons();
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
//--- graphische Objekte löschen
ObjectDelete(0,"Buy");
ObjectDelete(0,"Sell");
//---
}
//+------------------------------------------------------------------+
//| TradeTransaction function |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
const MqlTradeRequest &request,
const MqlTradeResult &result)
{
//--- Titel nach dem Namen der Handelsereignisse-Handler-Funktion
Print("=> ",__FUNCTION__," at ",TimeToString(TimeCurrent(),TIME_SECONDS));
//--- Typ der Transaktion in Form von Enumerationswerte erhalten
ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- wenn die Transaktion ist ein Ergebnis der Verarbeitung einer Anfrage
if(type==TRADE_TRANSACTION_REQUEST)
{
//---den Name der Transaktion ausgeben
Print(EnumToString(type));
//--- dann geben die String-Beschreibung der verarbeiteten Anfrage
Print("------------RequestDescription\r\n",
RequestDescription(request,DescriptionModeFull));
//--- und anzeigen die Beschreibung des Abfrageergebnisses
Print("------------ ResultDescription\r\n",
TradeResultDescription(result,DescriptionModeFull));
}
else // Für die Transaktionen anderen Typen geben wir eine vollständige Beschreibung der Transaktion aus
{
Print("------------ TransactionDescription\r\n",
TransactionDescription(trans,DescriptionModeFull));
}
//---
}
//+------------------------------------------------------------------+
//| Trade function |
//+------------------------------------------------------------------+
void OnTrade()
{
//--- Statische Mitglieder, um den Kontostand zu speichern
static int prev_positions=0,prev_orders=0,prev_deals=0,prev_history_orders=0;
//--- Handelsgeschichte anfragen
bool update=HistorySelect(history_start,TimeCurrent());
PrintFormat("HistorySelect(%s , %s) = %s",
TimeToString(history_start),TimeToString(TimeCurrent()),(string)update);
//--- Titel nach dem Namen der Handelsereignisse-Handler-Funktion
Print("=> ",__FUNCTION__," at ",TimeToString(TimeCurrent(),TIME_SECONDS));
//--- Name des Handlers und die Anzahl der Order in der Zeit der Verarbeitung ausgeben
int curr_positions=PositionsTotal();
int curr_orders=OrdersTotal();
int curr_deals=HistoryOrdersTotal();
int curr_history_orders=HistoryDealsTotal();
//--- Anzahl der Aufträge, Positionen, Transaktionen und Änderungen in Klammern anzeigen
PrintFormat("PositionsTotal() = %d (%+d)",
curr_positions,(curr_positions-prev_positions));
PrintFormat("OrdersTotal() = %d (%+d)",
curr_orders,curr_orders-prev_orders);
PrintFormat("HistoryOrdersTotal() = %d (%+d)",
curr_deals,curr_deals-prev_deals);
PrintFormat("HistoryDealsTotal() = %d (%+d)",
curr_history_orders,curr_history_orders-prev_history_orders);
//--- Zeilenumbruch einfügen zum einfachen Ablesen des Journal
Print("");
//--- den Zustand des Kontos speichern
prev_positions=curr_positions;
prev_orders=curr_orders;
prev_deals=curr_deals;
prev_history_orders=curr_history_orders;
//---
}
//+------------------------------------------------------------------+
//| ChartEvent function |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
const long &lparam,
const double &dparam,
const string &sparam)
{
//--- Verarbeitung von Ereignissen CHARTEVENT_CLICK ("Klick mit der Maus auf dem Chart")
if(id==CHARTEVENT_OBJECT_CLICK)
{
Print("=> ",__FUNCTION__,": sparam = ",sparam);
//--- Mindesvolumen für Transaktion
double volume_min=SymbolInfoDouble(_Symbol,SYMBOL_VOLUME_MIN);
//--- wenn die Schaltfläche "Buy" ist gedrückt, dann kaufen wir
if(sparam=="Buy")
{
PrintFormat("Buy %s %G lot",_Symbol,volume_min);
BuyAsync(volume_min);
//--- Undrücken die gedrückte Schaltfläche
ObjectSetInteger(0,"Buy",OBJPROP_STATE,false);
}
//--- wenn die Schaltfläche "Sell" ist gedrückt, dann verkaufen wir
if(sparam=="Sell")
{
PrintFormat("Sell %s %G lot",_Symbol,volume_min);
SellAsync(volume_min);
//--- Undrücken die gedrückte Schaltfläche
ObjectSetInteger(0,"Sell",OBJPROP_STATE,false);
}
ChartRedraw();
}
//---
}
//+------------------------------------------------------------------+
//| Gibt eine textuelle Beschreibung der Transaktion zurück |
//+------------------------------------------------------------------+
string TransactionDescription(const MqlTradeTransaction &trans,
const bool detailed=true)
{
//--- eine Zeichenfolge für Zurückgabe aus der Funktion vorbereiten
string desc=EnumToString(trans.type)+"\r\n";
//--- im detaillierten Modus fügen wir maximale Information hinzu
if(detailed)
{
desc+="Symbol: "+trans.symbol+"\r\n";
desc+="Deal ticket: "+(string)trans.deal+"\r\n";
desc+="Deal type: "+EnumToString(trans.deal_type)+"\r\n";
desc+="Order ticket: "+(string)trans.order+"\r\n";
desc+="Order type: "+EnumToString(trans.order_type)+"\r\n";
desc+="Order state: "+EnumToString(trans.order_state)+"\r\n";
desc+="Order time type: "+EnumToString(trans.time_type)+"\r\n";
desc+="Order expiration: "+TimeToString(trans.time_expiration)+"\r\n";
desc+="Price: "+StringFormat("%G",trans.price)+"\r\n";
desc+="Price trigger: "+StringFormat("%G",trans.price_trigger)+"\r\n";
desc+="Stop Loss: "+StringFormat("%G",trans.price_sl)+"\r\n";
desc+="Take Profit: "+StringFormat("%G",trans.price_tp)+"\r\n";
desc+="Volume: "+StringFormat("%G",trans.volume)+"\r\n";
}
//--- Geben wir den den resultierenden String zurück
return desc;
}
//+------------------------------------------------------------------+
//| Gibt eine textuelle Beschreibung der Handelsanfrage zurück |
//+------------------------------------------------------------------+
string RequestDescription(const MqlTradeRequest &request,
const bool detailed=true)
{
//--- eine Zeichenfolge für Zurückgabe aus der Funktion vorbereiten
string desc=EnumToString(request.action)+"\r\n";
//--- im detaillierten Modus fügen wir maximale Information hinzu
if(detailed)
{
desc+="Symbol: "+request.symbol+"\r\n";
desc+="Magic Number: "+StringFormat("%d",request.magic)+"\r\n";
desc+="Order ticket: "+(string)request.order+"\r\n";
desc+="Order type: "+EnumToString(request.type)+"\r\n";
desc+="Order filling: "+EnumToString(request.type_filling)+"\r\n";
desc+="Order time type: "+EnumToString(request.type_time)+"\r\n";
desc+="Order expiration: "+TimeToString(request.expiration)+"\r\n";
desc+="Price: "+StringFormat("%G",request.price)+"\r\n";
desc+="Deviation points: "+StringFormat("%G",request.deviation)+"\r\n";
desc+="Stop Loss: "+StringFormat("%G",request.sl)+"\r\n";
desc+="Take Profit: "+StringFormat("%G",request.tp)+"\r\n";
desc+="Stop Limit: "+StringFormat("%G",request.stoplimit)+"\r\n";
desc+="Volume: "+StringFormat("%G",request.volume)+"\r\n";
desc+="Comment: "+request.comment+"\r\n";
}
//--- Geben wir den den resultierenden String zurück
return desc;
}
//+------------------------------------------------------------------+
//| Gibt textuelle Beschreibung der Ergebnis der Anfrageverarbeitung |
//+------------------------------------------------------------------+
string TradeResultDescription(const MqlTradeResult &result,
const bool detailed=true)
{
//--- eine Zeichenfolge für Zurückgabe aus der Funktion vorbereiten
string desc="Retcode "+(string)result.retcode+"\r\n";
//--- im detaillierten Modus fügen wir maximale Information hinzu
if(detailed)
{
desc+="Request ID: "+StringFormat("%d",result.request_id)+"\r\n";
desc+="Order ticket: "+(string)result.order+"\r\n";
desc+="Deal ticket: "+(string)result.deal+"\r\n";
desc+="Volume: "+StringFormat("%G",result.volume)+"\r\n";
desc+="Price: "+StringFormat("%G",result.price)+"\r\n";
desc+="Ask: "+StringFormat("%G",result.ask)+"\r\n";
desc+="Bid: "+StringFormat("%G",result.bid)+"\r\n";
desc+="Comment: "+result.comment+"\r\n";
}
//--- Geben wir den den resultierenden String zurück
return desc;
}
//+------------------------------------------------------------------+
//| Erstellt zwei Schaltflächen für Kauf und Verkauf |
//+------------------------------------------------------------------+
void CreateBuySellButtons()
{
//--- überprüfen wir ob ein namens "Buy" existiert
if(ObjectFind(0,"Buy")>=0)
{
//--- wenn das gefundene Objekt keine Schaltfläche ist, löschen wir es
if(ObjectGetInteger(0,"Buy",OBJPROP_TYPE)!=OBJ_BUTTON)
ObjectDelete(0,"Buy");
}
else
ObjectCreate(0,"Buy",OBJ_BUTTON,0,0,0); // Schaltfläche "Buy" erstellen
//--- Schaltfläche "Buy" abstimmen
ObjectSetInteger(0,"Buy",OBJPROP_CORNER,CORNER_RIGHT_UPPER);
ObjectSetInteger(0,"Buy",OBJPROP_XDISTANCE,100);
ObjectSetInteger(0,"Buy",OBJPROP_YDISTANCE,50);
ObjectSetInteger(0,"Buy",OBJPROP_XSIZE,70);
ObjectSetInteger(0,"Buy",OBJPROP_YSIZE,30);
ObjectSetString(0,"Buy",OBJPROP_TEXT,"Buy");
ObjectSetInteger(0,"Buy",OBJPROP_COLOR,clrRed);
//--- überprüfen wir ob ein namens "Sell" existiert
if(ObjectFind(0,"Sell")>=0)
{
//--- wenn das gefundene Objekt keine Schaltfläche ist, löschen wir es
if(ObjectGetInteger(0,"Sell",OBJPROP_TYPE)!=OBJ_BUTTON)
ObjectDelete(0,"Sell");
}
else
ObjectCreate(0,"Sell",OBJ_BUTTON,0,0,0); // Schaltfläche "Sell" erstellen
//--- Schaltfläche "Sell" abstimmen
ObjectSetInteger(0,"Sell",OBJPROP_CORNER,CORNER_RIGHT_UPPER);
ObjectSetInteger(0,"Sell",OBJPROP_XDISTANCE,100);
ObjectSetInteger(0,"Sell",OBJPROP_YDISTANCE,100);
ObjectSetInteger(0,"Sell",OBJPROP_XSIZE,70);
ObjectSetInteger(0,"Sell",OBJPROP_YSIZE,30);
ObjectSetString(0,"Sell",OBJPROP_TEXT,"Sell");
ObjectSetInteger(0,"Sell",OBJPROP_COLOR,clrBlue);
//--- Zwangsaktualisierung des Charts um die Schaltflächen sofort zu zeichnen
ChartRedraw();
//---
}
//+------------------------------------------------------------------+
//| Kauf über die asynchrone Funktion OrderSendAsync() |
//+------------------------------------------------------------------+
void BuyAsync(double volume)
{
//--- Anfrage bereiten
MqlTradeRequest req={};
req.action =TRADE_ACTION_DEAL;
req.symbol =_Symbol;
req.magic =MagicNumber;
req.volume =0.1;
req.type =ORDER_TYPE_BUY;
req.price =SymbolInfoDouble(req.symbol,SYMBOL_ASK);
req.deviation =10;
req.comment ="Buy using OrderSendAsync()";
MqlTradeResult res={};
if(!OrderSendAsync(req,res))
{
Print(__FUNCTION__,": Fehler ",GetLastError(),", retcode = ",res.retcode);
}
//---
}
//+------------------------------------------------------------------+
//| Verkauf über die asynchrone Funktion OrderSendAsync() |
//+------------------------------------------------------------------+
void SellAsync(double volume)
{
//--- Anfrage bereiten
MqlTradeRequest req={};
req.action =TRADE_ACTION_DEAL;
req.symbol =_Symbol;
req.magic =MagicNumber;
req.volume =0.1;
req.type =ORDER_TYPE_SELL;
req.price =SymbolInfoDouble(req.symbol,SYMBOL_BID);
req.deviation =10;
req.comment ="Sell using OrderSendAsync()";
MqlTradeResult res={};
if(!OrderSendAsync(req,res))
{
Print(__FUNCTION__,": Fehler ",GetLastError(),", retcode = ",res.retcode);
}
//---
}
//+------------------------------------------------------------------+
|