ドキュメントセクション
MQL5 リファレンス取引関数HistoryDealGetString 

HistoryDealGetString

約定のリクエストされたプロパティを返します。 約定プロパティは string 型でなければなりません。この関数には 2 つのバージョンがあります。

1. すぐにプロパティ値を返します。

string  HistoryDealGetString(
  ulong                      ticket_number,    // チケット
  ENUM_DEAL_PROPERTY_STRING  property_id        // プロパティ識別子
  );

2. 関数実行の成功に応じて true または false を返します。成功した場合、プロパティの値は、参照によって渡された最後のパラメータに配置されます。

bool  HistoryDealGetString(
  ulong                      ticket_number,    // チケット
  ENUM_DEAL_PROPERTY_STRING  property_id,       // プロパティ識別子
  string&                    string_var        // プロパティ値を受け取る
  );

パラメータ

ticket_number

[in]   約定チケット

property_id

[in]   約定プロパティ識別子値は ENUM_DEAL_PROPERTY_STRING 列挙のいずれかです。

string_var

[out] リクエストされたプロパティ値を受け取るstring 型の変数

戻り値

string 型の変数

注意事項

注文、約定 及び ポジションは混乱されてはなりません。 約定は注文実行の結果で、ポジションは 1 つ以上の 約定の結果の概要です。

例：

//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                              |
//+------------------------------------------------------------------+
void OnStart()
 {
//--- 取引及び注文履歴をリクエストする
  if(!HistorySelect(0, TimeCurrent()))
    {
    Print("HistorySelect() failed. Error ", GetLastError());
    return;
    }
 
//--- 口座履歴の取引リストによるループ
  int total=HistoryDealsTotal();
  for(int i=0; i<total; i++)
    {
    //--- 次の取引のチケットを取得する（取引はプロパティを取得するために自動的に選択される）
    ulong ticket=HistoryDealGetTicket(i);
    if(ticket==0)
        continue;
     
    //--- 選択した取引の実数プロパティのリストのヘッダーを表示するために、取引のタイプと方向を取得する
    string type=DealTypeDescription((ENUM_DEAL_TYPE)HistoryDealGetInteger(ticket, DEAL_TYPE));
    string entry=DealEntryDescription((ENUM_DEAL_ENTRY)HistoryDealGetInteger(ticket, DEAL_ENTRY));
    PrintFormat("String properties of an deal %s entry %s #%I64u:", type, entry, ticket);
     
    //--- 選択した取引のすべての実数プロパティをヘッダーの下に表示する
    HistoryDealPropertiesStringPrint(ticket, 13);
    }
  /*
   結果：
  String properties of an deal Buy entry In #2785021084:
  Symbol:     EURUSD
  Comment:     Test PositionGetString
  Extarnal ID:
  String properties of an deal Buy entry Out #2497993663:
  Symbol:     EURUSD
  Comment:     [tp 1.08639]
  Extarnal ID:
  */
 }
//+------------------------------------------------------------------+
//| 選択した取引の文字列プロパティを操作ログに表示する                            |
//+------------------------------------------------------------------+
void HistoryDealPropertiesStringPrint(const ulong ticket, const uint header_width=0)
 {
  uint   w=0;
  string header="";
  string value ="";
 
//--- ヘッダーのテキストとヘッダーフィールドの幅を定義する
//--- ヘッダーの幅が関数に渡され、ゼロと等しい場合、幅はヘッダー行のサイズ+1になる
  header="Symbol:";
  w=(header_width==0 ? header.Length()+1 : header_width);
//--- 取引銘柄を取得し、指定されたヘッダー幅で操作ログに表示する
  if(!HistoryDealGetString(ticket, DEAL_SYMBOL, value))
    return;
  PrintFormat("%-*s%-s", w, header, value);
 
//--- 操作ログに取引コメントを表示する
  header="Comment:";
  w=(header_width==0 ? header.Length()+1 : header_width);
  if(!HistoryDealGetString(ticket, DEAL_COMMENT, value))
    return;
  PrintFormat("%-*s%-s", w, header, value);
 
//--- 外部取引システムでの約定IDを表示する
  header="Extarnal ID:";
  w=(header_width==0 ? header.Length()+1 : header_width);
  if(!HistoryDealGetString(ticket, DEAL_EXTERNAL_ID, value))
    return;
  PrintFormat("%-*s%-s", w, header, value);
 }
//+------------------------------------------------------------------+
//| 取引タイプの説明を返す                                                 |
//+------------------------------------------------------------------+
string DealTypeDescription(const ENUM_DEAL_TYPE type)
 {
  switch(type)
    {
    case DEAL_TYPE_BUY                     : return("Buy");
    case DEAL_TYPE_SELL                    : return("Sell");
    case DEAL_TYPE_BALANCE                 : return("Balance");
    case DEAL_TYPE_CREDIT                  : return("Credit");
    case DEAL_TYPE_CHARGE                  : return("Additional charge");
    case DEAL_TYPE_CORRECTION              : return("Correction");
    case DEAL_TYPE_BONUS                   : return("Bonus");
    case DEAL_TYPE_COMMISSION              : return("Additional commission");
    case DEAL_TYPE_COMMISSION_DAILY        : return("Daily commission");
    case DEAL_TYPE_COMMISSION_MONTHLY      : return("Monthly commission");
    case DEAL_TYPE_COMMISSION_AGENT_DAILY  : return("Daily agent commission");
    case DEAL_TYPE_COMMISSION_AGENT_MONTHLY: return("Monthly agent commission");
    case DEAL_TYPE_INTEREST                : return("Interest rate");
    case DEAL_TYPE_BUY_CANCELED            : return("Canceled buy deal");
    case DEAL_TYPE_SELL_CANCELED           : return("Canceled sell deal");
    case DEAL_DIVIDEND                     : return("Dividend operations");
    case DEAL_DIVIDEND_FRANKED             : return("Franked (non-taxable) dividend operations");
    case DEAL_TAX                          : return("Tax charges");
    default                                : return("Unknown deal type: "+(string)type);
    }
 }
//+------------------------------------------------------------------+
//| ポジション変更法を返す                                                 |
//+------------------------------------------------------------------+
string DealEntryDescription(const ENUM_DEAL_ENTRY entry)
 {
  switch(entry)
    {
    case DEAL_ENTRY_IN      : return("In");
    case DEAL_ENTRY_OUT     : return("Out");
    case DEAL_ENTRY_INOUT   : return("Reverce");
    case DEAL_ENTRY_OUT_BY  : return("Out by");
    case DEAL_ENTRY_STATE   : return("Status record");
    default                 : return("Unknown deal entry: "+(string)entry);
    }
 }

参照

HistoryDealsTotal()、HistorySelect()、HistoryDealGetTicket()、 約定プロパティ