GetMicrosecondCount

La función GetMicrosecondCount() devuelve la cantidad de microsegundos transcurridos desde el inicio de funcionamiento del programa MQL5.

ulong  GetMicrosecondCount();

Valor devuelto

Valor del tipo ulong.

Ejemplo:

//+------------------------------------------------------------------+
//| Código a probar                                                  |
//+------------------------------------------------------------------+
void Test()
  {
   int    res_int=0;
   double res_double=0;
//---  
   for(int i=0;i<10000;i++)
     {
      res_int+=i*i;
      res_int++;
      res_double+=i*i;
      res_double++;
     }
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   uint   ui=0,ui_max=0,ui_min=INT_MAX;
   ulong  ul=0,ul_max=0,ul_min=INT_MAX;
//--- número de pruebas
   for(int count=0;count<1000;count++)
     {
      uint  ui_res=0;
      ulong ul_res=0;
      //--- 
      for(int n=0;n<2;n++)
        {
         //--- seleccionamos modo de medición
         if(n==0) ui=GetTickCount();
         else     ul=GetMicrosecondCount();
         //--- código a probar
         Test();
         //--- acumulamos el resultado de medición (dependiendo del modo)
         if(n==0) ui_res+=GetTickCount()-ui;
         else     ul_res+=GetMicrosecondCount()-ul;         
        }
      //--- apuntamos el tiempo mínimo y máximo de ejecución del código de ambas dimensiones
      if(ui_min>ui_res) ui_min=ui_res;
      if(ui_max<ui_res) ui_max=ui_res;
      if(ul_min>ul_res) ul_min=ul_res;
      if(ul_max<ul_res) ul_max=ul_res;
     }
//---
   Print("GetTickCount error(msec): ",ui_max-ui_min);
   Print("GetMicrosecondCount error(msec): ",DoubleToString((ul_max-ul_min)/1000.0,2));
  }

Véase también

Fecha y hora