void OnStart()
{
ulong deal_ticket; // ticket da operação
ulong order_ticket; // ticket da ordem com a qual a operação foi feita
datetime transaction_time; // hora da operação
long deal_type ; // tipo de operação de negociação
long position_ID; // identificador da posição
string deal_description; // descrição da operação
double volume; // volume de operação
string symbol; // símbolo da operação
//--- definimos a data de início e de término para solicitar o histórico de operações
datetime from_date=0; // desde o início
datetime to_date=TimeCurrent();// até o momento
//--- solicitamos o histórico de operações no intervalo especificado
HistorySelect(from_date,to_date);
//--- número total na lista de operações
int deals=HistoryDealsTotal();
//--- agora vamos processar cada operação
for(int i=0;i<deals;i++)
{
deal_ticket= HistoryDealGetTicket(i);
volume= HistoryDealGetDouble(deal_ticket,DEAL_VOLUME);
transaction_time=(datetime)HistoryDealGetInteger(deal_ticket,DEAL_TIME);
order_ticket= HistoryDealGetInteger(deal_ticket,DEAL_ORDER);
deal_type= HistoryDealGetInteger(deal_ticket,DEAL_TYPE);
symbol= HistoryDealGetString(deal_ticket,DEAL_SYMBOL);
position_ID= HistoryDealGetInteger(deal_ticket,DEAL_POSITION_ID);
deal_description= GetDealDescription(deal_type,volume,symbol,order_ticket,position_ID);
//--- criamos uma formatação agradável para o número da operação
string print_index=StringFormat("% 3d",i);
//--- exibimos informações sobre a operação
Print(print_index+": deal #",deal_ticket," at ",transaction_time,deal_description);
}
}
//+------------------------------------------------------------------+
//| Retorna uma descrição de string da operação |
//+------------------------------------------------------------------+
string GetDealDescription(long deal_type,double volume,string symbol,long ticket,long pos_ID)
{
string descr;
//---
switch(deal_type)
{
case DEAL_TYPE_BALANCE: return ("balance");
case DEAL_TYPE_CREDIT: return ("credit");
case DEAL_TYPE_CHARGE: return ("charge");
case DEAL_TYPE_CORRECTION: return ("correction");
case DEAL_TYPE_BUY: descr="buy"; break;
case DEAL_TYPE_SELL: descr="sell"; break;
case DEAL_TYPE_BONUS: return ("bonus");
case DEAL_TYPE_COMMISSION: return ("additional commission");
case DEAL_TYPE_COMMISSION_DAILY: return ("daily commission");
case DEAL_TYPE_COMMISSION_MONTHLY: return ("monthly commission");
case DEAL_TYPE_COMMISSION_AGENT_DAILY: return ("daily agent commission");
case DEAL_TYPE_COMMISSION_AGENT_MONTHLY: return ("monthly agent commission");
case DEAL_TYPE_INTEREST: return ("interest rate");
case DEAL_TYPE_BUY_CANCELED: descr="cancelled buy deal"; break;
case DEAL_TYPE_SELL_CANCELED: descr="cancelled sell deal"; break;
}
descr=StringFormat("%s %G %s (order #%d, position ID %d)",
descr, // descrição atual
volume, // volume da operação
symbol, // instrumento da operação
ticket, // ticket da ordem que acionou a operação
pos_ID // ID da posição na qual a operação estava envolvida
);
return(descr);
//---
}
|