DocumentazioneSezioni
MQL5 RiferimentoOperazioni col GraficoChartIndicatorsTotal 

ChartIndicatorsTotal

Restituisce il numero di tutti gli indicatori applicati alla finestra del grafico specificato.

int  ChartIndicatorsTotal(
   long  chart_id,      // ID del Grafico
   int   sub_window     // numero di sottofinestra
   );

Parametri

chart_id

[in] ID del Grafico. 0 indica il grafico corrente.

sub_window

[in] Numero di sottofinestra grafico. 0 denota la principale sottofinestra del grafico.

Valore restituito

Il numero di indicatori nella finestra del grafico specificato. Per ottenere i dettagli dell' errore utilizzare la funzione GetLastError().

Nota

La funzione permette di fare la ricerca attraverso tutti gli indicatori collegati al grafico. Il numero di tutte le finestre del grafico può essere ottenuto dalla proprietà CHART_WINDOWS_TOTAL utilizzando la funzione ChartGetInteger().

Esempio:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- ottenere l'ID del grafico corrente e il numero delle sue sotto finestre, compresa la finestra principale
   long chart_id = ChartID();
   int  wnd_total= (int)ChartGetInteger(0,CHART_WINDOWS_TOTAL);
   
//--- iterare in un ciclo su tutte le finestre del grafico corrente
   for(int w=0; w<wnd_total; w++)
     {
 //--- ottenere il numero di indicatori allegati alla finestra del grafico specificato dall'indice del ciclo
      int ind_total=ChartIndicatorsTotal(chart_id, w);
      
 //--- ottenere il numero di indicatori allegati alla finestra del grafico specificata
      PrintFormat("Chart ID %I64d, subwindow %d. Attached indicators: %d", chart_id, w, ind_total);
     }
   /*
   risultato:
   Chart ID 133246248352168439, subwindow 0. Attached indicators: 3
   Chart ID 133246248352168439, subwindow 1. Attached indicators: 2
   Chart ID 133246248352168439, subwindow 2. Attached indicators: 1
   */
  }

Vedi anche

ChartIndicatorAdd(), ChartIndicatorDelete(), iCustom(), IndicatorCreate(), IndicatorSetString()