DocumentationSections
Référence MQL5Fonctions CommunesSleep 

Sleep

 

    Bloque l'exécution de l'expert courant ou du script pendant l'intervalle défini.

void  Sleep(
   int  milliseconds      // intervalle 
   );

Paramètres

milliseconds

[in]  La durée de pause en millisecondes.

Valeur de Retour

Aucune.

Note

On ne peut pas appeler la fonction Sleep() depuis des indicateurs utilisateur, puisque les indicateurs sont accomplis dans le thread d'interface et qu'ils ne doivent pas le ralentir. La vérification de l'état du drapeau de stop de l'expert chaque 0.1 seconde est inseré dans la fonction.

Exemple :

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- afficher un compte à rebours de 10 à 1 dans les commentaires du graphique
   for(int i=10; i>0 && !IsStopped(); i--)
     {
      Comment(StringFormat("Wait %u seconds",i));
      Sleep(1000);
     }
//--- écrit un texte dans le commentaire "arriving" qui décrit le but du script
   string text="This was a test showing how the Sleep() function works";
   string mess="";
   for(int i=0; i<(int)text.Length(); i++)
     {
      mess+=ShortToString(text.GetChar(i));
      Sleep(100);
      Comment(mess);
     }
//--- dit au revoir...
   Sleep(1000);
   for(int i=0; i<6; i++)
     {
      mess=(i % 2 == 0 ? "" : "  Bye!");
      Comment(mess);
      Sleep(300);
     }
//--- supprime le texte sur le graphique
   Comment("");
  }