DocumentazioneSezioni
MQL5 RiferimentoIndicatori PersonalizzatiIndicatorSetString 

IndicatorSetString

La funzione imposta il valore della proprietà indicatore corrispondente. La proprietà indicatore deve essere di tipo string. Ci sono due varianti della funzione.

Chiamare specificando l'identificatore di proprietà.

bool  IndicatorSetString(
   int     prop_id,           // identificatore
   string  prop_value         // valore da impostare
   );

Chiamare specificando l'identificatore della proprietà ed il modificatore.

bool  IndicatorSetString(
   int     prop_id,           // identificatore
   int     prop_modifier,     // modificatore
   string  prop_value         // valore da impostare
   )

Parametri

prop_id

[in] Identificatore della proprietà dell'indicatore. Il valore può essere uno dei valori dell'enumerazione ENUM_CUSTOMIND_PROPERTY_STRING.

prop_modifier

[in] Modificatore della proprietà specificata. Solo le proprietà livello richiedono un modificatore.

prop_value

[in]  Valore della proprietà.

Valore restituito

In caso di esecuzione avvenuta con successo, restituisce true, altrimenti - false

Nota

La numerazione delle proprietà (modificatori) comincia da 1 (uno) quando si utilizza la direttiva #property, mentre la funzione utilizza la numerazione da 0 (zero). Nel caso in cui il numero di livello è impostato in modo errato, la visualizzazione dell' indicatore può differire da quanto previsto.

Ad esempio, per impostare la descrizione della prima linea orizzontale, usa l'indice zero:

  • IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - l'indice 0 viene usato per impostare la descrizione del testo del primo livello.

Esempio: indicatore che imposta l'etichetta del testo sulla linea orizzontale dell'indicatore.

Esempio di utilizzo della funzione IndicatorSetString()

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- visualizza tre livelli orizzontali in una finestra indicatore separata
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- imposta il colore dei livelli orizzontali
#property indicator_levelcolor clrRed
//--- imposta lo stile dei livelli orizzontali
#property indicator_levelstyle STYLE_SOLID
//+--------------------------------------------------------------------------------+
//| Funzione di inizializzazione Indicatore Personalizzato                         |
//+--------------------------------------------------------------------------------+
int OnInit()
  {
//--- imposta le descrizioni dei livelli orizzontali
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"Primo livello (indice 0)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"Secondo livello (indice 1)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Terzo livello (indice 2)");
//--- imposta il nome corto per l'indicatore
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
  }
//+--------------------------------------------------------------------------------+
//| Funzione di iterazione indicatore personalizato                                |
//+--------------------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   
//--- restituisce il valore di prev_calculated per la prossima chiamata
   return(rates_total);
  }

Vedi anche

Proprietà Indicatori Personalizzati, Proprietà Programmi (#property)