#define EXPERT_MAGIC 123456
#define OFFSET 50 // Abstand vom aktuellen Preis, um die Order zu platzieren, in Punkten
#define DIRECTION ORDER_TYPE_BUY_LIMIT // Order-Typ
#define VOLUME 1.0 // Volumen
#define DEVIATION 2 // erlaubte Abweichung vom Preis
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion |
//+------------------------------------------------------------------+
void OnStart()
{
//-- Handelsanfrage, Ergebnis und Variablen deklarieren und initialisieren
MqlTradeRequest request={};
MqlTradeResult result ={};
double order_price=0;
//--- Parameter der Pending-Orders
request.action = TRADE_ACTION_PENDING; // Typ der Handelsoperation
request.symbol = _Symbol; // Symbol
request.volume = VOLUME; // Volumen
request.deviation = DEVIATION; // erlaubte Abweichung vom Preis
request.magic = EXPERT_MAGIC; // MagicNumber der Order
//--- Prüfen des Auftragstyps
switch(DIRECTION)
{
case ORDER_TYPE_BUY_LIMIT :
request.type = ORDER_TYPE_BUY_LIMIT; // Order-Typ
order_price = SymbolInfoDouble(_Symbol, SYMBOL_ASK)-OFFSET*_Point;// Order-Preis
request.price= NormalizeDouble(order_price, _Digits); // normalisierter Order-Preis
break;
case ORDER_TYPE_SELL_LIMIT :
request.type = ORDER_TYPE_SELL_LIMIT; // Order-Typ
order_price = SymbolInfoDouble(_Symbol, SYMBOL_BID)+OFFSET*_Point;// Order-Preis
request.price= NormalizeDouble(order_price,_Digits); // normalisierter Eröffnungspreis
break;
case ORDER_TYPE_BUY_STOP :
request.type = ORDER_TYPE_BUY_STOP; // Order-Typ
order_price = SymbolInfoDouble(_Symbol, SYMBOL_ASK)+OFFSET*_Point;// Eröffnungspreis
request.price= NormalizeDouble(order_price,_Digits); // normalisierter Eröffnungspreis
break;
case ORDER_TYPE_SELL_STOP :
request.type = ORDER_TYPE_SELL_STOP; // Order-Typ
order_price = SymbolInfoDouble(_Symbol, SYMBOL_BID)-OFFSET*_Point;// Eröffnungspreis
request.price= NormalizeDouble(order_price,_Digits); // normalisierter Eröffnungspreis
break;
default: // wenn eine nicht-schwebende oder StopLimit-Order gewählt wurde
Alert("This example is only for placing pending orders BuyLimit, SellLimit, BuyStop and SellStop");
break;
}
//--- eine Anfrage senden. Wenn das Senden einer Anfrage fehlgeschlagen ist, zeige den Fehlercode an und beende den Vorgang
if(!OrderSend(request, result))
{
Print("OrderSend error ", GetLastError());
return;
}
//--- Operationsdaten anzeigen
PrintFormat("Trade request result: retcode=%u, order=%I64u", result.retcode, result.order);
//--- Order-Ticket aus dem Handelsoperationsergebnis abrufen und die Order nach Ticket auswählen
ulong ticket=result.order;
ResetLastError();
if(!OrderSelect(ticket))
{
PrintFormat("OrderSelect(%I64u) failed. Error %d", ticket, GetLastError());
return;
}
//--- Daten der per Ticket ausgewählten Order im Journal anzeigen
ENUM_ORDER_TYPE type = (ENUM_ORDER_TYPE)OrderGetInteger(ORDER_TYPE);
long time = OrderGetInteger(ORDER_TIME_SETUP_MSC);
double price = OrderGetDouble(ORDER_PRICE_OPEN);
double volume= OrderGetDouble(ORDER_VOLUME_CURRENT);
string symbol= OrderGetString(ORDER_SYMBOL);
int digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
PrintFormat("Current selected order: %s %.2f %s #%I64u at %.*f, %s",
symbol, volume, OrderTypeDescription(type), ticket, digits, price, TimeMscToString(time));
/*
Ergebnis:
Trade request result: retcode=10009, order=2811006719
Current selected order: EURUSD 1.00 Buy Limit #2811006719 at 1.10550, 2024.09.04 10:38:28.563
*/
}
//+------------------------------------------------------------------+
//| Rückgabe der Zeit in Millisekunden |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
{
return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
}
//+------------------------------------------------------------------+
//| Rückgabe der Beschreibung des Auftragstyps |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE type)
{
switch(type)
{
case ORDER_TYPE_BUY : return("Buy");
case ORDER_TYPE_SELL : return("Sell");
case ORDER_TYPE_BUY_LIMIT : return("Buy Limit");
case ORDER_TYPE_SELL_LIMIT : return("Sell Limit");
case ORDER_TYPE_BUY_STOP : return("Buy Stop");
case ORDER_TYPE_SELL_STOP : return("Sell Stop");
case ORDER_TYPE_BUY_STOP_LIMIT : return("Buy Stop Limit");
case ORDER_TYPE_SELL_STOP_LIMIT : return("Sell Stop Limit");
default : return("Unknown order type");
}
}
|