DocumentationSections
Référence MQL5Fonctions CommunesGetTickCount64 

GetTickCount64

La fonction GetTickCount64() retourne le nombre de millisecondes depuis le dernier lancement du système.

ulong  GetTickCount64();

Valeur de Retour

Une valeur de type ulong.

Note

Le compteur est limité à la précision du timer du système, qui retourne habituellement un résultat avec une précision entre 10 et 16 millisecondes. Contrairement à GetTickCount, qui est de type uint et dont le contenu déborde tous les 49,7 jours dans le cas d'une utilisation continue de l'ordinateur, la fonction GetTickCount64() peut être utilisée indéfiniment et n'est pas sujette au débordement (overflow).

Exemple :

#define MAX_SIZE 40
 
//+------------------------------------------------------------------+
//| Script pour mesurer le temps de calcul de 40 nombres Fibo        |
//+------------------------------------------------------------------+
void OnStart()
  {
   long fib_array[MAX_SIZE];
 
//--- stocke la valeur initiale
   ulong start=GetTickCount64();
//--- boucle dans laquelle on calcule le nombre donné de nombres de la série Fibo
   for(int i=0;i<MAX_SIZE;i++) 
      fib_array[i]=TestFibo(i);
//--- récupère le temps passé en millisecondes
   ulong time=GetTickCount64()-start;
 
//--- afficher le message d'erreur dans le journal des Experts
   ArrayPrint(fib_array);
   PrintFormat("Calculating the first %d Fibonacci numbers took %I64u ms",MAX_SIZE,time);
  }
//+------------------------------------------------------------------+
//| Fonction pour obtenir un numéro de Fibo par son numéro de série  |
//+------------------------------------------------------------------+
long TestFibo(long n)
  {
//--- premier membre de la série Fibo
   if(n<2)
      return(1);
//--- tous les membres suivants sont calculés à l'aide de cette équation
   return(TestFibo(n-2)+TestFibo(n-1));
  }

Voir aussi

Date et Heure, EventSetMillisecondTimer, GetTickCount, GetMicrosecondCount